Office: Inhalt einer Variable an einen Filter übergeben

moses-ms · 8. November 2015

Moin,

ich hab ein Problem mit der AutoFilter Funktion in VBA. Nutze ich die AutoFilterFunktion mit "Criteria1:=(".....")" funktioniert alles ohne Probleme, will ich aber "Criteria1:=" mit dem Inhalt einer Variable füllen filtert er nichts, es wird nichts angezeigt. Ich habe versucht die Werte in eine Variable zu speichern und dann mit "CStr(Variable) " zu übergeben ohne Erfolg. Auch das ganze als Array zu übergeben schlägt fehl.

Wo mache ich den Fehler?

:)

Hajo_Zi · 10. November 2015

die Übergabe ist falsch nach dem =

moses-ms · 10. November 2015

Moin,

sorry, das verstehe ich nicht. Egal was und wie ich es übergebe, ob als String oder als Array, es wird alles "weggefiltert".

moses-ms · 10. November 2015

ANbei noch einmal mein Code und eine kleine Testtabelle Code:

Sub Filter_Test()

Dim TestName As Variant

TestName = Worksheets("Hilfsdaten").Range("F1:F4").Value

Worksheets("Hilfsdaten").Range("A1:B11").AutoFilter Field:=1, Criteria1:=TestName, Operator:=xlFilterValues

Selection.AutoFilter

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das Selection.Autofilter, am Schluß, ersparrt mir nur das entfernen des gesetzten Filters.

Hajo_Zi · 10. November 2015

der Code sieht ok aus.

Der Name einer hochgeladenen Mappe wird im Beitrag automatisch angezeigt, sodass es bei Verwendung von aussagekräftigen Namen leichter fällt, sie später im Ablageordner wiederzufinden und sie gedanklich einem bestimmten Thema zuzuordnen. Namen wie Test, Mappe, Beispiel usw. sind so allgemein, dass eine Zuordnung zu einem Thema unmöglich gemacht wird.
Wenn du an Stelle einer Demomappe deine Originalmappe hochladen willst, diese aber sensible Daten enthält, kannst du diese Daten

Luschi · 10. November 2015

Hallo moses-ms,

bei mir klapp das so: Code:

Sub Filter_Name()
Dim TestName As Variant

On Error Resume Next
ActiveSheet.ShowAllData
On Error GoTo 0

TestName = WorksheetFunction.Transpose(Worksheets("Tabelle1"). _
Range("F2:F4").Value)

Worksheets("Tabelle1").Range("A1:B11").AutoFilter Field:=1, _
Criteria1:=TestName, Operator:=xlFilterValues

Erase TestName
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß von Luschi
aus klein-Paris

Hajo_Zi - der Code sieht ok aus.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

So ein Quatsch...
Mein Credo: Programmcode muß funktionieren!

moses-ms · 11. November 2015

Moin,

Danke für die Lösung, funktioniert hervorragend. Eine weiteres Problem was sich eben herausgestellt hat ist, kann mal mehrere solcher "Ranges" im Nachgang zusammenfügen?
Grund ist, dass die Anwender mittels Checkbox bestimmte Filterungen auswählen können, die dann natürlich auch gemischt sein können. Mittels Union (Range1, Range2) funktioniert es leider nicht, so oder so ähnlich hatte ich es mir im Vorfeld gedacht.

Luschi · 11. November 2015

Hallo moses-ms,

so klappt es bei mir: Code:

Sub Filter_Name()
Dim Testname0 As Variant, _
TestName1 As Variant, TestName2 As Variant

On Error Resume Next
ActiveSheet.ShowAllData
On Error GoTo 0

'1. Bereich
TestName1 = WorksheetFunction.Transpose(Worksheets("Tabelle1").Range("F2:F4").Value)
'2. Bereich
TestName2 = WorksheetFunction.Transpose(Worksheets("Tabelle1").Range("H2:H4").Value)

'beide Arrays vereinen
Testname0 = MergeArrays(TestName1, TestName2)
If IsArray(Testname0) Then
'Filtern
Worksheets("Tabelle1").Range("A1:B11").AutoFilter Field:=1, _
Criteria1:=Testname0, Operator:=xlFilterValues
Else
MsgBox "Fehler im Vereinigungs-Array", 4096 + 16, _
"Filtern nicht möglich!"
End If
Set rg = Nothing
On Error Resume Next
Erase Testname0: Erase TestName1: Erase TestName2
On Error GoTo 0
End Sub

Function MergeArrays(ByRef arr1 As Variant, ByRef arr2 As Variant) As Variant
'Test if not isarray then exit
If Not IsArray(arr1) Or (Not IsArray(arr2)) Then Exit Function

Dim arr As Variant
Dim a As Long, b As Long 'index Array
Dim len1 As Long, len2 As Long 'nb of item

'get len if array don't start to 0
len1 = UBound(arr1) - LBound(arr1) + 1
len2 = UBound(arr2) - LBound(arr2) + 1

b = 1 'position of start index
'dim new array
ReDim arr(b To len1 + len2)
'merge arr1
For a = LBound(arr1) To UBound(arr1)
arr(b) = arr1(a)
b = b + 1 'move index
Next a
'merge arr2
For a = LBound(arr2) To UBound(arr2)
arr(b) = arr2(a)
b = b + 1 'move index
Next a

'final
MergeArrays = arr
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß von Luschi
aus klein-Paris

moses-ms · 17. November 2015

Moin,

Danke für die Lösung! Es funktioniert auch bei mir.

Office: Inhalt einer Variable an einen Filter übergeben

Inhalt einer Variable an einen Filter übergeben

Inhalt einer Variable an einen Filter übergeben

Inhalt einer Variable an einen Filter übergeben

Inhalt einer Variable an einen Filter übergeben

Inhalt einer Variable an einen Filter übergeben - Similar Threads - Inhalt Variable Filter

Variable in Pfad zu externem Inhalt (Sharepoint)

Hyperlink mit Inhalten aus Inhaltssteuerelement

Inhalt einer Text Datei vom Sharepoint einer Variablen zuweisen

Zuweisung Inhalt Zelle zu Variable

variabler Inhalt in Kombibox

Excel 2010 - Makro zum Auffinden einer variablen Zeile und Löschen derer Inhalte

Inhalt einer Datei in eine Variable übergeben - Gelöst