Office: (Office 365) Leerzellen in Excel-Tabellen nachträglich mit Inhalten darüberliegender Zellen ausfüllen

Hallo Zusammen,

folgende Situation würde ich gerne per Formel lösen und nicht über Inhalte Leerzellen.

In Spalte A steht folgendes.


Ich möchte jetzt gerne, dass in der Spalte A2:A4 die 10 eingetragen wird und in der Spalte A6:A8 die 99 usw.

Hat jemand vielleicht eine Lösung dafür?

VG
Mth

 

Hola,
per Formel geht das nicht weil du damit die Werte in A5, A9... überschreiben würdest.
Gruß,
steve1da

 

Dann über die VBA.

Wie Füge ich hier ein bestimmtes Worksheet jetzt richtig ein z.B. Test?


Sub Leerzellen()

Dim Bereich As Range, Zelle As Range

Set Bereich = Range("B2:B1000")
For Each Zelle In Bereich.SpecialCells(xlCellTypeBlanks)
Zelle = Zelle.Offset(-1, 0)
Next Zelle

End Sub

 

Das ist doch kein Widerspruch!
• Markiere A2:A(Ende)
• Inhalte, Leerzellen
• =A1, mit Strg+Enter abschließen
• Strg+c → Strg+Umschalt+V

 

Da ich so noch nie gearbeitet habe, habe ich das mal versucht, nachzuvollziehen:
• Markiere A2:A(Ende)
• F5, Inhalte, Leerzellen, Enter
• =A1, mit Strg+Enter abschließen
• nun alle auswählen! (die F5-Auswahl reicht nicht), Strg+c → Strg+Umschalt+V
___________________________________________________________________
Alternativ:
B1#: =SCAN(0;A1:A17;LAMBDA(a;c;a*(c=0)+c))
B1#: Strg-C
A1: Alt-BÜW

 

Ja klar!
Strg+c → Strg+Umschalt+V funktioniert nicht bei einer Mehrfachauswahl!
Danke für die Richtigstellung!

Zusatz:
Das Strg+Umschalt+V gibt es ja in Excel erst seit kurzer Zeit.
Ich behelfe mir seit längerer Zeit mit einer kleinen Prozedur in der Personal.xlsb, welcher ich den Shortcut Strg+Umschalt+W (wie Werte) zugeordnet habe.
Dieses Makro kommt auch mit Mehrfachauswahlen zurecht:

Code:

Sub FormelInWert()
'Shortcut Strg+Umschalt+W
Dim x As Range
If TypeName(Selection) = "Range" Then
  With Application
     .ScreenUpdating = False
     For Each x In .Selection.Areas
        If x.HasSpill Then
          With x.SpillParent.SpillingToRange
            .Copy: .PasteSpecial xlPasteValues
          End With
        Else
          x.Copy: x.PasteSpecial xlPasteValues
        End If
     Next
     .CutCopyMode = False
     .Goto ActiveCell
  End With
End If
End Sub

 

Gelöst durch:

Ich habe es jetzt so gelöst:

Sub Auffüllen()

Sheets("Test").Select

Columns("B:B").Select

Selection.SpecialCells(xlCellTypeBlanks).Select

Application.CutCopyMode = False

Selection.FormulaR1C1 = "=R[-1]C"

End Sub

 

Na prima!
Dass Du damit eine komplett gefüllte Spalte mit 1.048.576 Werten erhältst, hast Du bemerkt?
Außerdem solltest Du dringend Formel gegen Wert tauschen, ansonsten gibt es beim sortieren anderer Spalten als B bööööse Überraschungen.
Was soll das Select-Gedöns?

 

So würde ich das machen.
Allerdings (siehe weiter oben) würde ich dazu nicht VBA bemühen.

Code:

Sub FillEmptyCells()
With Range("B:B")
  With Range(.Cells(2), .Cells(.Rows.Count).End(xlUp)).SpecialCells(xlCellTypeBlanks)
    .Formula2R1C1 = "=R[-1]C"
  End With
  .Copy
  .PasteSpecial xlPasteValues
End With
With Application
  .Goto Cells(1)
  .CutCopyMode = False
End With
End Sub

 

Danke RPP63_neu.

Hier noch der Teil mit dem Worksheet.

Code:

Sub FillEmptyCells()

With Worksheets("test").Range("B:B")
  With Range(.Cells(2), .Cells(.Rows.Count).End(xlUp)).SpecialCells(xlCellTypeBlanks)
    .FormulaR1C1 = "=R[-1]C"
  End With
  .Copy
  .PasteSpecial xlPasteValues
End With
With Application
  .Goto Cells(1)
  .CutCopyMode = False
End With
End Sub