Office: (Office 2003) Komplizierter Excel Import

Helfe beim Thema Komplizierter Excel Import in Microsoft Access Hilfe um das Problem gemeinsam zu lösen; Nicht schlecht. Das lässt sich dann folgendermaßen nutzen: OK, ich sehe mit Freuden, dass es auch einfacher geht! (s.o.) Dieses Thema im Forum "Microsoft Access Hilfe" wurde erstellt von ElBirn, 15. Oktober 2007.

Seite 4 von 5

ANNE BERG

Anne Berg

Komplizierter Excel Import

Nicht schlecht. Das lässt sich dann folgendermaßen nutzen:

OK, ich sehe mit Freuden, dass es auch einfacher geht! (s.o.)

Anne Berg, 18. Oktober 2007

#46
JOSEF P.

Josef P.

Warum seid ihr nicht bei der Recordset-Variante (verknüpfte Tab) geblieben?
Die Daten per Excel-Automation auszulesen ist ja nicht unbedingt die schnelle Art. *wink.gif*

Ich hätte so eine Variante probiert (nur Luftcode!):
Code:

set rst = db.Openrecordset("SELECT from ExcelTab where 1=0")
with rst
for i = 1 to (rst.fields.count-1)
strSQL = "INSERT INTO Tabl (id, Wert) SELECT idFeld, [" & .fields(i).name & "] from ExcelTab"
db.execute strsql, dbfailonerror
next i
.close
end with
set rst = nothing
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Josef P., 18. Oktober 2007

#47
ANNE BERG

Anne Berg

Hallo Josef,
schön, dass du dich nochmal dazu meldest. Leider verstehe ich nicht ganz, wie du dir das vorstellst. Das Recordset ist aufgrund des Kriteriums leer - was willst du da auslesen? OK, die Feldliste, aber was tun damit?

Das Problem ist, dass die Tabelle aus zwei Zeilen mit Texten besteht und dann folgen Zahlen (Beträge) mit einem Datum. Egal wie man's macht, entweder gibt es keine Texte oder keine Zahlen, sondern jeweils Fehler in den Feldern der verlinkten Excel-Tabelle. Die einzige Lösung wäre, sie zu teilen, aber da hatte Lucas Bedenken, er könne die korrekten Bezüge von Firma zu Kursen verlieren.

Ich hätte mir das auch nicht so schwierig vorgestellt. Das Problem fing damit an, dass beim Importieren Daten verloren gingen, wegen der max. Zeichen pro Datensatz...

Anne Berg, 18. Oktober 2007

#48
JOSEF P.

Josef P.

Komplizierter Excel Import

aus dem 1. Recordset lese ich nur die Feldnamen, mit denen ich dann eine Insert-Anweisung für jede Spalte erstelle.
Das mit den 2 Text-Zeile ist mir nicht aufgefallen: in diesem Fall würde ich per Excel-Automatition die ersten 2 Zeilen in eine Tabelle einfügen und dann gleich die daraus enthaltene ID in die 1. Zeile im Excel-Blatt schreiben. (damit ist auf jeden Fall schon einmal der Bezug für die Datumsfelder fixiert.)
Dann die 2. Zeile löschen, damit nur noch Feldnamen und Datenwerte vorhanden sind. Ab dann sollte eine Verküpfung keine Probleme bereiten.
Diese verknüpfte Tabelle wird dann mit dem von mir gezeigten Schema in eine weitere Tabelle übertragen.

/edit: imo wird Code bereits eindeutig sein, damit fällt der Umweg über die ID weg.

Josef P., 18. Oktober 2007

#49
ANNE BERG

Anne Berg

Es geht aber nicht um Feldnamen dabei, sondern um die Inhalte der Textzeilen.

Na ja, die Idee gab es wohl anfangs schon mal, auf die Informationen der 2. Zeile zu verzichten und diese später irgendwie nachzuerfassen. Das dürfte bei der Menge aber auch kein Vergnügen sein...
Wenn nur die Inhalte alle korrekt ausgelesen würden, könnte man immerhin aus den Überschriften wieder Datenfeldinhalte machen. *wink.gif*

Ich fürchte, es wird ihm letztenldlich nichts anderes übrig bleiben, weil die Laufzeit ansonsten in den Stundenbereich gehen dürfte. *frown.gif*

Anne Berg, 18. Oktober 2007

#50
JOSEF P.

Josef P.

Ein Codebeispiel: ... ganz ohne Excel-Automation *wink.gif*
Code:

Option Compare Database
Option Explicit

Private Const mcon_ExcelFile As String = "F:\Transfer\IPO_Kurse_Test.xls"
Private Const mcon_ExcelBlattName As String = "Tabelle1"

Private Sub ImportDaten()

Dim strSQL As String
Dim db As DAO.Database
Dim rst As DAO.Recordset

Dim i As Long

strSQL = "SELECT * FROM [Excel 5.0;HDR=YES;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & mcon_ExcelBlattName & "$2:2]"
Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL)
With rst
'mach was mit den daten
' ... hier Insert-Schleife einbauen
For i = 1 To (rst.Fields.Count - 1)
strSQL = "INSERT INTO tabDaten (Code, KursDatum, KursWert) SELECT '" & .Fields(i).Name & "', Code AS KursDatum, [" & .Fields(i).Name & "]" & _
"FROM [Excel 5.0;HDR=YES;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & mcon_ExcelBlattName & "$2:65000]"
db.Execute strSQL, dbFailOnError
Next i
.Close
End With

End Sub

Private Sub ImportKopf()

Dim strSQL As String
Dim db As DAO.Database
Dim rst As DAO.Recordset
strSQL = "SELECT * FROM [Excel 5.0;HDR=NO;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & mcon_ExcelBlattName & "$1:2]"
Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL)
With rst
'mach was mit den 2 Kopfzeilen ... die im DS 1 und 2 stehen.
.Close
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...auf die Informationen der 2. Zeile zu verzichten ...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In meinem Beispiel verzichte ich beim Datenimport auf die 1. Zeile. *wink.gif*

Josef P., 18. Oktober 2007

#51
ANNE BERG

Anne Berg

Mensch, das habe ich den ganze Zeit gesucht, wie man auf einen Tabellenbereich zugreifen kann! *Smilie

Da werde ich die Sache doch noch einmal in Angriff nehmen...

Anne Berg, 18. Oktober 2007

#52
JOSEF P.

Josef P.

Komplizierter Excel Import

Hier noch der Code zum Einlesen der Kopfdaten:
Code:

Private Sub ImportKopf_v2()

Dim strSQL As String
Dim db As DAO.Database
Dim rst As DAO.Recordset

Dim i As Long

strSQL = "SELECT * FROM [Excel 5.0;HDR=Yes;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & mcon_ExcelBlattName & "$1:2]"
Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL)
With rst
For i = 1 To (rst.Fields.Count - 1)
strSQL = "INSERT INTO tabCode (Code, CodeName) SELECT [" & .Fields(i).Name & "], '" & .Fields(i).Name & "'" & _
"FROM [Excel 5.0;HDR=YES;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & mcon_ExcelBlattName & "$1:2]"
db.Execute strSQL, dbFailOnError
Next i
.Close
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Mit GetRows hätte es natürlich auch funktioniert, dann ist aber HDR=NO notwendig, damit beide Kopfzeilen im Recordset vorkommen.

Josef P., 18. Oktober 2007

#53
ANNE BERG

Anne Berg

Hallo Josef,

mit Hilfe deiner Prozeduren sollte sich das Import-Problem doch noch auf akzeptable weise lösen lassen. Ich habe das alles inzwischen mal getestet und bin begeistert. *Smilie

Was mir fehlte, war die Syntax für den Direktzugriff auf eine Excel-Tabelle, inkl. Auswahl des Zell-Bereichs.

Anne Berg, 18. Oktober 2007

#54
JOSEF P.

Josef P.

Die Prozeduren sind sogar - zumindest vom Ansatz her - für den Import von mehreren Tabellenblättern vorbereitet. *wink.gif*
Es muss nur noch die Konstante mcon_ExcelBlattName gegen eine Variable ausgetauscht werden.

Josef P., 18. Oktober 2007

#55
ELBIRN

ElBirn

Hallo zusammen,

an meinem Problem hat sich während meiner Abwesenheit jede Menge getan :-) und es scheint auch problemlos zu funktionieren!!!

Danke euch beiden... ohne eure Hilfe hätte ich das nie geschafft!

Wie kann ich denn mehrere Blätter auf einmal importieren? Hab nicht so ganz verstanden wie Josef das meint!

Gruß

Lucas

ElBirn, 18. Oktober 2007

#56
JOSEF P.

Josef P.

Ausnahmsweise noch einmal ein vollständiges Code-Beispiel. *wink.gif*
Code:

Option Compare Database
Option Explicit

Private Const mcon_ExcelFile As String = "F:\Transfer\IPO_Kurse_Test.xls"
' Private Const mcon_ExcelBlattName As String = "Tabelle1" ... ersetzt durch Variable
Private m_ExcelBlattName As String
Private m_ExcelBlattAnzahlZeilen As Long
'

Private Sub ImportBlaetter()

'early binding:
'Dim xlsWorkBook As Excel.Workbook
'Dim xlsWorkSheet As Excel.Worksheet

'late binding:
Dim xlsApplication As Object
Dim xlsWorkBook As Object
Dim xlsWorkSheet As Object
Const xlUp = -4162

'1. Daten aus Tabellen löschen, da sie neu eingelesen werden
vorhandeneTabellenDatenLoeschen

'2. Daten neu einlesen
Set xlsApplication = CreateObject("Excel.Application")
xlsApplication.Visible = True
Set xlsWorkBook = xlsApplication.Workbooks.Open(mcon_ExcelFile)

For Each xlsWorkSheet In xlsWorkBook.Sheets

'prüfen ob in A Werte stehen ... wenn ja, dann wird das ein Blatt für den Import sein.
m_ExcelBlattAnzahlZeilen = xlsWorkSheet.Cells(xlsWorkSheet.Rows.Count, 1).End(xlUp).Row
If m_ExcelBlattAnzahlZeilen >= 2 Then '2, damit zumindest Kopf vorhanden ist
'Tabellennamen einstellen
m_ExcelBlattName = xlsWorkSheet.Name
Debug.Print m_ExcelBlattName & " ...";

'Kopfdaten einlesen
ImportKopf

'Detaildaten einlesen
ImportDaten

Debug.Print " wurde importiert"
End If

Next xlsWorkSheet

xlsWorkBook.Close
Set xlsWorkBook = Nothing
xlsApplication.Quit
Set xlsApplication = Nothing

End Sub

Private Sub vorhandeneTabellenDatenLoeschen()
Dim db As DAO.Database
Set db = CurrentDb
db.Execute "Delete from tabCode"
db.Execute "Delete from tabDaten"
Set db = Nothing
End Sub

Private Sub ImportDaten()

Dim strSQL As String
Dim db As DAO.Database
Dim rst As DAO.Recordset

Dim i As Long

strSQL = "SELECT * FROM [Excel 5.0;HDR=YES;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & m_ExcelBlattName & "$2:2]"
Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL)
With rst
For i = 1 To (rst.Fields.Count - 1)
strSQL = "INSERT INTO tabDaten (Code, KursDatum, KursWert) SELECT '" & .Fields(i).Name & "', Code AS KursDatum, [" & .Fields(i).Name & "]" & _
"FROM [Excel 5.0;HDR=YES;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & m_ExcelBlattName & "$2:" & m_ExcelBlattAnzahlZeilen & "]"
'Anm.: die Spalte "Code" steht in der Excel-Tabelle für das Datumsfeld
db.Execute strSQL, dbFailOnError
Next i
.Close
End With
Set rst = Nothing
Set db = Nothing

End Sub

Private Sub ImportKopf()

Dim strSQL As String
Dim db As DAO.Database
Dim rst As DAO.Recordset

Dim i As Long
Dim A As Variant

strSQL = "SELECT * FROM [Excel 5.0;HDR=NO;IMEX=2;DATABASE=" & mcon_ExcelFile & "].[" & m_ExcelBlattName & "$1:2]"
Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL)
With rst
A = .GetRows(2)
For i = 1 To (rst.Fields.Count - 1)
strSQL = "INSERT INTO tabCode (Code, CodeName) Values ('" & A(i, 1) & "', '" & A(i, 0) & "')"
db.Execute strSQL, dbFailOnError
Next i
.Close
End With
Set rst = Nothing
Set db = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Josef P., 18. Oktober 2007

#57
JOSEF P.

Josef P.

Komplizierter Excel Import

Mir ist gerade etwas aufgefallen: Warum bleibt beim vorigen Code eine Excel-Instanz offen?
... sobald ich ImportKopf und ImportDaten ausklammere wird alles geschlossen.

Mit dieser Funktion gibt es auch keine offene Instanz nach Codeende:
Code:

Private Sub ImportBlaetter()

'early binding:
' Dim xlsApplication As Excel.Application
' Dim xlsWorkBook As Excel.Workbook
' Dim xlsWorkSheet As Excel.Worksheet

'late binding:
Dim xlsApplication As Object
Dim xlsWorkBook As Object
Dim xlsWorkSheet As Object
Const xlUp = -4162

Dim ArrWorkSheetsInfo() As Variant
Dim strWorkSheetName As String
Dim i As Long

'1. Daten aus Tabellen löschen, da sie neu eingelesen werden
vorhandeneTabellenDatenLoeschen

'2. Daten neu einlesen
'Variante 1:
'Set xlsApplication = CreateObject("Excel.Application")
'xlsApplication.Visible = True
'Set xlsWorkBook = xlsApplication.Workbooks.Open(mcon_ExcelFile)
'Variante 2: (einfacher):
Set xlsWorkBook = CreateObject(mcon_ExcelFile)

'Namen Tabellenblätter einlesen
ReDim ArrWorkSheetsInfo(1, xlsWorkBook.Sheets.Count - 1)
i = 0
For Each xlsWorkSheet In xlsWorkBook.Sheets
'prüfen ob in A Werte stehen ... wenn ja, dann wird das ein Blatt für den Import sein.
m_ExcelBlattAnzahlZeilen = xlsWorkSheet.Cells(xlsWorkSheet.Rows.Count, 1).End(xlUp).Row
If m_ExcelBlattAnzahlZeilen >= 2 Then '2, damit zumindest Kopf vorhanden ist
'Tabellennamen einstellen
m_ExcelBlattName = xlsWorkSheet.Name
ArrWorkSheetsInfo(0, i) = m_ExcelBlattName
ArrWorkSheetsInfo(1, i) = m_ExcelBlattAnzahlZeilen
i = i + 1
End If
Next xlsWorkSheet
If i > 0 Then
ReDim Preserve ArrWorkSheetsInfo(1, i - 1)
Else
MsgBox "Keine Tabellenblätter zum Einlesen verfügbar!"
Exit Sub
End If

Set xlsWorkSheet = Nothing
xlsWorkBook.Close
Set xlsWorkBook = Nothing
'xlsApplication.Quit ' ... bei Variante 1 notwendig
'Set xlsApplication = Nothing

'Daten importieren
For i = LBound(ArrWorkSheetsInfo, 2) To UBound(ArrWorkSheetsInfo, 2)

'Zugriffsvariablen einstellen
m_ExcelBlattName = ArrWorkSheetsInfo(0, i)
m_ExcelBlattAnzahlZeilen = ArrWorkSheetsInfo(1, i)

Debug.Print m_ExcelBlattName & " ...";

'Kopfdaten einlesen
ImportKopf

'Detaildaten einlesen
ImportDaten

Debug.Print " wurde importiert"

Next i

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Josef P., 19. Oktober 2007

#58
JOSEF P.

Josef P.

Ich fand die Antwort. *Smilie

Excel will mir eine Meldung schicken, dass die Datei nun für den Schreibzugriff zur Verfügung steht. (Das macht Excel aber erst, nachdem ich keinen Zugriff mehr auf Excel habe.)
Öffne ich ReadOnly per:
Code:

Set xlsWorkBook = xlsApplication.Workbooks.Open(m_ExcelFile, , True)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ist alles in Ordnung.

Falls jemand testen will: siehe Anhang. (Modul2 ist der "Problem-Code")

Josef P., 19. Oktober 2007

#59
SASCHA TROWITZSCH

Sascha Trowitzsch

Hi Josef,

Nun bist du mir mit "Expertenblick" zuvorgekommen. *wink.gif*
Hatte erst noch mit dem ODBC-API aus dem anderen Thread zu tun. *tongue.gif*
Schön!

Gruß, Sascha

Sascha Trowitzsch, 19. Oktober 2007

#60

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 4 von 5

Thema:

Komplizierter Excel Import

Die Seite wird geladen...

Komplizierter Excel Import - Similar Threads - Komplizierter Excel Import
Erbitte komplizierte Formel Wenn,dann oder wenn dies, dann
in Microsoft Excel Hilfe
Erbitte komplizierte Formel Wenn,dann oder wenn dies, dann: Hallo liebe Wissende, folgende 3 Probleme schaffe ich, als Laie, auch mit Hilfe des Internets nicht zu lösen. Mir wird monatlich eine csv-Datei mit folgenden Daten zur Verfügung gestellt. Ich...
Berechung monatl. Kosten
in Microsoft Excel Hilfe
Berechung monatl. Kosten: Hallo zusammen, ich habe mal eine Excel erstellt, die versucht mein Problem etwas näher zu beschreiben. Gegeben ist eine Tabelle, welche Daten enthält, sowie ein Projekt, welches an dem Tag...
Hilfe bei Formel-Vereinfachung/-Kürzung
in Microsoft Excel Hilfe
Hilfe bei Formel-Vereinfachung/-Kürzung: Hallo zusammen, ich stehe gerade auf dem Schlauch bei der Vereinfachung/Kürzung einer Formel. Mein aktuelles Ziel ist es in Excel die Umsätze bei der Einstellung neuer Vertriebsmitarbeiter zu...
Prüfen und Verketten von Zellen mit Formeln als Inhalt
in Microsoft Excel Hilfe
Prüfen und Verketten von Zellen mit Formeln als Inhalt: Sehr geehrte Damen und Herren, ich möchte in einer Excel Tabelle ca. 72 Zellen miteinander verketten und prüfen, ob diese gefüllt sind, falls manche dieser Zellen leer sind sollen diese aus der...
Komplizierter Blattschutz
in Microsoft Excel Hilfe
Komplizierter Blattschutz: Hi, ich brauchte Unterstützung bei der Umsetzung eines Schreibschutzes/Blattschutzes. Dieser Schutz soll folgendermaßen aussehen: 1. Insgesamt habe ich 10 Tabellenblätter die geschützt werden...
Tastenkombination für die Texthervorhebunsfarbe möglich? + 2. komplizierte Frage
in Microsoft Word Hilfe
Tastenkombination für die Texthervorhebunsfarbe möglich? + 2. komplizierte Frage: Hallo! Schon vorab vielen lieben Dank, falls jemand eine Idee hat für mich. Ich habe zwei Fragen, ob gewisse Funktionen in Microsoft Word 2010 möglich sind: 1. Ich nutze in beim Verfassen...
komplizierte (für mich :D) formel zur berechnung in excel
in Microsoft Excel Hilfe
komplizierte (für mich :D) formel zur berechnung in excel: Hallo Leute! Habe eine Tabelle mit Daten (5x16 Felder), in einer anderen Tabelle habe ich Dropdown-Listen zur Auswahl, je nachdem was ich auswähle möchte ich dass er mir gernau einen Wert aus der...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden