Office: Letzte Zeile mit bestimmten Wert finden

DennjoOyola · 20. Oktober 2014

Hallo,

nach einer Fragefreien Woche, heute dann doch mal wieder eine Frage zu einer Aufgabe bei der ich feststecke.

Ich habe eine Tabelle namens "Volumencheck" hier sind von zeile 11 bis openend daten enthalten. in der spalte A ist ein Datum angegeben. Nun möchte ich, dass wenn ich ein Knopf drücke, das Script von oben nach unten die Spalte A nach einem bestimmten Datum durchsucht und mir die letzte Zeile in der das Datum enthalten ist markiert.

Folgender Code bis jetzt

Code:

Sub finden()

Dim Letzte As Long, i As Long
Dim Eingabe As String
Eingabe = InputBox("Startdatum des Zyklus?", "Eingabe")
Letzte = Range("A65536").End(xlUp).Row
For i = Letzte To 1 Step -1
If Cells(i, 1).Value = Eingabe Then
Cells(i, 1).EntireRow.Select
Exit For
Else
End If
Next i

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Mir ist bewusst, dass dieses Script von unten nach oben geht und entsprechend auch richtig funktioniert. Die Frage die hier im Raum steht. Wie drehe ich das Script um. Habe bereits die Range auf "A1" und End auf "xlDown" gesetzt gehabt. jedoch hat dies nicht zum erhofften Erfolg geführt.

Vielen lieben Dank für eure Tipps und Ideen.

:)

Mc Santa · 21. Oktober 2014

Hallo,

ich würde nur die Zeile mit For i =... ändern:
Code:

For i = 11 To Letzte
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hilft dir das weiter?

VG
Santa

DennjoOyola · 21. Oktober 2014

Leider nicht so wirklich, weil er weiterhin nicht die letzte Zeile nimmt, sondern für mich gesehen die erste Zeile mit dem Wert die er findet. Auf dem Screenshot habe ich also das Datum "02.10.2014" gesucht und er sollte in diesem Fall die Zeile 82 zurückgeben und nicht die Zeile 77

Mc Santa · 21. Oktober 2014

Hallo,

ich vermute, dass das an deiner Abfrage liegt:
Code:

If CLng(Cells(i, 1).Value) = CLng(Eingabe) Then
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bitte lade als Beispiel keine Bilder, sondern eine Tabelle hoch. Dadurch ist sichergestellt, dass ich als Helfer unter den gleichen Bedingungen arbeite wie du. (Wenn man ein Bild abschreiben muss, ist das ersten unnötiger Aufwand, außerdem können dadurch Fehler entstehen, Formate abweichen, usw)
Eine Datei kannst du unter "Erweitert" > "Zusätzliche Einstellungen" > "Anhänge verwalten" anhängen.

Hilf dir das weiter?

VG

GMG-CC · 21. Oktober 2014

Moin,

die Reihenfolge war schon richtig ... *Smilie
Ich gehe davon aus, dass in Spalte_A ein echtes Datum steht und kein Text. Dann sollte folgendes klappen (ungeprüft):
Code:

Option Explicit

Sub finden()

Dim Letzte As Long, i As Long
Dim Eingabe As String, datEingabe As Date
Eingabe = InputBox("Startdatum des Zyklus?", "Eingabe")
If IsDate(Eingabe) Then
datEingabe = CDate(Eingabe)
Else
MsgBox "Kein Datum"
Exit Sub
End If
Letzte = Range("A65536").End(xlUp).Row
For i = Letzte To 1 Step -1
If Cells(i, 1).Value = datEingabe Then
Cells(i, 1).EntireRow.Select
Exit For
End If
Next i
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

EarlFred · 21. Oktober 2014

Hallo Name?,

Schleifen sind langsam, die Funktion Vergleich() ist schneller und zuverlässig. Um den letzten Treffer zu finden, muss man tricksen:
Code:

Option Explicit

Sub test()
Dim Eingabe As Date
Dim vRet As Variant
Dim rngSuche As Range
Dim lngZeile As Long

Eingabe = CDate(InputBox("Startdatum des Zyklus?", "Eingabe"))
Set rngSuche = Range(ActiveSheet.Cells(1, 1), ActiveSheet.Cells(Rows.Count, 1).End(xlUp))

vRet = Application.Match(CLng(Eingabe), rngSuche, 0)
Do While IsNumeric(vRet)
lngZeile = CLng(vRet) + lngZeile
Set rngSuche = Range(ActiveSheet.Cells(lngZeile + 1, 1), ActiveSheet.Cells(Rows.Count, 1).End(xlUp))
vRet = Application.Match(CLng(Eingabe), rngSuche, 0)
Loop
Set rngSuche = Nothing
MsgBox lngZeile
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

DennjoOyola · 22. Oktober 2014

Also erstmal vielen lieben Dank an alle. Ich bekomme es dennoch nicht hin, bei mir schmeißt er bei allen Lösungsansätzen immer die falsche Zeile raus.

Ich hab mal die Excel Datei angehängt. Vielleicht kann nochmal jemand von euch rüber schauen.

EarlFred · 22. Oktober 2014

Hallo Name?,

Du fängst nicht bei Zeile 1 mit der Suche an (was ich wegen Deines Codeauszugs angenommen hatte), also müsstest Du bei der Zeilennummer berücksichtigen, wie viele Zeilen später Du anfängst (Beginn in Zeile 12 heißt: 11 Zeilen weiter unten, also +11).

Da ich mir Bilder nicht anschaue, fällt mir aber erst jetzt auf, dass die Datumswerte auch Zeiten beinhalten. Unschön!

Also neue Berechnungsmethode:
Code:

Sub testNeu()
Dim vRet As Variant
Dim Eingabe As Long, lngZeile As Long
Eingabe = CLng(CDate(InputBox("Startdatum des Zyklus?", "Eingabe")))

vRet = Evaluate("=MAX((INT(A11:A196)=" & Eingabe & ")*ROW(11:196))")
If IsNumeric(vRet) Then
lngZeile = CLng(vRet)
If lngZeile > 0 Then
MsgBox CStr(lngZeile)
Else
MsgBox "Nicht gefunden!"
End If
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

DennjoOyola · 22. Oktober 2014

lieben lieben Dank. Viel lernen ich noch zu hab *Smilie

Ja das mit der Uhrzeit ist nicht optimal, aber leider momentan für mich nicht anders zu lösen bzw mit meinem derzeitigen können *wink.gif*

ebs17 · 22. Oktober 2014

die letzte Zeile in der das Datum enthalten ist
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn man die Aufgabe entsprechend der real vorhandenen Gegebenheiten umformuliert, finden sich dann vlt. weitere Lösungsansätze:
Suche den höchsten DateTime-Wert (die höchste Zeit) für ein gegebenes Datum.

GMG-CC · 22. Oktober 2014

Aufbauend auf deinem Entwurf und damit du (wegen des Lernens) Alternativen kennen lernst hier noch eine Möglichkeit:
Code:

Sub test()
'ohne Sicherheitsnetz (Prüfung) ...
Dim Eingabe As Date
Dim lRow As Integer, Ze As Integer
Dim rngDaten As Range
Dim aDaten()
Dim gefunden As Boolean

Eingabe = CDate(InputBox("Startdatum des Zyklus?", "Eingabe"))
lRow = Cells(Rows.Count, 1).End(xlUp).Row
aDaten = Range("A11:A" & lRow)
'Daten sind sortiert, also entfällt das

For Ze = UBound(aDaten) To 1 Step -1
If Int(aDaten(Ze, 1)) = Eingabe Then
MsgBox "Zeile " & Ze + 10
gefunden = True
Exit For
End If
Next Ze
If Not gefunden Then MsgBox "Nicht gefunden!"
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bei diesen wenigen Daten ist das Array zwar nicht wirklich fühlbar schneller, aber wenn es denn einmal mehrere tausend Zeilen sind, dann hilft es schon *wink.gif*.

Luschi · 22. Oktober 2014

Hallo

da Deine Daten aufsteigend sortiert sind, hier noch 1 Variante ohne Schleifchen: Code:

Sub test()
Dim Eingabe As Date
Dim vRet As Variant
Dim rngSuche As Range
Dim lngZeile As Long

'Eingabe = CDate(InputBox("Startdatum des Zyklus?", "Eingabe"))
'Eingabe = CDate("25.09.2014")
lngZeile = 11
Set rngSuche = Range(ActiveSheet.Cells(11, 1), ActiveSheet.Cells(Rows.Count, 1).End(xlUp))

vRet = Application.Match(CLng(Eingabe) + 1, rngSuche, 1)
lngZeile = CLng(vRet) - 1 + lngZeile - 1
Set rngSuche = Nothing
'MsgBox lngZeile
If Fix(ActiveSheet.Cells(lngZeile, 1).Value) = Fix(Eingabe) Then
MsgBox ActiveSheet.Cells(lngZeile, 1).Address & " - " & _
CStr(ActiveSheet.Cells(lngZeile, 1).Value), 48
Else
MsgBox "Datum '" & CStr(Eingabe) & "' nicht gefunden!", 16
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß von Luschi
aus klein-Paris

Office: Letzte Zeile mit bestimmten Wert finden

Letzte Zeile mit bestimmten Wert finden

Letzte Zeile mit bestimmten Wert finden

Letzte Zeile mit bestimmten Wert finden

Letzte Zeile mit bestimmten Wert finden

Letzte Zeile mit bestimmten Wert finden - Similar Threads - Letzte Zeile bestimmten

Letzten Wert(Text!) einer Zeile ausgeben

Kopiert nicht bis zur letzten Zeile

Letzter Wert in Zeile - abhängig von Inhalt einer Spalte

indirekte Funktion, letzte Zeile mit einem Zeitwert anzeigen

Letzte Zelle mit bestimmtem Text finden, Zeilen darunter löschen

Letzte Zeile in einem bestimmten Bereich finden

Erste und letzte Zeile mit bestimmtem Inhalt finden