Office: Kombination von TEILERGEBNIS und SUMMEWENN mit ODER Kriterium kombinieren

Hallo zusammen,

ich würde gern in der folgenden Formel statt "Reinvestition Fahrweg" einen Zellbereich auswählen und wenn ein Kriterium zutrifft soll es summiert werden

=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("U"&ZEILE(8:2581)))*(I8:I2581="Reinvestition Fahrweg"))

Leider steh ich da irgendwo an und weiß nicht wie ich das machen kann.. einfach statt dem "Reinvestition Fahrweg" den Zellbereich einfügen hat leider nicht funktioniert

LG

 

Hallo,

wie wäre es, wenn du eine Beispieldatei hochladen würdest?

 

Hallo,

das kann so nicht funktionieren. Im ersten Teil hast Du einen gefilterten Bereich, im zweiten Teil den gesamten Spaltenbereich, ergibt unterschiedliche Bereiche, das mag die Formel nicht!
Mal ein ungetesteter Versuch:
=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("U"&ZEILE(8:2581)))*(TEILERGEBNIS(9;INDIREKT("I"&ZEILE(8:2581)))="Reinvestition Fahrweg"))

 

Hier die Beispieldatei :)

Die Formeel aus D2560 soll auch als Teilergebnis funktionieren...

Quasi die Formel aus E2560 soll mehrere Kritierien umfassen

Im Tabellenblatt Aufteilung Überkategorien sind die Programme, welche zu der jeweiligen Überkategorie zusammengefasst werden

 

Danke für die Antwort. Die Formel hat eigentlich funktioniert! Ich möchte nur statt dem Reinvestition Fahrweg am Ende ein zweites Kriterium einfügen und wenn eines der beiden zutrifft, solls summiert werden

 

Hallo,

1. stehen in U keine Daten.
2. stehen die "Reinvest" in A, was willst Du dann mit I?
3. müssen beim Summenprodukt, so wie es jetzt vorliegt, alle Bedingungen erfüllt sein.

Es wäre nicht schlecht, wenn Du anhand der Tabelle, die Du vorgestellt hast, erklärst, was Du willst, inkl. Wunschergebnis!

 

Ich hab die Tabelle vorm Hochladen noch anpassen müssen, da ich nicht alle Daten veröffentlichen darf.

Die richtige Formel steht in der Datei und hier auch nochmal passend zur Beispieltabelle:
=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("E"&ZEILE(7:2556)))*(A7:A2556="Reinvestition Fahrweg"))

Ich möchte mit der Formel erreichen das alle Werte der Spalte E zusammengerechnet werden wenn in Spalte A Reinvestition Fahrweg oder Reinvestition Brückenbau enthalten ist

Ich hoffe das ist so verständlich..

 

Hi,

alle Werte der Spalte E

auch die ausgeblendeten?

 

Hi,

es sollen nur die gefiltertetn Werte (Quasi die angezeigten) zusammengerechnet werden. Wenn der Filter dann aufgelöst wird, sollen alle zusammengerechnet werden, auf welche die beiden Kriterien zutreffen.

 

Hallo,

eigentlich reicht doch diese Formel:

=TEILERGEBNIS(109;E7:E2550)

Vielleicht solltest Du Dir auch mal klarmachen, was die Formel macht: Sie summiert alle nicht ausgeblendeten Zeilen.

 

Hallo,

ist doch immer wieder schön, wenn eine Idee funktioniert.

Gruß Roger

 

Hallo,

da du uns eine ganz wichtige Information vorenthalten hast, nämlich welche Excel-Version du hast, habe ich angenommen, dass du Excel365 hast oder aber zumindest Excel2021.

1) Ich habe deine Daten im Arbeitsblatt "VORHABEN" im Bereich A6:L2556 umgewandelt in eine strukturierte (=intelligente) Tabelle mit Namen "tbDaten".

2) Um mittels Formeln kontrollieren zu können, welche Zeilen in dieser Tabelle eingeblendet bzw. ausgeblendet sind, habe ich in Spalte M in dieser Tabelle eine Hilfsspalte mit Namen "Sichtbar" eingefügt.
Diese enthält eine einfache Formel: =TEILERGEBNIS(3;[@2031ff])
Diese Formel hat als sichtbares Resultat den Wert 1. Ist jedoch eine Zeile ausgeblendet, ist die Zelle von Spalte M in dieser ausgeblendeten Zeile leer.
Vorteil: Daran können dann andere Formeln erkennen, ob eine Zeile ein- bzw. ausgeblendet ist.
Nachteil: Jedesmal, wenn ein neuer Zeilenfilter festgelegt wird, muss diese Formelspalte ihre Werte neu festlegen, was bei 2550 Zeilen eine gewisse Zeit benötigt.

3) Zelle E2560 enthält folgende Formel:
=SUMME(tbDaten[2025]*(tbDaten[Programm]="Reinvestition Fahrweg")*tbDaten[Sichtbar])
Diese summiert alle Werte in Spalte "2025" (Spalte E), die in Spalte A den Text "Reinvestition Fahrweg" enthalten und die sichtbar sind (also nicht ausgeblendet sind). Zeilen, die ausgeblendet sind, haben in tbDaten[Sichtbar] einen Leerwert (=0), sodass eine solche Zeile zu 0 ausgewertet wird und daher in der Summe nicht aufscheint.

4) Zelle D2560 enthält folgende Formel:
=SUMME(SUMMEWENNS(tbDaten[2024];tbDaten[Programm];'Aufteilung Überkategorien'!$G$7:$G$8;tbDaten[Sichtbar];1))
Diese funktioniert ähnlich wie die vorherige, nur eben für Spalte "2024" (Spalte D). Die Kriterienwerte für Spalte A sind jedoch in einem Spaltenbereich G7:G8 enthalten, sodass die SUMMEWENNS-Funktion ebenfalls einen Resultatsbereich aus 2 Werten liefert, der mittels der äußeren SUMME-Funktion aufsummiert wird. Diese Funktionalität erfordert jedoch mindestens ein Excel2021 oder Excel365. Falls kein solches Excel vorhanden ist, müsste die Formel als Array-Formel eingegeben werden (Abschluss nicht bloß mit EINGABE-Taste, sondern mit UMSCHALT+Strg+EINGABE, sodass danach die Formel in geschweiften Klammern eingeschlossen erscheint).

Datei liegt bei.