Office: Komplizierte Formel

Hallo,

mit meinem Wissen komme ich hier leider nicht mehr weiter, da man keine sau lange Formel bauen kann.
Das ist schonmal die Tabelle. Die Stufeneintritte werden mit dem heitigen Datum vergleichen und "Nächste Stufe" hüpft dann automatisch zur richtigen Position. Das ist nicht das Problem.

15.10.2009
Stufungen: 210
Stufe Stufeneintritt
1 04.05.1980
2 05.05.1985
3 05.05.1990
4 05.05.1995
5 04.05.2000
Nächste Stufe 6 04.05.2010


Problem ist jetzt, das ich ein Feld haben will, indem die Stufung und die aktuelle Stufe drinne steht. In diesem Beispiel wäre es jetzt, 210 / 5, weil die 6 Stufe am 04.05.2010 wäre. Ab dem 04.05.2010 müsste dann 210 / 6 angezeigt werden.

Das ist meine momentane Formel die auch so klappt. Das problem ist jetzt, das 2 Stufungen wie 209 und 207 dazu kommen und dann wäre diese Formal zulang!

=WENN(ODER(Start!Z6="";Start!Z8="");"";WENN(UND(Start!Z6=210;Start!X8="Nächste Stufe");"210 / 1";WENN(UND(Start!Z6=210;Start!X9="Nächste Stufe");"210 / 1";WENN(UND(Start!Z6=210;Start!X10="Nächste Stufe");"210 / 2";WENN(UND(Start!Z6=210;Start!X11="Nächste Stufe");"210 / 3";WENN(UND(Start!Z6=210;Start!X12="Nächste Stufe");"210 / 4";(WENN(UND(Start!Z6=210;Start!X13="Nächste Stufe");"210 / 5";"210 / 6"))))))))

Das "Start!" ist das tabellenblatt.

Wäre super wenn jemand eine Idee hätte.

Gruß Patrick

 

Hallo!

Vielleicht so?

	A	B	C
1	15.10.2009
2	Stufungen	210
3
4	Stufe	Stufeneintritt
5	1	04.05.1980
6	2	05.05.1985
7	3	05.05.1990
8	4	05.05.1995
9	5	04.05.2000
10	6	04.05.2010	Nächste Stufe
11
12	210 / 5

Zelle	Formel
A1	=HEUTE()
C5	{=WENN(B5=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C6	{=WENN(B6=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C7	{=WENN(B7=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C8	{=WENN(B8=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C9	{=WENN(B9=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C10	{=WENN(B10=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
A12	=B2&" / "&INDEX(A5:A10;VERGLEICH("Nächste Stufe";C5:C10;)-1)

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Die Formel vom Feld a12 ist super! Bisher hat die alle meine Test überstanden. Könntest du mir diese vielleicht erklären? Weiß bisher nur, dass diese funktioniert, aber wie ist mir noch ein Rätsel

 

Hallo!

VERGLEICH("Nächste Stufe";C5:C10;)
liefert die Zeile, in der "Nächste Stufe" steht; hier also 6 (6. Zeile von C5:C10).
Du suchst den Wert, der eine Zeile darüber steht, also minus 1, ergibt 5.

INDEX(A5:A10;5)
liefert den Eintrag aus der 5. Zeile von A5:A10.

 

So jetzt habe ich ein anderes Problem. Bei A12 kommt jetzt eine Lohnstufe raus wie z. B. 209/6 und dazu kriegt man ein Monatsentgeld in höhe von 2.000€ z.B.

Die daten stehen in einer Tabelle neben der Rechung
Lohnart Monatseltgeld
209/6 2.000€

Und ich will jetzt in ein anderes Feld das monatliche Entgelt angezeigt bekommen. Mit Sverweis funktioniert das nicht so recht. In Feld A13

Gruß Patrick

 

Hallo!

Warum denn nicht?

	A	B	C	D	E	F	G
1	15.10.2009					Lohnart	Monatsentgelt
2	Stufungen	210				210 / 1	1800
3						210 / 2	2000
4	Stufe	Stufeneintritt				210 / 3	2200
5	1	04.05.1980				210 / 4	2400
6	2	05.05.1985				210 / 5	2600
7	3	05.05.1990				210 / 6	2800
8	4	05.05.1995
9	5	04.05.2000
10	6	04.05.2010	Nächste Stufe
11
12	210 / 5	2600

Zelle	Formel
A1	=HEUTE()
C5	{=WENN(B5=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C6	{=WENN(B6=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C7	{=WENN(B7=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C8	{=WENN(B8=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C9	{=WENN(B9=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
C10	{=WENN(B10=MIN(WENN(B$5:B$10>=A$1;B$5:B$10));"Nächste Stufe";"")}
A12	=B2&" / "&INDEX(A5:A10;VERGLEICH("Nächste Stufe";C5:C10;)-1)
B12	=SVERWEIS(A12;F:G;2;)

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Hallo,

also ich weiß nicht, warum es nicht funktioniert. Habe alles genau so wie du eingeben auf meine Tabelle, aber der will das monatliche Entgelt nicht erscheinen lassen. Stattdessen steht da jetzt #NV. Was für ein Problem könnte jetzt vorliegen?

 

Hallo!

#NV! bedeutet "nicht verfügbar".
Bist du sicher, dass die Einträge aus deiner Referenztabelle EXAKT so aussehen wie in A12?
Ein einzelnes Leerzeichen kann dir da schon einen Strich durch die Rechnung machen!

 

Hallo,

du hattes recht!! Hatte zwischen 209/1 keine Leerzeichen gehabt. Jetzt funktioniert alles, wie ich es mir vorgestellt hatte.

Herzlichen Dank. War eine super Hilfe!!!

Schöne Grüße aus Duisburg