Office: Letzte Zeile finden und in anderes Blatt kopieren

Hallo, ich bin neu hier und da ich zur Zeit auf dem Schlauch stehe, hoffe ich auf eure Hilfe.
Mein Problem:
Ich habe eine Tabelle mit Aufträgen. Wenn ein neuer Auftrag (Tabelle1) eingetragen habe, möchte ich ein Auftragsformular erzeugen. Ich habe das Auftragsformular in Tabelle2 angelegt.
Jetzt habe ich das Problem, dass ich gerne ein Makro ausführen würde welches mir aus der letzten Zeile der Tabelle1 (Spalte i) in die Tabelle2 kopiert.
Ich habe ein Makro erstellt, welches mir die Zellen von Tabelle1 in Tabelle2 kopiert. Aber ich bekomme es nicht hin das ich die Daten aus der letzten beschriebenen Zelle in Spalte i kopiert bekomme.
Ich weiß nicht ob es wichtig ist, aber beim kopieren muss z.B. A1 aus Tabelle1 nach B5 in Tabelle2 kopiert werden, dies ist bei allen Zellen die ich kopieren muss so.

VG

 

Hi,

tu dir selbst einen Gefallen und verzichte auf die Select-Orgien. Select, Activate etc. sind in 99,999% aller Fälle überflüssig. Siehe dazu Online - Excel Programmierung VBA Makro: Achtung Makrorekorder oder Wer selektiert denn da?

Aus deinem Code

Code:

    Sheets("Auftragsübersicht").Select
    Range("B4").Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("Auftragsformular").Select
    Range("D1").Select
    ActiveSheet.Paste

kann man ein einfaches

Code:

    Sheets("Auftragsübersicht").Range("B4").Copy
    Sheets("Auftragsformular").Range("D1")..Paste

oder bei Copy sogar ein

Code:

    Sheets("Auftragsübersicht").Range("B4").Copy Sheets("Auftragsformular").Range("D1")

machen. Wenn es dir nur um den Inhalt geht, dann reicht auch

Code:

    Sheets("Auftragsformular").Range("D1") = Sheets("Auftragsübersicht").Range("B4")

Und wenn du bei xxx.RANGE("B4") das "B4" zusammensetzt und es so schreibst xxx.RANGE("B" & 4), dann kannst du die 4 durch deine Variable letztezeile ersetzen.
Oder du verwendest statt dessen gleich xxx.Cells(letztezeile, "B") oder auch xxx.Cells(letztezeile, 2).

 

Hallo,

ich habe dir im allgemein.VBA-Codemodul "Modul2" folgenden VBA-Code eingefügt, der die letzte Zeile im Arbeitsblatt "Auftragsübersicht" ermittelt (anhand der Spalte C = Name) und diese Zeile ins Arbeitsblatt "Auftragsformular" überträgt.

Code:

Option Explicit

Sub Auftragsformular_erzeugen()
'
' Auftragsformular_erzeugen Makro
'
    Dim WsUbs As Worksheet, WsFrm As Worksheet
    Dim letzteZeile As Long, rgUbs As Range
  
    Set WsUbs = Worksheets("Auftragsübersicht")      'Quellblatt
    Set WsFrm = Worksheets("Auftragsformular")       'Zielblatt
  
    letzteZeile = WsUbs.Cells(Rows.Count, 3).End(xlUp).Row    'Spalte C wird zum Ermitteln der letzt.Zeile verw.
    Set rgUbs = WsUbs.Cells(letzteZeile, "A").Resize(1, 24)   'Zeile A4:X4 und folgende
  
    With rgUbs
      .Cells(1).Copy Destination:=WsFrm.Range("C1")       'Jahr
      .Cells(2).Copy Destination:=WsFrm.Range("D1")       'Auftr.Nr.
      .Cells(3).Copy Destination:=WsFrm.Range("C9:D9")    'Name            'D9 ist mit C9 verbunden!!
      .Cells(4).Copy Destination:=WsFrm.Range("C10:D10")  'Telefon         'D10 ist mit C10 verbunden!!
      .Cells(5).Copy Destination:=WsFrm.Range("F9:G9")    'Etage           'G9 ist mit F9 verbunden!!
      .Cells(6).Copy Destination:=WsFrm.Range("F10:G10")  'RaumNr.         'G10 ist mit F10 verbunden!!
      .Cells(7).Copy Destination:=WsFrm.Range("C11:D11")  'Ort             'D11 ist mit C11 verbunden!!
      .Cells(8).Copy Destination:=WsFrm.Range("F11:G11")  'Kostenst.       'G11 ist mit F11 verbunden!!
      .Cells(9).Copy Destination:=WsFrm.Range("C12")      'Eing.Datum
      .Cells(10).Copy Destination:=WsFrm.Range("E12")     'Starttermin
      .Cells(11).Copy Destination:=WsFrm.Range("G12")     'Endtermin
      .Cells(12).Copy Destination:=WsFrm.Range("B17")     'Termin/jederzeit
      .Cells(13).Copy Destination:=WsFrm.Range("C17")     'Termin/Vereinb.
      .Cells(14).Copy Destination:=WsFrm.Range("E17")     'Termin/Festtermin
      .Cells(15).Copy Destination:=WsFrm.Range("F17")     'Termin/FesteZeit
      .Cells(16).Copy Destination:=WsFrm.Range("C20")     'Bearb./Datum
      .Cells(17).Copy Destination:=WsFrm.Range("E20")     'Bearb./Startzeit
      .Cells(18).Copy Destination:=WsFrm.Range("G20")     'Bearb./Endzeit
    
      .Cells(20).Copy Destination:=WsFrm.Range("C22:G22") 'Arb.Beschreibg. 'D22:G22 sind mit C22 verbunden!!
      .Cells(21).Copy Destination:=WsFrm.Range("C23:G23") 'Anmerkg.zus.    'D23:G23 sind mit C23 verbunden!!
      .Cells(22).Copy Destination:=WsFrm.Range("C25:G25") 'Arb.abgeschl.   'D25:G25 sind mit C25 verbunden!!
      .Cells(23).Copy Destination:=WsFrm.Range("C26:D26") 'Arb.durchgef.   'D26 ist mit C26 verbunden!!
      .Cells(24).Copy Destination:=WsFrm.Range("C27:D27") 'Arb.Bestätigg.  'D27 ist mit C27 verbunden!!
    End With 'rgUbs
  
End Sub

Die Datei liegt bei.