Office: (Office 365) Kombi Diagramm Format ändert sich

Hallo zusammen,

ich habe ein Diagramm mit 2 Datenreihen. Die 1. Datenreihe (DR) ist als Balken und die 2. DR als Linie dargestellt. Bei Betätigung eines Schalters, soll die 2. DR als Balken und die 1. DR als Linie dargestellt werden, also wechseln. Habe die Formate vorher eingestellt (siehe wie Diagramm 2), beide Formate sind gleich. Nach dem Wechsel der DR verlieren diese ihre Formate.
Das möchte ich gerne verhindern.

 

Hi,

versuche es mal so:

Code:

Sub Wechsel()
    'Variablen definieren
    Dim wsAs As Worksheet
    Set wsAs = ActiveSheet
    'Farbe der Form ändern
    If wsAs.Shapes("Form1").Fill.ForeColor.RGB = RGB(89, 89, 89) Then
      wsAs.Shapes("Form1").Fill.ForeColor.RGB = RGB(237, 125, 49)
      ' Datenreihe 1 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(1)
        .ChartType = xlColumnClustered
        With .Format.ThreeD
            .BevelTopType = msoBevelCircle
            .BevelTopInset = 6
            .BevelTopDepth = 6
        End With
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent2
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
        End With
      End With
      ' Datenreihe 2 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(2)
        .ChartType = xlLine
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent1
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
        End With
      End With
    'Farbe der Form ändern
    Else
      wsAs.Shapes("Form1").Fill.ForeColor.RGB = RGB(89, 89, 89)
      ' Datenreihe 1 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(1)
        .ChartType = xlLine
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent1
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
        End With
      End With
      ' Datenreihe 2 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(2)
        .ChartType = xlColumnClustered
        With .Format.ThreeD
            .BevelTopType = msoBevelCircle
            .BevelTopInset = 6
            .BevelTopDepth = 6
        End With
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent2
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
        End With
      End With
    End If
End Sub

---

 

Hallo Karin,

Vielen Dank für deine Antwort, ich werde es morgen probieren.

LG

 

Hallo Karin,

ich konnte jetzt deinen Code probieren. Die Balken bleiben in ihrem Format bestehen, das ist gut. Jedoch ist die Linie nach dem Umschalten sehr dünn und müsste dicker sein. Außerdem fehlen noch die Markierungspunkte, wäre schön, die auch noch rein zu bringen.

Vielen Dank für deine Mühe.

LG
Michael

 

Hi Michael,

die Liniendicke kann man anpssen, aber es gibt einiges, was man war von Hand einstellen kann, sich aber per VBA nicht realisieren lässt, wie z.B. den Markern eine andere Farbe als der Linie zu geben.

Code:

Sub Wechsel()
    'Variablen definieren
    Dim wsAs As Worksheet
    Set wsAs = ActiveSheet
    'Farbe der Form ändern
    If wsAs.Shapes("Form1").Fill.ForeColor.RGB = RGB(89, 89, 89) Then
      wsAs.Shapes("Form1").Fill.ForeColor.RGB = RGB(237, 125, 49)
      ' Datenreihe 1 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(1)
        .ChartType = xlColumnClustered
        With .Format.ThreeD
            .BevelTopType = msoBevelCircle
            .BevelTopInset = 6
            .BevelTopDepth = 6
        End With
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent2
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
       End With
      End With
      ' Datenreihe 2 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(2)
        .ChartType = xlLine
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent1
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
            .Weight = 4
        End With
        .MarkerStyle = 8
        .MarkerSize = 3
      End With
    'Farbe der Form ändern
    Else
      wsAs.Shapes("Form1").Fill.ForeColor.RGB = RGB(89, 89, 89)
      ' Datenreihe 1 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(1)
        .ChartType = xlLine
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent1
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
            .Weight = 4
        End With
        .MarkerStyle = 8
        .MarkerSize = 3
      End With
      ' Datenreihe 2 ändern
      With wsAs.ChartObjects(1).Chart.FullSeriesCollection(2)
        .ChartType = xlColumnClustered
        With .Format.ThreeD
            .BevelTopType = msoBevelCircle
            .BevelTopInset = 6
            .BevelTopDepth = 6
        End With
        With .Format.Line
            .Visible = msoTrue
            .ForeColor.ObjectThemeColor = msoThemeColorAccent2
            .ForeColor.TintAndShade = 0
            .ForeColor.Brightness = 0
            .Transparency = 0
        End With
      End With
    End If
End Sub

---

 

Perfekt, vielen lieben Dank.

LG
Michael