Office: (Office 2007) keine Doppelten Werte aus Liste in Array einlesen

MaggusR · 21. Februar 2011

Hallo zusammen,

ich habe ich Excel 2007 auf einem Excelblatt folgende Liste:

Fragen

Frage1
Frage2
Frage3
Frage3
Frage1
Frage4
Frage5
Frage7
Frage11
Frage8
Frage9
Frage8

Ich möchte mir in einem Array nun alle Werte einfach speichern, also keine doppelten Werte:

Frage1
Frage2
Frage3
Frage4
Frage5
Frage7
Frage8
Frage9
Frage11

Mein Ansatz ist folgender:

Lege die Werte der Reihe nach im Array ab.
Wenn ein Wert eingelesen werden soll, der schon im Array existiert dann lies diesen nicht ein:

Code:

Sub Question()

Dim Question()
Dim k As Variant
Dim i, j, x As Integer

letzteZeile = Sheets(1).Cells(Rows.Count, 1).End(xlUp).Row

ReDim Question(1 To letzteZeile)

j = 1
x = 1

For i = 2 To letzteZeile
For x = 1 To UBound(Question(i))
If Question(x) = Workbooks(1).Sheets(1).Cells(i, 5).Value Then
MsgBox "Gefunden"
Else
Question(i) = Workbooks(1).Sheets(1).Cells(i, 5).Value
End If
Next x
Next i

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

An der Stelle

Code:

For x = 1 To UBound(Question(i))
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

kommt der Fehler "Runtime-Error 13: Type mismatch"

Was mache ich falsch bzw. ist dieser Lösungsansatz richtig?

Vielen Dank für Eure Hilfe *Smilie

MaggusR

:)

AusmStiftingtol · 23. Februar 2011

Hallo

sollte das nicht nur UBound(Question) sein?

MaggusR · 23. Februar 2011

Hallo AusmStiftingtol,

ja stimmt *Smilie

Aber im Array stehen alle Werte, auch die doppelten...

Gruß
MaggusR

ebs17 · 23. Februar 2011

Lege die Werte der Reihe nach im Array ab.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn Du Deine Liste vorher sortierst, musst Du nicht im Array suchen (dafür ist es weniger geeignet), sondern Du kannst stets mit dem letzten Arraywert vergleichen (vor Eintrag).

Weitere Varianten:
- Weg über Dictionary: Wegen der Indizierung lässt es keine Duplikate zu.
- Weg über SQL: In einer Abfrage kann man einfach Duplikate ausschließen.

EarlFred · 23. Februar 2011

Hallo MaggusR,

eine schnelle Variante mit Dictionary:

Code:

Sub ArrayODuplikate()
Dim fOhneDuplikate As Variant, fAusgangswerte As Variant
Dim dic As Object
Dim i As Long

Set dic = CreateObject("Scripting.Dictionary")

With Sheets(1)
fAusgangswerte = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp)).Value
End With

For i = LBound(fAusgangswerte, 1) To UBound(fAusgangswerte, 1)
If Not dic.exists(fAusgangswerte(i, 1)) Then _
dic.Add fAusgangswerte(i, 1), 1
Next i

fOhneDuplikate = dic.keys

Set dic = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

chris-kaiser · 23. Februar 2011

hi

wobei ich auch gleich den Bereich in ein Array geben würde (geht schneller)

Code:

Option Explicit
Sub QuestionMakro()
Dim Question()
Dim objDict As Object, StrTemp As String
Dim i As Long
Dim letzteZeile As Long
Set objDict = CreateObject("Scripting.Dictionary")
letzteZeile = Sheets(1).Cells(Rows.Count, 1).End(xlUp).Row
For i = 2 To letzteZeile
If Not objDict.exists(Sheets(1).Cells(i, 5).Value) Then
Call objDict.Add(Sheets(1).Cells(i, 5).Value, Empty)
End If
Next i
Question() = objDict.keys
'hier zum Testen
' For i = 0 To UBound(Question)
' StrTemp = StrTemp & Question(i) & " / "
' Next
' MsgBox "folgende Einträge ohne Duplikate sind: " & StrTemp
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ups war ich wohl zu langsam ^^ *wink.gif*
das meinte ich mit gleich den Bereich in ein Array geben, nur vermute ich das Spalte 5 gebraucht wird und ab Zeile 2, falls ja
die Zeile so ändern. (ist jetzt aber nicht getestet)

fAusgangswerte = .Range(.Cells(2, 5), .Cells(Rows.Count, 5).End(xlUp)).Value

EarlFred · 23. Februar 2011

\@Chris:

wobei ich auch gleich den Bereich in ein Array geben würde (geht schneller)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Schon erledigt *wink.gif*

Grüße
EarlFred

MaggusR · 23. Februar 2011

Hallo zusammen,

vielen Dank für Eure Antworten bzw. Hilfen *Smilie

Ich habe jetzt die Lösung von chris-kaiser
verwendet und läuft prima.

Gruß
MaggusR

Edit:

@chris-kaiser: ja, stimmt, die Werte stehen in Spalte 5 ab Zeile 2 *Smilie

Office: (Office 2007) keine Doppelten Werte aus Liste in Array einlesen

keine Doppelten Werte aus Liste in Array einlesen

keine Doppelten Werte aus Liste in Array einlesen

keine Doppelten Werte aus Liste in Array einlesen

keine Doppelten Werte aus Liste in Array einlesen

keine Doppelten Werte aus Liste in Array einlesen - Similar Threads - Doppelten Werte Liste

Abfrageergebnis soll keine doppelten Werte enthalten

Doppelte Werte pro Tag, an anderen nicht

Doppelte Werte mit 2 Bedingungen finden

Doppelte Werte mit Index

Doppelte Werte mit gleiche Farbe löschen

Doppelte in Liste Werte verhindern

Daten kopieren ohne doppelte Werte