Office: (Office 2010) Kommentarfeld Größe automatisch anpassen

Hi Leute,

ich hoffe ihr könnt mir helfen.

Ich habe folgenden Code in einem Modul:

------------------------------------------------
Option Explicit

Function SetComment(rngBezug As Range, vCommentText As Variant) As Boolean
Dim strCommentText As String

On Error Resume Next
rngBezug.Comment.Delete

If TypeOf vCommentText Is Range Then
strCommentText = vCommentText.Value
ElseIf TypeName(vCommentText) = "String" Then
strCommentText = vCommentText
Else
strCommentText = ""
End If

If strCommentText <> "" Then
rngBezug.AddComment strCommentText
SetComment = rngBezug.Comment.Text = strCommentText
End If

End Sub

----------------------------------------------------------------------------

Die Kommentare werden in einem extra Blatt aufgeführt und dann über =wenn(A1="Test";setcomment(A1;D13);setcomment(A1;"")) mit der richtigen Zelle verlinkt.

Dies funktioniert auch einwandfrei.

Allerdings hätte ich es nun gerne, dass diese Kommentarfelder die Größe automatisch anpassen.
Nun ist ja Standard Schriftgröße 9 Fett und die übliche Feldgröße.

Ich bräuchte Schriftgröße 9 nicht fett und eine automatische Feldgrößen-Anpassung das alles reinpasst.

Oder besteht auch die Möglichkeit, dass die Formatierung von der Zelle wo der Kommentar eingepflegt ist
übernommen wird?


Ich hoffe ihr könnt mir weiterhelfen.

Gruß Alex

 

Hallo Alex,

da es in der Regel nicht bzw. nur im beschränkten Ausmaß möglich ist, mit Hilfe von benutzerdef. VBA-Funktionen Werte ins Arbeitsblatt auszugeben außer über den Funktionsrückgabewert, habe ich deine Funktion so belassen, wie sie ist, und habe in mehreren SUB-Beispielen die Kommentarformatierung demonstriert.
Die SUBs "AuswahlKommentarFormatierenX" formatieren jeweils die Kommentare des ausgewählten Zellbereichs im aktiven Arbeitsblatt und sind nur als Beispiele für den Einsatz der "Sub SetCommentFormat(rngBezug As Range, Optional arrFont as Variant)" gedacht.

Falls über den Parameter "arrFont" kein Zeichensatz angegeben wird (wie zB. in der SUB AuswahlKommentareFormatieren0()) wird jeweils der Zeichensatz der Zelle verwendet, in der sich der Kommentar befindet. Falls du eine andere Methode haben möchtest, müsstest du im Bereich der beiden unterstrichenen Makrostellen deine Änderungen vornehmen.
Ferner ist die Default-Zeichengröße =9 und die Fett/Kursiv/Unterstrich/Durchstreichung-Auszeichnung defaultmäßig ausgeschaltet.

Code:

Sub AuswahlKommentareFormatieren0()
  Dim Zelle As Range
  For Each Zelle In Selection.Cells
    SetCommentFormat Zelle
  Next Zelle
End Sub

Sub AuswahlKommentareFormatieren1()
  Dim Zelle As Range
  For Each Zelle In Selection.Cells
    SetCommentFormat Zelle, Array("Times New Roman")
  Next Zelle
End Sub

Sub AuswahlKommentareFormatieren6()
  Dim Zelle As Range
  For Each Zelle In Selection.Cells
    SetCommentFormat Zelle, Array("Symbol", 21, True, True, True, True)
  Next Zelle
End Sub

Sub SetCommentFormat(rngBezug As Range, Optional arrFont As Variant)
  Dim ftName As String, I As Integer
  With rngBezug
      On Error GoTo Err_SetComm
      
      [U]ftName$ = .Font.Name[/U]
      If IsMissing(arrFont) Then I = -1 Else I = UBound(arrFont)
      
      With .Comment.Shape.TextFrame
        .AutoSize = True
        With .Characters.Font
          If I <= -1 Then .Name = [U]ftName$[/U] Else .Name = arrFont(0)
          If I <= 0 Then .Size = 9 Else .Size = arrFont(1)
          If I <= 1 Then .Bold = False Else .Bold = arrFont(2)
          If I <= 2 Then .Italic = False Else .Italic = arrFont(3)
          If I <= 3 Then .Underline = False Else .Underline = arrFont(4)
          If I <= 4 Then .Strikethrough = False Else .Strikethrough = arrFont(5)
        End With
      End With
  End With
Err_SetComm:
End Sub

 

Hi,

danke für deine Antwort.

Und wie genau müsste ich es nun eingeben? So dass es auch automatisch dann funktioniert?

Bin leider nicht so wirklich ein VBAler :)


Gruß Alex