Office: Kommentare auslesen

Brauche mal wieder Hilfe in VBA.

Ich möchte gern meine Kommentare in ein separates Blatt auslesen, mit Angabe, in welchem Registerblatt und in welcher Zelle dieser Kommentar steht.
Zellen auslesen habe ich schon gefunden, wie ich aber nun meine Anforderung da reinbaue ist mir nicht klar.
Für Hilfe wäre ich dankbar.
hexlein

Public Function Kommentar(Zelle As Range) As String
Application.Volatile
If Zelle.Cells.Count <> 1 Then Exit Function

On Error GoTo Fehler
Kommentar = Zelle.Comment.Text
Exit Function

Fehler:
Kommentar = ""
End Function

 

Hi,

eine Möglichkeit:

Code:

Sub KommentarzellenAuflisten()
    Dim raZelle As Range
    Dim wsTabelle As Worksheet
    Dim loZeile As Long
    Dim raBereich As Range
    loZeile = 1
    For Each wsTabelle In Worksheets
        If wsTabelle.Name <> "Übersicht" Then
            On Error Resume Next
            Set raBereich = wsTabelle.UsedRange.SpecialCells(xlCellTypeComments)
            On Error GoTo 0
            If Not raBereich Is Nothing Then
                For Each raZelle In raBereich
                    With Worksheets("Übersicht")
                        .Cells(loZeile, 1) = raZelle.Address
                        .Cells(loZeile, 2) = raZelle.Parent.Name
                        .Cells(loZeile, 3) = raZelle.Comment.Text
                    End With
                    loZeile = loZeile + 1
                Next raZelle
            End If
            Set raBereich = Nothing
        End If
    Next wsTabelle
End Sub

Bis später,
Karin

 

Hallo Karin,

vielen vielen Dank, es hat funktioniert und ich kann weiterarbeiten :-D
hexlein