Office: Makro in ausgeblendetem Tabellenblatt

Hallo,

ich habe eine Excel-Arbeitsmappe mit mehreren Tabellenblättern. Diese Blätter sind mit Sverweisen und Makros verknüpft. Läuft auch alles soweit. Nur möchte ich jetzt, die Blätter ausblenden, die der eigentliche Nutzer nicht benötigt. Wenn ich die Blätter ausgeblendet habe funktionieren meine Makros aber nicht mehr.

Gibt es eine Möglichkeit Makros ausführen zu lassen ohne die betreffenden Blätter einzublenden und dann wieder auszublenden?

Danke für eure Hilfe

 

Hallo Klaus,

ja arbeite ohne Activate, select usw.

Gruß Hajo

 

Hallo Hajo,

danke für die schneller Antwort. Kann da aber nicht ganz folgen - bin ja kein Excelprofi. Wenn ich die .select entferne, dann geht gar nix mehr.
Ich habe mal den Code angehängt. Die Tabellenblätter "Temp für Komm" und "Auswahlfelder Tore-Kleinteile" sind die beiden, die ausgeblendet werden sollen. Der Makro hängt an einer Schaltfläche in Tabelle "Grunddaten". Wenn du mir nur den Beginn kurz mitteilen könntest, dann schaff ich den Rest hoffentlich selbst. P.S.: Version Excel 2000

Danke Klaus

Sub Neu_kalkulieren()
'
' Neu_kalkulieren Makro

Sheets("Temp für Komm").Select
Range("E1:F1").Select
Selection.ClearContents
Range("G1").Select
Sheets("Kommissionierladeliste").Select
Range("A1:M500").Select
Selection.Sort Key1:=Range("M2"), Order1:=xlAscending, Key2:=Range("A2") _
, Order2:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:= _
False, Orientation:=xlTopToBottom
Sheets("Temp für Komm").Select
Range("A1:D1").Select
Selection.AutoFilter
Selection.AutoFilter Field:=1, Criteria1:="<>"
Range("A2:A500").Select
Selection.Copy
Sheets("Auswahlfelder Tore-Kleinteile").Select
Range("A2").Select
Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False
Sheets("Temp für Komm").Select
Selection.AutoFilter Field:=1
Selection.AutoFilter Field:=2, Criteria1:="<>"
Range("B2:B500").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("Auswahlfelder Tore-Kleinteile").Select
Range("D2").Select
Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False
Range("C1").Select
Sheets("Temp für Komm").Select
Selection.AutoFilter Field:=2
Application.CutCopyMode = False
Range("A1:D1").Select
Selection.AutoFilter
Sheets("Ladeliste LKW Tore und Antriebe").Select
End Sub

 

Hallo Klaus,

ich baue das jetzt nicht nach, datum ungetestet.

Code:

Option Explicit
Sub Neu_kalkulieren()
    '
    ' Neu_kalkulieren Makro
    
    Sheets("Temp für Komm").Range("E1:F1").ClearContents
    With Sheets("Kommissionierladeliste")
        .Range("A1:M500").Sort Key1:=.Range("M2"), Order1:=xlAscending, Key2:=.Range("A2") _
            , Order2:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:= _
            False, Orientation:=xlTopToBottom
    End With
    With Sheets("Temp für Komm").Range("A1:D1")
        .AutoFilter
        .AutoFilter Field:=1, Criteria1:="<>"
        .Range("A2:A500").Copy
    End With
    Sheets("Auswahlfelder Tore-Kleinteile").Range("A2").PasteSpecial Paste:=xlValues
    With Sheets("Temp für Komm")
        .AutoFilter Field:=1
        .AutoFilter Field:=2, Criteria1:="<>"
        .Range("B2:B500").Copy
    End With
    Sheets("Auswahlfelder Tore-Kleinteile").Range("D2").PasteSpecial Paste:=xlValues
    With Sheets("Temp für Komm")
        .AutoFilter Field:=2
        .Range("A1:D1").AutoFilter
    End With
    Application.CutCopyMode = False
End Sub

Gruß Hajo

 

Was Hajo meinte: Der Makro-Rekorder ist zwar ein grundsätzlich feines Tool, erzeugt aber einen Source, der ziemlich grausam ist, da im Prinzip jeder Mausklick "protokolliert" wird.

Als Beispiel mal die ersten 3 Zeilen der Routine:

Code:

    Sheets("Temp für Komm").Select 
    Range("E1:F1").Select
    Selection.ClearContents

Da wird also zuerst das Blatt aktiviert / selektiert. Dann wird auf dem (selektierten) Blatt der Bereich e1:f1 selektiert. Und dann wird der (selektierte) Bereich gelöscht.

Du siehst am Ende jedes Befehls dieses ".Select" und in der nächsten Zeile wird mit ebendieser "Selection." weiter gearbeitet.

Und das ist der Schlüssel, denn dadurch läßt sich das ganze "weg kürzen":
Sheets("Temp für Komm").Select
Range("E1:F1").Select
Selection.ClearContents

Code:

    Sheets("Temp für Komm").Range("E1:F1").ClearContents

Und dieser "direkte" Zugriff auf einen Zellbereich funktioniert auch in versteckte Blätter hinein.

Nur mal so als Ergänzung zum Verständnis, was Hajo denn mit dem Source gemacht hat.

Gruß, Michael

 

Hallo Ihr beiden,

DANKE !!!! :-)

Habe jetzt alles verstanden. Hajo's Code getestet, etwas nach gearbeitet (hatte noch Problem mit dem Abschalten des 1.Autofilters und wieder Aufruf des 2.Autofilters) und nun funktioniert es.

SUPER

Gruß Klaus