Office: Makro - Kombination aus Zeile löschen oder Text ersetzen

Hallo miteinander,

ich würde gerne folgendes Problem per Makro (nicht mit klassischen Formeln) lösen (wichtig, das Makro muss beim Öffnen starten):
- wenn in Spalte A nichts steht -> gesamte Zeile löschen
- wenn in Spalte A "nein" erscheint -> nur Text in Spalte D - F mit "anonymisiert" ersetzen.

Ersteres habe ich wie folgt gelöst aber ich habe leider keine Ahnung, wie ich das kombinieren kann?:
Private Sub Workbook_Open()
lz = Cells(Rows.Count, 1).End(xlUp).Rows.Row
For t = lz To 2 Step -1
If Cells(t, 1).Value = "" Then
Rows(t).Delete Shift:=xlUp
End If
Next t
End Sub

Vielen Dank vorab für Eure Hilfe!
Grüße
Snoy

 

Hallo,

in das Codemodul der Arbeitsmappe "DieseArbeitsmappe" (bzw. "ThisWorkbook") ist folgender VBA-Code zu kopieren:

Code:

Option Explicit

Public Sub Workbook_Open()
  Dim lz As Long, Z As Long, S As Long
 
  'Im 1.Arbeitsblatt tue Folgendes:
  '1) Ist in der Spalte A eine Zelle leer,
  '       dann ist die gesamte Zeile, in der diese Zelle enthalten ist, zu entfernen.
  '2) Enthält in der Spalte A eine Zelle "nein",
  '       dann ist Inhalt in Spalte D - F dieser Zeile mit "anonymisiert" ersetzen.
 
  With Worksheets(1)
      lz = .Cells(.Rows.Count, 1).End(xlUp).Rows.Row
      For Z = lz To 2 Step -1
        Select Case .Cells(Z, 1).Value
          Case "":
              .Rows(Z).Delete Shift:=xlUp
          Case "nein":
              For S = 4 To 6
                 .Cells(Z, S).Value = "anonymisiert"
              Next S
          Case Else:
              'Tue nichts
        End Select
      Next Z
  End With
End Sub

 

Hallo Exl121150,

ganz herzlichen Dank! Werde ich am Montag gleich ausprobieren :-)
Viele Grüße & schönes Wochenende.

 

Guten Morgen Exl121150,

eben getestet: fantastisch :-) ganz herzlichen Dank!!!!
Grüße & guten Start in die Woche.