Office: Makro für alle Arbeitsblätter

Hallo zusammen,
ich verzeifel derzeit an meinem Makro.

Folgendes Makro habe ich geschrieben, welches auch funktioniert:
Sub Ein_PDF_erstellen()
Dim DateiName As String
DateiName = Range("G3") & Range("G3") & ".pdf"
Range("A1:D45").ExportAsFixedFormat Type:=xlTypePDF, Filename:=DateiName, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
End Sub

Nun wollte ich ein weiteres schreiben, welches alle Arbeitsmappen als PDF abspeichert. kann mir jemand dabei helfen? Danke im vorraus

 

Hi,

du meinst vermutlich nicht Arbeitsmappen sondern Arbeitsblätter?

Ungetestet:

Code:

Sub Mehrere_PDF_erstellen()
    Dim wksTab As Worksheet
    Dim DateiName As String
    For Each wksTab In Worksheets
        DateiName = wksTab.Range("G3") & wksTab.Range("G3") & ".pdf"
        wksTab.Range("A1:D45").ExportAsFixedFormat Type:=xlTypePDF, Filename:=DateiName, _
            Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
    Next wksTab
End Sub

---

 

Hallo Beverly,
danke für die schnelle Antwort. leider habe ich jedoch einen Fehler

 

Hi,

was steht in G3? Weshalb soll der Dateiname 2mal aus der selben Zelle G3 genommen werden? Zum Speichern wird eine Pfadanangabe und ein Dateiname benötigt.

---

 

Hi, in G3 steht folgendes: =VERKETTEN("Rechnung";" ";D26)
Die Datei soll ebenso benannt werden, daher habe ich den Bezug gewählt.Ansonsten hat er mir die Datei eigenartig benannt ;-)

Mein Pfad steht in G4

 

Hi,

wenn in G3 diese Formel steht, dann ist das nur der Name der zu speichernden Datei und der dazugehörige Pfad fehlt. Richtigerweise müsste es dann nämlich so heißen:

DateiName = wksTab.Range("G4") & "\" & wksTab.Range("G3") & ".pdf"

---

 

Guten Morgen und erneutes Danke für deine Mitwirkung.

Leider habe ich immer noch meinen Laufzeitfehler:

 

Hallo,

welche Zeile wird denn markiert?

 

Hi,

dann lade doch mal deine Mappe hoch - ich kann das Problem nämlich nicht nachvollziehen, da bei mir kein Fehler auftritt.

---

 

Hallo nochmal,
sorry es hat etwas gedauert, ich musste erst die sensiblen Daten entfernen ;-)

Ich habe versucht euch die Makros zu beschriften die bei mir noch nicht funktionieren. ganz lieben Dank nochmal für euer mitwirken.
LG

 

Hallo,

wo?

 

Hi,

du hast geschrieben, dass du ALLE Blätter exportieren willst, folglich müssen auch in ALLEN Blättern in K3 und K4 adäquate Begriffe stehen, also Begriffe, die einem Verzeichnis und einem möglichen Dateinamen antsprechen. Das ist aber nur in Blatt 160 der Fall, in den anderen nicht - folglich kann Excel in den anderen Blättern keinen regulären Dateinamen mit Pfandangabe erstellen, was zu einem Fahler führt. Außerdem hat deine Ordner-Angabe in K4 am Ende bereits einen "\" im Gegensatz zu deinem Screenshot. Wenn du falsche Angaben machst musst du dich nicht wundern, dass ein Code nicht funktionieren kann...

Ändere meinen Code wie folgt:

Code:

Sub AllePDFspeichern()
    Dim wksTab As Worksheet
    Dim DateiName As String
    For Each wksTab In Worksheets
        If InStr(wksTab.Range("K4"), "\") > 0 Then
            If Right(wksTab.Range("K4"), 1) = "\" Then
                DateiName = wksTab.Range("K4") & wksTab.Range("K3") & ".pdf"
            Else
                DateiName = wksTab.Range("K4") & "\" & wksTab.Range("K3") & ".pdf"
            End If
            wksTab.Range("A1:D45").ExportAsFixedFormat Type:=xlTypePDF, Filename:=DateiName, _
                Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, _
                OpenAfterPublish:=True
        End If
    Next wksTab
End Sub

---

 

Hallo Beverly,
sorry ich arbeite den ganzen Tag an dieser Liste und habe den Fehler mit dem \ selbst gefunden. ;-). Es funktioniert jetzt genau so wie es sein soll.
Mit deiner Erklärung ist es total logisch, jedoch habe ich diese Logik nicht durchschaut. Ganz lieben Dank für deine Hilfe.