Office: makro für prüfung auf leere zelle und ansonsten drucken

hallo nochmal,

es gibt noch weiteren makrobedarf:

ich habe ein formular erstellt, das ein auftragsdatenblatt darstellt. die bearbeitung ist für 10 produkte ausgelegt. alle felder sind so angelegt, dass mit änderung der auftragsnummer durch sverweise die entsprechenden daten aus einer anderen tabelle eingefügt werden. das funktioniert auch alles top.
es gibt im feld auftragsnummer des formulars eine datenüberprüfung, die die vergebenen auftragsnummern aus dem anderen tabellenblatt über eine hilfsliste zur auswahl als dropdown anbietet. ich kann mir also durch klicken alle 10 varianten anzeigen lassen.

jetzt möchte ich die formulare (für das 1.-10.produkt) nacheinander ausdrucken via makro befehl. das makro soll aber auch prüfen, ob eventuell weniger als 10 produkte in dem auftrag enthalten sind und somit nur zb. 5 auftragsnummern vergeben wurden.

wie lässt sich das anstellen. habt ihr eine idee?

gruss tore

 

ich versuch dir fragestellung nochmal klarer zu formulieren

also zwischenzeitlich hab ich schon folgenden gedanken gehabt:

mit einer wenn-dann-abfrage und einer schleife müsste das doch machbar sein.

so in der Art (die leider nicht läuft)

Code:

Sub AuftragstaschenDrucken()
'
' Tabelle1Drucken Makro
'

'
    For i = 3 To 12
        
    If Sheets("Tabelle1").Range("AN", i).Value <> "" Then
    [Sheets("Tabelle1").Range(L2).Value = Sheets("Tabelle1").Range("AN", i)]
    [ExecuteExcel4Macro "PRINT(2,1,1,1,,,,,,,,2,,,TRUE,,FALSE)"]

End If

    Next i
    
    
End Sub

kann mir ausserdem jemand eine gute quelle nennen, um sich dem thema vba/makros grundsätzlich zu nähern.

danke und gruss

tore

 

Hallo Tore,

nachfolgendes Makro setzt Folgendes voraus:
1) Du hast ein Arbeitsblatt namens "Tabelle1", in dem Dein Formular enthalten ist;
2) In diesem Arbeitsblatt hast Du einen Druckbereich namens "Druckbereich" festgelegt; dieser Bereich wird bei einem Druckvorgang je Produktnummer ausgedruckt;
3) Ferner hast Du eine Zelle benannt mit dem Namen "AuftrNr", die die Auftragsnummer enthält, von der dann Deine SVERWEIS-Funktionen die benötigten Daten aus dem anderen Arbeitsblatt in den Druckbereich/Formular einblenden.
4) Ferner hast Du ja fürs Formular ein Datenüberprüfungs-Dropdown angelegt - ich nehme an, dieses befindet sich genau in der Zelle "AuftrNr". Für das Dropdown benötigst Du eine Liste mit maximal 10 Produktnummern. Dieser Listenbereich habe den Namen "DropDownAuswahl".

Am besten Du kopierst das Makro und fügst es im VBA-Editor in ein allgem. Codemodul ein.
Aufruf: Tastenkombination Alt+F8 mit nachfolgender Enter-Taste oder über einen Button im Arbeitsblatt.

Das Makro druckt den Druckbereich des Arbeitsblattes "Tabelle1" aus, der zuvor mit den jeweiligen Produktdaten ausgefüllt wurde, indem eine Produktnr. nach der anderen aus dem Dropdownlistenbereich "DropDownAuswahl" in die "AuftrNr"-Zelle gespeichert wird. Liegt eine Zelle mit leerer ProduktNr. vor, erfolgt kein Druckvorgang.
Drucker: der unter Windows als Standarddrucker definierte Drucker.

Code:

Public Sub AuftragstaschenDrucken()
  Dim DD_Auswahl As Range
  Dim DD_AN As Range
  Dim FormAN As Range
  Dim FormBereich As Range
  
  With Worksheets("Tabelle1")
    Set DD_Auswahl = .Range("DropDownAuswahl")
    Set FormAN = .Range("AuftrNr")
    Set FormBereich = .Range("Druckbereich")
  End With
  
  For Each DD_AN In DD_Auswahl.Cells
    If DD_AN.Value <> "" Then
      FormAN.Value = DD_AN.Value
      FormBereich.PrintOut Copies:=1, Preview:=False
    End If
  Next DD_AN
  
End Sub

 

danke läuft

habs gerade kopiert und die varaiablen angepasst und... es läuft.
danke, klasse hilfe!

gruss, tore