Office: Liste aus Liste erstellen

Hallo allerseits,

stehe vor folgendem Problem:

Ich habe eine Liste von x Zeilen, die jeweils aus einer Anzahl von y Spalten bestehen. Ich möchte nun auf Basis dieser Liste eine zweite Liste erstellen, die nur aus den Zeilen besteht, in denen zwei Werte gleich sind. Die erste Liste soll dabei unverändert bleiben.

Ein Beispiel:
Notation: InhaltSpalte1;InhaltSpalte2;InhaltSpalte3

Basistabelle:
A;1;1
B;2;5
C;3;3
D;4;6

Zieltabelle:
A;1;1
C;3;3

Ich habe es mit SVERWEIS probiert, klappt aber nicht, auch mit INDEX habe ich es nicht hinbekommen! Makros oder dergleichen kommen für mich leider nicht in Frage :-(

Was kann ich tun? Freue mich sehr über Hilfe!

Schöne Grüße, TheRedNoseRudolf

 

Hallo!

Entweder löst du's per Matrixformel

	A	B	C	D	E	F	G	H
1	A	1	1			A	1	1
2	B	2	5			C	3	3
3	C	3	3			0	0	0
4	D	4	6			0	0	0

Zelle	Formel
F1	{=INDEX(A:A;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A1)))}
G1	{=INDEX(B:B;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A1)))}
H1	{=INDEX(C:C;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A1)))}
F2	{=INDEX(A:A;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A2)))}
G2	{=INDEX(B:B;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A2)))}
H2	{=INDEX(C:C;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A2)))}
F3	{=INDEX(A:A;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A3)))}
G3	{=INDEX(B:B;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A3)))}
H3	{=INDEX(C:C;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A3)))}
F4	{=INDEX(A:A;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A4)))}
G4	{=INDEX(B:B;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A4)))}
H4	{=INDEX(C:C;KKLEINSTE(WENN($B$1:$B$100=$C$1:$C$100;ZEILE($1:$100));ZEILE($A4)))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

oder du baust dir eine Hilfsspalte à la =WENN(B1=C1;"gleich";"ungleich") und filterst diese Spalte nach "gleich".

 

Hammer, es klappt super :-)
Vielen Dank und einen schönen Restdonnerstag!

 

Hallo,

habe leider etwas außer Acht gelassen :-(

Die beiden Werte in Spalte B und C dürfen nicht gleichzeitig den Wert Null haben. Wenn dies doch der Fall sein sollte, dürfen Sie auch nicht in der Zielliste auftauchen ...

Sorry, ist mir zu spät bewusst geworden.
Habe schon herumgebastelt, bekomme es aber nicht hin :-(

Gruß und danke, TheRedNoseRudolf

 

Hallo!

Dann pack das doch mit in die Abfrage rein:

=INDEX(A:A;KKLEINSTE(WENN(($B$1:$B$100=$C$1:$C$100)*($B$1:$B$100<>0);ZEILE($1:$100));ZEILE($A1)))

 

Hi,

erst einmal besten Dank :-)

Ich habe aber gemerkt, dass ich mich vollkommen falsch ausgedrückt habe. Im Anschluss an deiner Antworten, dem Einbau der Formeln und im weiteren Verlaufe der Gestaltung des Sheets ist mir aufgefallen, dass das zwar alles so klappt, aber mein wirkliches Ziel nicht erreicht wird :-(

Mit deiner letzten Formel, reicht es schon aus, wenn nur eine der beiden Zahl Null ist -> Die Zeile wird ausgeblendet. Eine Null ist aber ok, ich benötige in der Zielliste alle Zeilen, in denen nicht in beiden Spalten (B und C) eine Null steht. Also die Zeilen, in den zweimal eine Null auftaucht, sollen nicht mehr erscheinen! Andere Zahlen dürfen doppelt sein.

Habe nun versucht, die Formel mit UND (s. Anhang) zu gestalten:

=INDEX(A:A;KKLEINSTE(WENN(UND($B$1:$B$100<>0;$C$1:$C$100<>0);ZEILE($1:$100));ZEILE(A1)))

Die Formel wird anscheinend ignoriert ... da passiert nix :-(

Problematisch ist auch, dass ich die Tabelle nicht in Zeile 1 stehen habe. Sie beginnt erst in der 5. Zeile. Deswegen habe ich deine Formel angepasst:

=INDEX(A:A;KKLEINSTE(WENN(UND($B$5:$B$100<>0;$C$5:$C$100<>0);ZEILE($5:$100));ZEILE(A1)))

Auch das geht dann in die Hose, wenn ich das UND einbaue :-( Der zieht sich die Werte aus den ersten 5 Zeilen.


Ich bin ziemlich verzweifelt :-(

Mit der Bitte um Hilfe, TheRedNoseRudolf

 

Hallo TheRedNoseRudolf,

Es funktioniert mit folgender Array-Formel:
=INDEX(A$5:A$8;KKLEINSTE(WENN(WENN($B$5:$B$8;$B$5:$B$8=WENN($C$5:$C$8;$C$5:$C$8;$B$5:$B$8);$B$5:$B$8<>$C$5:$C$8);ZEILE($1:$4));ZEILE($A1)))
1) Aktive Zelle in die linke obere Zelle der Zielliste stellen, Formel in den Zelleneditor kopieren, Tasten Strg+Shift+Enter drücken
2) Diese Formel in die restlichen 11 Zellen des Ziellistenbereichs kopieren. Fertig ist das Ganze.
3) Ich habe auch die Zellbereiche bzw. Zeilenbereiche an Deinen Basislistenbereich angepasst. Du hattest bereits einen Zirkelbezug im Arbeitsblatt, weil sich die Formeln der einzelnen Ziellisten überschnitten hatten.
Falls Du in Deiner Basisliste die Zeilenzahl erhöhst, musst Du natürlich die Zellbereiche und den Zeilenbereich $1:$4 in der Formel anpassen.

Gruß Exl121150