Office: (Office 2010) Kopieren von Zeilen mit Datumseingrenzung

Hallo Zusammen,

ich habe folgendes Problem.
In meinem Code soll ein Wertebereich abhängig von einer Datumsangaben kopiert werden. Die Daten ("Datum von" / "Datum bis") stehen in seperaten Zellen im Arbeitsblatt "Anwendung".

Diese "Datums-Range" möchte ich gerne im Bereich
"Wsh_Quelle.Range("A67:J87")"
berücksichtigen.

Also sowas in die Richtung:
"Kopiere Wsh_Quelle.Range("A:J") alle Zeilen mit Datum in Spalte A zwischen "Datum von" und "Datum bis"

Über Hilfe würde ich mich freuen.


Code:

Code:

Private Sub Werte_holen_Click()


Dim WkBk_Quelle  As Workbook   ' das Herkunfts-Workbook - die Quelle
Dim WSh_Quelle   As Worksheet  ' das Herkunfts-Tabellenblatt
Dim WkBk_Ziel    As Workbook   ' das Empfangs-Workbook - das Ziel
Dim WSh_Ziel     As Worksheet  ' das Empfangs-Tabellenblatt
Dim i As Integer
For i = 4 To 43


Set WkBk_Ziel = ActiveWorkbook  ' diese Datei ist das Ziel !!!
Set WSh_Ziel = WkBk_Ziel.Worksheets(ThisWorkbook.Worksheets("Anwendung").Range("G" & i).Value)   ' das Tabellenblatt ggf. anpassen !!!
Application.ScreenUpdating = False                                                               ' den Bildschirm-Update unterdrücken

Set WkBk_Quelle = Workbooks.Open(Filename:= _
"D:\Anwenderdateien\2-Außenanlagen\Pumpwerke\1-Bestand\" & _
"Datenbank-PW.xlsm", ReadOnly:=True)                                                              ' die Herkunfts-Datei - die Quelle - öffnen

Set WSh_Quelle = WkBk_Quelle.Worksheets(ThisWorkbook.Worksheets("Anwendung").Range("F" & i).Value) ' das Tabellenblatt benennen
With WSh_Quelle                                                                                     ' mit dem jeweiligen Tabellenblatt arbeiten
.Range("A67:J87").Copy

WSh_Ziel.Range("A4:J4").PasteSpecial Paste:=xlFormats
WSh_Ziel.Range("A4:J4").PasteSpecial Paste:=xlValues

End With
Application.CutCopyMode = False
WkBk_Quelle.Close savechanges:=False
Application.ScreenUpdating = True                                                                    ' den Bildschirm-Update wieder zulassen

Next i


End Sub

 

Hi,

dazu kannst du den Autofilter benutzen.

---

 

Danke schonmal für die Wegbeschreibung.
Mein Motto ist ja: "learning by doing"
Habe ein wenig gesucht und in Varianten rumprobiert.... erstmal zum Üben....

Nach vielen Fehlern passiert auch was....
Mit dem Ergebnis:
Alle Daten (ohne die Range A67:J500) werden rausgesucht, in eine neue Mappe kopiert (nicht meine gewünschte) und in das falsche Tabellenblatt eingefügt....

Code:

Set WSh_Quelle = WkBk_Quelle.Worksheets(ThisWorkbook.Worksheets("Anwendung").Range("F" & i).Value)
With WSh_Quelle                                                                                    
.Range("A67:J500").AutoFilter Field:=1, Criteria1:=">=N14"                 
.Copy

Ich denke ich habe ein wenig mehr Erklärungsbedarf nötig....
Ist mein Erstes Mal mit dem Autofilter....

 

Vom Prinzip her so:

Code:

    With ActiveSheet
        ' Autofilter für Bereich A3:D16 setzen
        ' Startdatum steht in Zelle G1, Enddatum in Zelle H1
        .Range("$A$3:$D$16").AutoFilter Field:=1, Criteria1:= _
            ">=" & CDbl(.Range("G1")), Operator:=xlAnd, Criteria2:="<=" & CDbl(.Range("H1"))
        ' Autofilterbereich alle sichtbaren Zellen kopieren ab A4, also ab erster gefilterter Zelle ohne Überschriftenzeile
        With .Range("A4:D16")
            .SpecialCells(xlCellTypeVisible).Copy
        End With
    End With

Blattname, Zellbereich des Autofilters und Zellen mit Start- und Enddatum musst du elbstverständlich anpassen,

---

 

Moin,
das ist ein Anstoß auf den wäre ich so nie gekommen...
Werd ich morgen direkt versuchen zu verstehen und einzubauen...

Super. Danke.

MfG

 

Moin,
ich habs eingebaut, angepasst und sogar verstanden...

Was soll ich sagen... läuft.

Danke nochmal.

MfG