Office: Kriterien prüfen und den Text in eine Zelle übernehmen

Hallo,

ich hoffe Ihr könnt mir weiterhelfen, denn ich bin mit meinem Latein am Ende

Also ich möchte:
21 Kriterien werden zuvor geprüft ob sie bestimmte Rahmen einhalten.
Es erscheint davon abhängig ein "OK" oder "RAUS" in 21 Zellen für jedes Kriterium.
>>> Ist es möglich nun die 21 Zellen zu prüfen ob dort "OK" oder "RAUS" steht und den textlichen Inhalt mehrerer Zellen bei der Wertung "RAUS" in eine Zelle zu übernehmen und zusammenzuführen???

Mit anderen Worten:
z.B. Kriterium 2, 5 und 14 sind "RAUS"
Jetzt sollen in einer anderen Zelle die Namen von 2, 5 und 14 erscheinen.

Wäre KLasse wenn Ihr eine Lösung wisst!!!

Danke vorab

Seb

 

Hallo!

Hier werden die Ergebnisse untereinander geschrieben. Mit VERKETTEN kriegst du sie dann auch in eine einzige Zelle, aber das macht weitere Auswertungen eher schwieriger...

	A	B	C	D
1	Name1	ok		Name2
2	Name2	raus		Name5
3	Name3	ok		Name14
4	Name4	ok
5	Name5	raus
6	Name6	ok
7	Name7	ok
8	Name8	ok
9	Name9	ok
10	Name10	ok
11	Name11	ok
12	Name12	ok
13	Name13	ok
14	Name14	raus
15	Name15	ok
16	Name16	ok
17	Name17	ok
18	Name18	ok
19	Name19	ok
20	Name20	ok
21	Name21	ok

Zelle	Formel
D1	{=WENN(ZEILE(A1)>ZÄHLENWENN(B:B;"raus");"";INDEX(A:A;KKLEINSTE(WENN(B$1:B$99="raus";ZEILE($1:$99));ZEILE(A1))))}
D2	{=WENN(ZEILE(A2)>ZÄHLENWENN(B:B;"raus");"";INDEX(A:A;KKLEINSTE(WENN(B$1:B$99="raus";ZEILE($1:$99));ZEILE(A2))))}
D3	{=WENN(ZEILE(A3)>ZÄHLENWENN(B:B;"raus");"";INDEX(A:A;KKLEINSTE(WENN(B$1:B$99="raus";ZEILE($1:$99));ZEILE(A3))))}
D4	{=WENN(ZEILE(A4)>ZÄHLENWENN(B:B;"raus");"";INDEX(A:A;KKLEINSTE(WENN(B$1:B$99="raus";ZEILE($1:$99));ZEILE(A4))))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Hallo Schatzi :lol:,

Danke schonmal!

Wie bekomme ich die jetzt in eine Zelle?
Verketten?

Habe ich noch nie benutzt!

Vielleicht kannst du mir das ja auch noch sagen!?

Danke und beste Grüße

Seb

 

Hallo!

Aber die Excel-Hilfe hast du mitinstalliert, oder?

=VERKETTEN(D1;",";D2;",";D3)
oder
=D1&","&D2&","&D3

 

Hey,

sorry! War gerade ehrlich gesagt zu faul das auszuprobieren auf eigene Faust weil ich mit VERKETTEN noch nicht gearbeitet hatte und nicht dachte, dass es so einfach geht ;)

Aber nochmal zum ersten Problem zurück:

Bei mir bekomme ich in D1 ein "Name1" ausgegeben und
in D2 sowie D3 einen Fehler (#Zahl!)???

Weist du warum das bei mir nicht geht?

Grüße

 

Hallo!

Wahrscheinlich, weil du dies nicht beachtet hast:

 

Super!!! Du hast Recht

Vielen Vielen Dank

Du hast mir echt weitergeholfen ;)