Office: Makro - Deklaration von Variabler Sheetauswahl, Auswahl über ComboBox

Hallo,
ich habe folgendes Problem:

Ich habe ein Makro welches Zellinhalte in ein anderes Tabellenblatt kopiert. Soweit so gut.
Nun hätte ich das gerne so das dieses Makro die Werte in ein variables Tabellenblatte kopiert. Die Variable wird über die ComboBox bestimmt.

Ich komme nur mit der Sheetsdeklaration nicht weiter...

Ich habe:

Sub WerteEintragen()

Sheets(ComboBox1.List(ComboBox1.ListIndex)).Select

Range("J11:X11").Select

Application.CutCopyMode = False
Selection.Insert Shift:=xlDown

Sheets("Eingabe").Range("J7:X7").Select
Selection.Copy

Sheets(ComboBox1.List(ComboBox1.ListIndex)).Select
Range("J11").Select

Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False

Sheets("Eingabe").Range("A1").Select

End Sub

Mit - Sheets(ComboBox1.List(ComboBox1.ListIndex)).Select - hab ich das Problem... (und auch mehrfach daran rumgespielt und versch. Variante probiert)
Da ich totaler Anfänger bin und mir das Wissen nach und nach selber aneigne (angeignet habe) weiss ich nichtmal ob der Ansatz überhaupt so richtig ist... ?
Über Hilfe würd ich mich daher freuen...
MfG,
Ijoohn

 

Hi,

versuche es mal so:

Code:

Sub WerteEintragen()
   Dim wksTab As Worksheet
   Dim blnVorhanden As Boolean
   For Each wksTab In Worksheets
      If wksTab.Name = ActiveSheet.OLEObjects("ComboBox1").Object.Value Then
         With wksTab
            .Range("J11:X11").Insert Shift:=xlDown
            Sheets("Eingabe").Range("J7:X7").Copy
            .Range("J11").PasteSpecial Paste:=xlPasteValues
            Application.CutCopyMode = False
            Exit For
         End With
      End If
   Next wksTab
End Sub

Bis später,
Karin

 

Top !
Perfekt !
Es klappt !
Jetzt versuch ich mal zu verstehen warum...
Soviele neue Ausdrücke... Die muss ich mir doch erstmal zu gemüte führen und mich da ordentlich durchwurschteln... ;)
Ach so, hab ich schon danke gesagt? Dann jetzt. Danke.
MfG,
Ijoohn

 

Hi,

hier der Code noch einmal mit einigen Kommentaren - vielleicht helfen sie dir, ihn besser zu verstehen:

Code:

Sub WerteEintragen()
   Dim wksTab As Worksheet          ' Variable für das Tabellenblatt als Woksheet-Objekt
   ' Schleife über alle Worksheets
   For Each wksTab In Worksheets
      ' Name des durchlaufenen Worksheets stimmt mit der ComboBox-Auswahl überein
      If wksTab.Name = ActiveSheet.OLEObjects("ComboBox1").Object.Value Then
         ' bezieht sich auf das gerade durchlaufene Worksheet (mit dem Namen aus der ComboBox-Auswahl)
         With wksTab
            ' Bereich J11:X11 nach unten verschieben
            .Range("J11:X11").Insert Shift:=xlDown
            ' Bereich J7:X7 aus Worksheet Eingabe kopieren
            Sheets("Eingabe").Range("J7:X7").Copy
            ' in J11 Werte nur einfügen
            .Range("J11").PasteSpecial Paste:=xlPasteValues
            ' Kopiermarkierung löschen
            Application.CutCopyMode = False
            Exit For
         End With
      End If
   Next wksTab
End Sub

Die Boolean-Variable habe ich gelöscht, sie ist nicht erforderlich - ich hatte zuerst eine andere Lösung und habe den Code dann noch einmal vereinfacht. Habe die Variable im zuvor geposteten Code nur vergessen zu löschen.

Bis später,
Karin

 

Mehr Mühe kann man wohl von einer Antwort nicht erwarten...
Das wär echt nicht nötig gewesen - hilft aber ungemein.
*Daumenhoch*
MfG,
Ijoohn