Office: Makro, das erst 5 min nach anklicken aktiv wird

Hallo,
ich möchte ein Makro erstellen, dass jedoch erst fünf Minuten nach dem der Nutzer auf den Button geklickt hat aktiv wird. Weiß hier jemand Rat?

 

Der folgende Code gibt zumindest eine Meldung aus, wenn nach 5 Minuten (oder später) der Zellen-Cursor bewegt wird:

Code:

Option Explicit

Const sht = "Tabelle5"
Const Minuten = 5

Dim ws As Worksheet

Private Sub CommandButton1_Click()

    Set ws = ThisWorkbook.Worksheets(sht)

    ws.Range("gedrueckt").Value = Now

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    Set ws = ThisWorkbook.Worksheets(sht)

    If (ws.Range("gedrueckt").Value <> "") Then

        ws.Range("aktuell").Value = Now

        If ws.Range("vergangen").Value > (1 / 24 / 60) * Minuten Then
            MsgBox "Zeit ist um!"
            ws.Range("gedrueckt").ClearContents
            ws.Range("aktuell").ClearContents
        End If

    End If

End Sub

Du mußt dafür allerdings noch 3 Zellen mit "Namen" versehen:

Code:

gedrueckt
aktuell
vergangen

Und in letztere muß dann noch die Formel

Code:

=aktuell-gedrueckt

eingesetzt werden.

Du kannst natürlich auch auf die benannten Zellen verzichten und alles in globale Variablen des Worksheets packen. Denk aber in jedem Fall daran, die Konstanten am Anfang des Codes anzupassen.

Gruß, Michael

 

Danke Michael. Das hilft mir auf jeden Fall mehr als die "Warteschleife" die ich bisher selbst kreirt hatte.
Leider ist es aber möglich, dass gar keine Taste gedrückt wird. Hast du noch eine Idee, wie man einen echten Countdown programmieren kann? Egal ob eine Taste gedrückt wird oder nicht, sollte nach fünf Minuten die Meldung "Zeit ist um" erscheinen.
Vielen Dank im Voraus,
Alex

 

Du könntest was mit den Schlüsselworten while und doevents werden. Es läuft dann aber auf eine Schleife hinaus, die selbst recht viel Rechenzeit beansprucht und nur ein bißchen für andere Aufgaben abgibt. Eine nicht sehr schöne Lösung...

Code:

Private Sub CommandButton2_Click()

    Dim abgelaufen As Boolean

    Set ws = ThisWorkbook.Worksheets(sht)

    ws.Range("gedrueckt").Value = Now
    ws.Range("aktuell").Value = Now

    abgelaufen = ws.Range("vergangen").Value > (1 / 24 / 60) * Minuten
    While Not abgelaufen
        ws.Range("aktuell").Value = Now
        DoEvents
        abgelaufen = ws.Range("vergangen").Value > (1 / 24 / 60) * Minuten
    Wend
    MsgBox "Zeit ist um!"

End Sub

Das Ding funktioniert zwar grundsätzlich, aber... Ich konnte während der Schleife mit dem Cursor in andere Zellen springen usw., aber wenn ich auch nur eine Änderung (Wert eingegeben) gemacht habe, blieb der Timer stehen, als wenn die Schleife / das Sub verlassen wurde. Gibt bestimmt eine Erklärung dafür, aber ich hab jetzt auf die Schnelle nichts gefunden.

Genauer: Bei Drücken der ersten Taste, die dafür sorgt, daß etwas in der "Bearbeitungszeile" erscheint, stoppt der Lauf. Man kann im VBA-Editor die Abarbeitung weiterlaufen lassen, aber "abgelaufen" startet dann wieder bei 0. Drückt man wieder eine Taste, die eine Eingabe initiiert, dann gibt es sogar einen Anwendungs-Fehler ohne Debug-Möglichkeit. Vielleicht weiß jemand anderes hier ja, woran das liegt.

Eine echte "Timer"-Funktion scheint es für Excel aber nicht zu geben. Unter Access kann man einen Timer auf xxx Sekunden stellen und es wird bei Erreichen von 0 ein Event ausgelöst. Für Excel (Bordmittel) hab ich da nichts Vergleichbares gefunden.

Gruß, Michael

 

Und da mir das keine Ruhe gelassen hat, hab ich weiter gesucht und was gefunden:

In das Worksheet:

Code:

Private Sub CommandButton3_Click()

    Dim abgelaufen As Boolean

    Set ws = ThisWorkbook.Worksheets(sht)

    ws.Range("gedrueckt").Value = Now
    ws.Range("aktuell").Value = Now

    Application.OnTime Now + TimeSerial(0, Minuten, 0), "Zeit_abgelaufen"

End Sub

Und als zusätzliches Modul:

Code:

Public Sub Zeit_abgelaufen()

    Dim ws As Worksheet

    Set ws = ThisWorkbook.Worksheets("Tabelle5")

    'Application.OnTime EarliestTime:=Now, Procedure:="Zeit_abgelaufen", Schedule:=False

    MsgBox "Zeit ist um!"
    ws.Range("gedrueckt").ClearContents
    ws.Range("aktuell").ClearContents

End Sub

Dann haste den Timer nach z.B. 5 Minuten ohne weitere Zeitverfolgung. Ok, "abgelaufen" wird dementsprechend nicht aktualisiert.

Gruß, Michael