Office: (Office 2003) Kopieren mehrerer Datensätze mit deren in Beziehung stehenden DS

Adversarius · 10. März 2014

Also, jetzt kommt weiterhin die "Argument ist nicht optionalmeldung":

(Rot ist der markierte Bereich beim debugging)

'1.)
Public Sub ProjektKopierenZuAuftrag(ByVal ZuKopierendeProjektNr_PZA As String, ByVal ZuKopierendeEntwurfNr_PZA As Long, ByVal NeueAuftragsNr As Long)
'Öffnet die jeweilige Abfrage mit den nachgenannten Parametern, die aus 2.) übernommen werden:
OpenProjektzuAuftragQueryDef "qryProjektzuAuftrag", ZuKopierendeProjektNr_PZA, NeueAuftragsNr 'ZuKopierendeEntwurfNr_PZA nicht notwendig
OpenProjektzuAuftragQueryDef "qryProjektzuAuftragPositionen", ZuKopierendeProjektNr_PZA, NeueAuftragsNr, ZuKopierendeEntwurfNr_PZA
OpenProjektzuAuftragQueryDef "qryProjektzuAuftragPosDetails", ZuKopierendeProjektNr_PZA, NeueAuftragsNr, ZuKopierendeEntwurfNr_PZA

End Sub

'2.) Definition der Parameter die in 1.) "ProjektKopierenZuAuftrag" aufgerufen werden KÖNNEN:
Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, ByVal ZuKopierendeProjektNr_PZA As String, ByVal ZuKopierendeEntwurfNr_PZA As Long, NeueAuftragsNr As Long)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)
qdf.Parameters("ZuKopierendeProjektNr_PZA") = ZuKopierendeProjektNr_PZA '("Name in Abfrage") = Name im Code
qdf.Parameters("ZuKopierendeEntwurfNr_PZA") = ZuKopierendeEntwurfNr_PZA '("Name in Abfrage") = Name im Code
qdf.Parameters("NeueAuftragsNr") = NeueAuftragsNr '("Name in Abfrage") = Name im Code
qdf.Execute 'führt SQL-Anweisung der qdf´s aus

End Sub

'3.)
Public Function ProjektzuAuftrag(ByVal ZuKopierendeProjektNr_PZA As String, _
ByVal ZuKopierendeEntwurfNr_PZA As Long) As Long

Dim NeueAuftragsNr As Long

NeueAuftragsNr = Me!AuftragsNr_F1 'Beziehe NeueAuftragsNr aus dem Formularfeld

'führe 1.) Public Sub ProjektKopierenZuAuftrag und übergebe dafür die nachgenannten Parameter:
ProjektKopierenZuAuftrag ZuKopierendeProjektNr_PZA, ZuKopierendeEntwurfNr_PZA, NeueAuftragsNr

'Übergebe "NeueAuftragsNr" an Projekt zu Auftrag
ProjektzuAuftrag = NeueAuftragsNr

End Function

'4.)
Private Sub Projekt_zu_Auftrag_B_Click()
If IsNull(Me!AuftragsNr_F1) Then
MsgBox "Sie müssen die neue Auftrags - N ummer festlegen !"
'raus aus der Prozedur, wenn keine neue Auftragsnummer angegeben wurde

Else:

Dim NeueAuftragsNr As Long

'übergebe Parameter aus den beiden Formularfeldern in NeueAuftragsNr an _
3.)Public Function ProjektzuAuftrag

NeueAuftragsNr = ProjektzuAuftrag(Me!ProjektNr_F1, Me!EntwurfNr_F1)

Me.Requery 'Aktualisierung des aktuellen Formulares
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich habe den Verdacht, dass dies an der nicht zugewiesenen "ZuKopierendeEntwurfNr_PZA" liegt, aber diese wird in der AUFDaten_Tabelle nicht benötigt (vgl. gif Beziehungen)?

Josef P. · 10. März 2014

Ach komm! Das ist doch wieder das gleiche Prinzip.

Aufruf:
Code:

OpenProjektzuAuftragQueryDef "qryProjektzuAuftrag", _
ZuKopierendeProjektNr_PZA, NeueAuftragsNr 'ZuKopierendeEntwurfNr_PZA nicht notwendig
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Und wie sieht die Prozedur aus:
Code:

Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, ByVal ZuKopierendeEntwurfNr_PZA As Long, NeueAuftragsNr As Long)
...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

=> ZuKopierendeEntwurfNr_PZA wird von der Prozedur erwartet, auch wenn der Parameter später im Prozedur-Code nicht verwendet wird.

mfg
Josef

Adversarius · 10. März 2014

Ja völlig klar, aber ich habe den bewusst rausgelassen, weil mit der Entwurfsnummer die Meldung kommt "Element in dieser Auflistung nicht gefunden". (Die erste Abfrage übergibt nämlich keine Entwurfsnummer, da diese in Projektdaten noch nicht vorhanden ist).

Code:

OpenProjektzuAuftragQueryDef "qryProjektzuAuftrag", ZuKopierendeProjektNr_PZA, NeueAuftragsNr, ZuKopierendeEntwurfNr_PZA
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

so wäre es ja richtig!?

qdf.Parameters("ZuKopierendeEntwurfNr_PZA") = ZuKopierendeEntwurfNr_PZA '("Name in Abfrage") = Name im Code
wird markiert. Mit Auflistung ist doch eine /mehrere der Abfragen gemeint richtig?

Josef P. · 10. März 2014

Code:

OpenProjektzuAuftragQueryDef "qryProjektzuAuftrag", ZuKopierendeProjektNr_PZA, NeueAuftragsNr, ZuKopierendeEntwurfNr_PZA
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code:

Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, ByVal ZuKopierendeEntwurfNr_PZA As Long, NeueAuftragsNr As Long)
...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich bin der Meinung, so wäre es nicht richtig, weil du die Parameter vertauscht hast. *wink.gif*

Du musst die Parameter-Werte genau in der Reihenfolge an die Prozedur übergeben, wie sie in der Prozedur deklariert sind.

Wenn du die Prozedur OpenProjektzuAuftragQueryDef auch für Abfragen verwenden willst, die keinen Parameter "ZuKopierendeEntwurfNr_PZA" enthalten, könntest du dir eine Zahl als Parameterwert überlegen, die du im Code prüfst und falls dieser Wert enthalten ist, den Parameter nicht einstellst.

Z. B.:
Code:

Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, ByVal ZuKopierendeProjektNr_PZA As String, ByVal ZuKopierendeEntwurfNr_PZA As Long, NeueAuftragsNr As Long)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)
qdf.Parameters("ZuKopierendeProjektNr_PZA") = ZuKopierendeProjektNr_PZA '("Name in Abfrage") = Name im Code
if ZuKopierendeEntwurfNr_PZA -1 then
qdf.Parameters("ZuKopierendeEntwurfNr_PZA") = ZuKopierendeEntwurfNr_PZA
end if
qdf.Parameters("NeueAuftragsNr") = NeueAuftragsNr '("Name in Abfrage") = Name im Code
qdf.Execute 'führt SQL-Anweisung der qdf´s aus

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Aufruf:
Code:

OpenProjektzuAuftragQueryDef "qryProjektzuAuftrag", ZuKopierendeProjektNr_PZA, -1, NeueAuftragsNr
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich würde an dieser Stelle aber lieber eine extra Prozedur verwenden, damit es nicht irrtümlich zu einer falschen Verwendung kommt.

.. und damit dann nicht Code mehrfach vor kommt, könnte man eine extra Hilfsprozedur erstellen, an die man eine Parameterauflistung inkl. Werte übergibt und die dann die Abfrage-Parameter befüllt. (Das zeige ich jetzt aber nicht, da das nichts mit deinem Problem zu tun hat - ich will das nur erwähnen, da mir viel an "sauberem Code" liegt. *wink.gif*)

mfg
Josef

Adversarius · 10. März 2014

VIELEN, VIELEN DANK JOSEF!

Also jetzt funktioniert wirklich alles, sowohl Projektduplizierung, als auch Umwandlung in Auftrag. Ich habe jetzt auch alle Abläufe verstanden denk ich. Das Hauptproblem war wohl, dass ich die Übergaberichtungen jeweils falsch verstand habe.

Ich habe mir jetzt auch eine Hilfssub erstellt, ist das so "vernünftig/sauber"? (will das ja auch richtig lernen):
Code:

'1.)
Public Sub ProjektKopierenZuAuftrag(ByVal ZuKopierendeProjektNr_PZA As String, _
ByVal ZuKopierendeEntwurfNr_PZA As Long, ByVal NeueAuftragsNr As Long)
'Öffnet die jeweilige Abfrage mit den nachgenannten Parametern, die aus 2.) übernommen werden:
OpenProjektzuAuftragKOPFDATENQueryDef "qryProjektzuAuftrag", ZuKopierendeProjektNr_PZA, NeueAuftragsNr
OpenProjektzuAuftragQueryDef "qryProjektzuAuftragPositionen", ZuKopierendeProjektNr_PZA, ZuKopierendeEntwurfNr_PZA, NeueAuftragsNr
OpenProjektzuAuftragQueryDef "qryProjektzuAuftragPosDetails", ZuKopierendeProjektNr_PZA, ZuKopierendeEntwurfNr_PZA, NeueAuftragsNr

End Sub

'2.) Definition der Parameter die in 1.) "ProjektKopierenZuAuftrag" aufgerufen werden KÖNNEN:
Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, ByVal ZuKopierendeEntwurfNr_PZA As Long, NeueAuftragsNr As Long)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)
qdf.Parameters("ZuKopierendeProjektNr_PZA") = ZuKopierendeProjektNr_PZA
qdf.Parameters("ZuKopierendeEntwurfNr_PZA") = ZuKopierendeEntwurfNr_PZA
qdf.Parameters("NeueAuftragsNr") = NeueAuftragsNr
qdf.Execute 'führt SQL-Anweisung der qdf´s aus

End Sub

Private Sub OpenProjektzuAuftragKOPFDATENQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, NeueAuftragsNr As Long)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)
qdf.Parameters("ZuKopierendeProjektNr_PZA") = ZuKopierendeProjektNr_PZA '("Name in Abfrage") = Name im Code
qdf.Parameters("NeueAuftragsNr") = NeueAuftragsNr '("Name in Abfrage") = Name im Code
qdf.Execute 'führt SQL-Anweisung der qdf´s aus

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Josef P. · 10. März 2014

Hallo!

Noch ein kurzer Ausflug in den Programmierstil. *Smilie

Ich habe mir jetzt auch eine Hilfssub erstellt, ist das so "vernünftig/sauber"?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ein einfacher Test:
Wenn du deinen Code ansiehst und der Code-Ablauf ohne Kommentare verständlich ist, ist das ein gutes Zeichen. (Für mich sieht die Code übersichtlich und verständlich aus.)
Code, der nur mit extra Kommentar-Zeilen verständlich wird, dem schadet vermutlich eine Überarbeitung (Refactoring) nicht.

Jetzt komme ich aber noch einmal auf den bereits erwähnten Hinweis mit dem doppelten Code zurück.

Code:
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, _
ByVal ZuKopierendeEntwurfNr_PZA As Long, _
ByVal NeueAuftragsNr As Long)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)
qdf.Parameters("ZuKopierendeProjektNr_PZA") = ZuKopierendeProjektNr_PZA
qdf.Parameters("ZuKopierendeEntwurfNr_PZA") = ZuKopierendeEntwurfNr_PZA
qdf.Parameters("NeueAuftragsNr") = NeueAuftragsNr
qdf.Execute 'führt SQL-Anweisung der qdf´s aus

End Sub

Private Sub OpenProjektzuAuftragKOPFDATENQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, _
ByVal NeueAuftragsNr As Long)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)
qdf.Parameters("ZuKopierendeProjektNr_PZA") = ZuKopierendeProjektNr_PZA '("Name in Abfrage") = Name im Code
qdf.Parameters("NeueAuftragsNr") = NeueAuftragsNr '("Name in Abfrage") = Name im Code
qdf.Execute 'führt SQL-Anweisung der qdf´s aus

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Diese 2 Prozeduren haben einen sehr ähnlichen Ablauf - nur die Parameter sind etwas unterschiedlich.
=> Mit einer weiteren Hilfsprozedur (die dann übrigens global verwendbar wäre) könnte man den Code eventuell noch etwas übersichtlicher gestalten.

Code:

Public Sub ExecuteParamQdf(ByVal QueryDefName As String, ParamArray QdfParams() As Variant)

Dim qdf As DAO.QueryDef
Set qdf = CurrentDb.QueryDefs(QueryDefName)

Dim i As Long
For i = LBound(QdfParams) To UBound(QdfParams) - 1 Step 2
qdf.Parameters(QdfParams(i)) = QdfParams(i + 1)
Next

qdf.Execute dbFailOnError

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

An diese Prozedur können nach dem Parameter "QueryDefName" weitere Parameter (Anzahl ist nicht fixiert) übergeben werden.
Für diese Prozedur werden diese ParamArray-werte in folgender Reihenfolge benötigt:
"ParamName1", ParamWert1, "ParamName2", ParamWert2, ... , "ParamNameN", ParamWertN

Damit wird aus deinen 2 Prozeduren OpenProjektzuAuftragQueryDef und OpenProjektzuAuftragKOPFDATENQueryDef dieser Code:

Code:

Private Sub OpenProjektzuAuftragQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, _
ByVal ZuKopierendeEntwurfNr_PZA As Long, _
ByVal NeueAuftragsNr As Long)

ExecuteParamQdf QueryDefName, _
"ZuKopierendeProjektNr_PZA", ZuKopierendeProjektNr_PZA, _
"ZuKopierendeEntwurfNr_PZA", ZuKopierendeEntwurfNr_PZA, _
"NeueAuftragsNr", NeueAuftragsNr

End Sub

Private Sub OpenProjektzuAuftragKOPFDATENQueryDef(ByVal QueryDefName As String, _
ByVal ZuKopierendeProjektNr_PZA As String, _
ByVal NeueAuftragsNr As Long)

ExecuteParamQdf QueryDefName, _
"ZuKopierendeProjektNr_PZA", ZuKopierendeProjektNr_PZA, _
"NeueAuftragsNr", NeueAuftragsNr

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ein Problem sehe ich bei der Prozedur "ExecuteParamQdf": Man kann nicht über den Compiler prüfen, ob der Programmierer die Parameter richtig übergeben hat.
Das ist jetzt zwar nicht sehr schlimm - aber auch nicht ganz sauber. - Ein Kompromiss zw. "sauber" und "komfortabel unter VBA" *Smilie

"Sauberer"/fehlervermeidender wäre eine Übergabe einer Parameter-Auflistung (Collection o. ä.), die man wieder über eine weitere Hilfsfunktion erstellt und in der dann fix auf den Parametername sowie der Parameterwert zugegriffen wird und nicht "gehofft" wird, dass der Programmierer diese Werte abwechselnd ins ParamArray schrieb.

=>
Code:

For each param in ParamCollection
qdf.Parameters(param.Name) = param.Value
Next
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn so eine ähnliche Schleife genutzt werden kann, kann es zu keiner Verwechslung zw. Parametername und Parameterwert kommen.

mfg
Josef

Office: (Office 2003) Kopieren mehrerer Datensätze mit deren in Beziehung stehenden DS

Kopieren mehrerer Datensätze mit deren in Beziehung stehenden DS

Kopieren mehrerer Datensätze mit deren in Beziehung stehenden DS

Kopieren mehrerer Datensätze mit deren in Beziehung stehenden DS

Kopieren mehrerer Datensätze mit deren in Beziehung stehenden DS - Similar Threads - Kopieren mehrerer Datensätze

Werte aus mehreren Spalten kopieren und darunter einfügen

Kontrollkästchen (mehrere) Makro kopieren, Problem: Zellen nicht gegenseitig überschreiben

Daten aus mehreren Blättern kopieren

Tastaturbefehle Ctrl + C, Ctrl + V, Ctrl + X funktionieren in Word nicht mehr

Mehrere Zellen aus geschlossener Datei kopieren

Mehrere Datensätze markieren, kopieren und mit aktuellem Datum einfügen

Makro VBA: Kopieren aus Quelldatei nach Zieldatei über mehrere Tabellen