Office: Inhalt einer ZIP-Datei mit AC2010 auslesen

Hallo,
hat jemand eine Idee wie man den Inhalt einer ZIP-Datei mit Access 2010 auslesen kann, ohne diese zuvor zu entpacken.

Das Auslesen eines Ordners mittels VBA zeigt mir zwar den ZIP-Ordner selbst, aber nicht dessen Inhalt.

Danke im Voraus und LG
JoSch

 

Hallo,

mit folgendem Link
http://www.databasejournal.com/feat...th-Compressed-zipped-folders-in-MS-Access.htm
erhältst du Informationen und Beispielcode in VBA zum Thema Zip-Files.
Der Kommentar ist allerdings in Englisch.

 

Hallo Anton Exl,

herzlichen Dank, der Hinweis hat mich ein Stück weitergebracht und der Beispielcode hat auf Anhieb funktioniert.
Leider gibt es aber auch ZIP-Dateien, die Unterordner enthalten - deren Inhalt mit dem Beispielcode nicht erkannt wird.

Nochmals vielen Dank
und liebe Grüße
JoSch

 

Hallo,

um die Dateien eines Zip-Archivs (rekursiv) im Direktbereich aufzulisten, genügt eigentlich folgendes VBA-Programm:

Code:

Sub Zip_Listing()

  Dim ShS As Object  'New Shell32.Shell
  Dim ShF As Object  'Shell32.Folder
  
  Dim vDir As Variant
  Set ShS = CreateObject("Shell.Application")
  
  vDir = "I:\EXCEL\MAKRO\Baustein-Einträge_toExcel.docm.zip"    '<== Hier Pfad+ZipDatei eingeben.
  Set ShF = ShS.Namespace(vDir)
  PrintFolder 0, ShF
    
  Set ShS = Nothing
  
End Sub
Sub PrintFolder(ByVal Tb As Integer, ShF As Object) 'Shell32.Folder)
  
  Dim ShI As Object 'Shell32.FolderItem
  
  For Each ShI In ShF.Items
    Debug.Print Spc(Tb); ShI.Name; Tab(40);
    Debug.Print ShI.IsFolder,
    Debug.Print ShI.Type
    If ShI.IsFolder Then
      PrintFolder Tb+2, ShI.GetFolder
    End If
  Next ShI
  
End Sub

Du musst nur in der Zeile vDir = "C:\Pfad...\Datei.zip" natürlich einen gültigen Pfad eingeben zusammen mit einer Zip-Datei.

So wie das Makro zur Zeit ist, setzt es die Late-Binding-Technik ein. Falls du jedoch auf Early-Binding umstellst, dann müssten alle Typ-Wörter "Object" durch die jeweils nachfolgenden Typen, die zur Zeit als Kommentare aufscheinen, ersetzt werden; weiters wäre dann die Zeile mit ...CreateObject... zu entfernen/auszukommentieren.
Voraussetzung dafür ist natürlich, dass du die Shell32.dll als Programmbibliothek einbindest, indem du im
VBA-Editor-Menü > Extras > Verweise...
ins Dialogfenster für "Verweise-VBAProjekt" gehst und dort in der Liste "Verfügbare Verweise" in der Checkbox für "Microsoft Shell Controls and Automation" ein Häkchen setzst. Dann hast du auch bequemen Zugriff auf alle Objekte/Eigenschaften/Methoden der Shell32-Bibliothek.

 

Hallo,
genau das ist es, was ich gesucht habe.
Vielen Dank für die Mühe zu später Abendstunde.

Liebe Grüße
JoSch