Office: Letzter Stand aus Matrix mit Datumsangabe verketten

Hallo!
Ich habe eine Tabelle mit mehreren Kunden, unterschiedlichem Zahlstatus zu unterschiedlichen Datumsangaben. Ich möchte je Kunde das letzt verfügbare Datum ausgeben und dieses Datum in einem Textstring verketten.
Am besten schaut Ihr in die kleine Beispieldatei.
Danke für Eure Hilfe!
Jürgen

 

Hallo Jürgen,

falscher ansatz

 

Hi,

ausgelegt für Excelversion VOR 365:

B9:
=INDEX(B$2:G$2;VERGLEICH(MAX(INDEX($B$3:$G$5;VERGLEICH(A9;A$3:A$5;0);));INDEX($B$3:$G$5;VERGLEICH(A9;A$3:A$5;0);)))&" vom "&TEXT(MAX(INDEX($B$3:$G$5;VERGLEICH(A9;A$3:A$5;0);));"TT.MM.JJJJ")

und runterkopieren.

In Excel 365 könnte das so aussehen:

B9:
=LET(X;FILTER(B$3:G$5;A$3:A$5=A9);maxX;MAX(X);INDEX(B$2:G$2;VERGLEICH(maxX;X;0))&" vom "&TEXT(maxX;"TT.MM.JJJJ"))

und runterkopieren.

 

Hallo Excel-Fan's,

hier meine E_365 1-Formel-Lösung:

Code:

=LET(ka;A9:A11;kb;B3:G5;
     kc;WEGLASSEN(REDUCE("";ka;LAMBDA(kd;ke;
          LET(kg;FILTER(kb;A3:A5=ke);
              kf;VERGLEICH(MAX(kg);kg;0);
              kh;INDEX(B2:G2;1;kf) & " vom " & TEXT(MAX(kg);"TT.MM.JJJJ");
              VSTAPELN(kd;kh))));1);kc)

Gruß von Luschi
aus klein-Paris

 

Hallo Excel-Fan's,

so geht's auch in E_365:

Code:

=LET(ka;A9:A11;kb;B3:G5;
     kc;MAP(ka;LAMBDA(ke;
          LET(kg;FILTER(kb;A3:A5=ke);
              kf;VERGLEICH(MAX(kg);kg;0);
              kh;INDEX(B2:G2;1;kf) & " vom " & TEXT(MAX(kg);"TT.MM.JJJJ");
              VSTAPELN(kh))));kc)

Gruß von Luschi
aus klein-Paris

 

Hallo Excel-Fan's,

und hier noch die Variante mit SCAN():

Code:

=LET(ka;A9:A11;kb;B3:G5;
     kc;SCAN("";ka;LAMBDA(kd;ke;
          LET(kg;FILTER(kb;A3:A5=ke);
              kf;VERGLEICH(MAX(kg);kg;0);
              kh;INDEX(B2:G2;1;kf) & " vom " & TEXT(MAX(kg);"TT.MM.JJJJ");
              kh)));kc)

Gruß von Luschi
aus klein-Paris

 

Hallo Excel-Fan's,

auch NACHZEILE() kann das:

Code:

=LET(ka;A9:A11;kb;B3:G5;
     kc;NACHZEILE(ka;LAMBDA(ke;
          LET(kg;FILTER(kb;A3:A5=ke);
              kf;VERGLEICH(MAX(kg);kg;0);
              kh;INDEX(B2:G2;1;kf) & " vom " & TEXT(MAX(kg);"TT.MM.JJJJ");
              VSTAPELN(kh))));kc)

Gruß von Luschi
aus klein-Paris

 

Einen hätte ich auch noch:

Code:

=LET(m;MAX(B3:G3);XVERWEIS(m;B3:G3;B$2:G$2)&" vom "&TEXT(m;"TT.MM.JJJJ"))

Gruß Ralf

 

Ich danke Euch, es hat mein Problem gelöst. Ich habe die erste Version von {Boris} genommen, die habe ich verstanden...

 

Hallo yorcky2,

die Formel von {Boris} mußt Du x-mal nach unten kopieren, meine 1-Formel-Lösungen machen daß von selbst - schade, daß Du diesen Fortschritt nicht nutzen willst.

Gruß von Luschi
aus klein-Paris

 

Hi Luschi,

die Formel von {Boris} mußt Du x-mal nach unten kopieren, meine 1-Formel-Lösungen machen daß von selbst

Ich konnte hier bislang keine Excelversion des TE herauslesen ;-) Womöglich ist die aller erste Formel (für Excel vor 365) daher im Einsatz...?
Aber macht schon Laune, mit den neuen Funktionen zu spielen :-)