Office: (Office 365) LAMDA in Verbindung mit LET

Hallo Forum,

ich versuche gerade mich in die neuen Excel-Funktionen einzuarbeiten und habe angehängte Mappe erstellt.
Ich habe für die LET-Funktion Parameter und Berechnungen erstellt und möchte nun die LAMDA-Funktion drumherum packen.
Die LET-Funktion funktioniert, jedoch mit LAMDA erhalte ich die Fehlermeldung #Name?

Wer kann mir helfen, meinen Fehler aufzudecken? Ich finde den Fehler nicht.

Mit excellenten Grüßen

Der Mampfred

 

C10:

=LAMBDA(Jahr;LET(A;GANZZAHL(Jahr/100);
B;REST(19*REST(Jahr;19)+A-GANZZAHL(A/4)-GANZZAHL((A-GANZZAHL((A+8)/25)+1)/3)+15;30);
C;REST(32+2*REST(A;4)+2*GANZZAHL(REST(Jahr;100)/4)-B-REST(REST(Jahr;100);4);7);
D;B+C-7*GANZZAHL((REST(Jahr;19)+11*B+22*C)/451)+22;
E;DATUM(Jahr;WENN(D>31;4;3);WENN(D-31<1;D;D-31));E))(A10)

Der Inhalt von Jahr wird mit (A10) hinten angehängt.

Du nimmst das wieder weg, wenn Du dieses LAMBDA (siehst Du das B in Lambda? Oder zum Erkennen auch mal so: lamBda) als Ostern benennen möchtest. Dann:

C10: =Ostern(A10)

 

Wobei LAMBDA() hier flüssiger als Wasser ist.
Gut, man könnte sie als Lambda "benamsen".
Ich mache dies ja gerne mit dem Gleichungssatz von Lichtenberg, ist rasend schnell, auch wenn die Formel etwas länger ist.

	A	B
1	2022	17.04.2022

Zelle	Formel
B1	=LET(j;A1; A;GANZZAHL(j/100); B;15+GANZZAHL((3*A+3)/4)-GANZZAHL((8*A+13)/25); C;2-GANZZAHL((3*A+3)/4); D;REST(j;19); E;REST(19*D+B;30); F;GANZZAHL((E+GANZZAHL(D/11))/29); G;21+E-F; H;7-REST(j+GANZZAHL(j/4)+C;7); I;7-REST(G-H;7); OS;G+I; K; DATUM(j;3;OS);K)

Strukturiert so:
=LET(j;A1;
A;GANZZAHL(j/100);
B;15+GANZZAHL((3*A+3)/4)-GANZZAHL((8*A+13)/25);
C;2-GANZZAHL((3*A+3)/4);
D;REST(j;19);
E;REST(19*D+B;30);
F;GANZZAHL((E+GANZZAHL(D/11))/29);
G;21+E-F;
H;7-REST(j+GANZZAHL(j/4)+C;7);
I;7-REST(G-H;7);
OS;G+I;
K; DATUM(j;3;OS);K)
Gut, LibreOffice kann das nativ seit Äonen.
Who cares?


Gruß Ralf

 

Hallo lupo1,

vielen Dank für deine schnelle Antwort. Es funktioniert jetzt. Kleiner Fehler, große Wirkung
Ich bin immer wieder erstaunt, wie schnell hier im Forum auf Anfragen reagiert wird.

Mit freundlichen Grüßen

Der Mampfred

PS: Ich habe 16 kg abgenommen, ich nenne mich ab sofort wieder Manfred

 

Ich sach immer Müppwoch ... da passt Mampfred auch ganz gut zu.

 

Hallo RPP63_neu,

ich werde deine Version testen. Ich gehe aber davon aus, das deine Formel ebenfalls funktioniert.
Als Grundlage zur Erstellung meiner OSTERN-Funktion habe ich mich bei Excelformeln.de schlau gemacht.

Vielen Dank für deine Formel und bis demnächst

Der Ma(m)nfred

 

Hallo lupo1,