Office: Makro meckert bei meiner Syntax

Hallo Community,

Seit ein paar Wochen versuche ich nun mein funktionierendes Programm weiter zu verbessern. Mit Hilfe des Forums gelingt das auch ganz gut, nun hoffe ich auch dieses mal einen Schritt weiter zu kommen.

Bitte schaut euch einmal die Beispieldatei an. Dieses Prgrogramm ist dafür da, dass man kleine Rechnungen erstellen kann (das Rechnungsmakro hab ich mal rausgemacht um den Umfang zu reduzieren - da es ja funktioniert).
Jetzt würde ich gerne ein Makro implementieren dass mir ein nettes feature anzeigt und zwar die Kundenhistorie. Das hab ich mir über eine Multipage Lösung vorgestellt. Das Programm soll die "Auftragsdatenbank" nach einer bestimmten Kundennummer durchsuchen. In Spalte "A" können also durchaus mehrere Kundennummern stehen mit verschiedenen Angeboten / Rechnungen. Da alle "Aufträge" zu einem Kunden gehören sollen mir diese auch übersichtlich nochmal eingezeigt werden können. Da finde ich persönlich, das Vergleichen der Datensätze aus einer klassichen Tabelle für zu Aufwendig. Später sollen dann natürlich die verschiedenen Textboxen in den Reitern mit den entsprechenden Zeileninhalten aus der Exceldatei gefüllt werden. Das wird aber erst später kommen.

Für die nächsten freien Tage würde ich es gerne schaffen dass die zu erstellenden Reiter der Multipage überhaupt auftauchen. Dazu hab ich ein Kopiermakro gefunden aber das Problem liegt glaube ich schon vorher. Ich muss dem Makro ja irgendwie sagen wo es die Informationen herbekommt. Da es eben gar nicht funktioniert (ich habe verschiedene Ansätze eingefügt) bin ich am zweifeln ob meine Logik (was, zu welchem Zeitpunkt gemacht werden soll) überhaupt stimmt.
Als Zusatzinfo ist noch wichtig dass der erste Reiter mit der Bezeichnung "Neu" bleiben soll. Daraus würde ich gerne eine neue Rechnung erstellen. Die Historie soll dann mit den Nächsten Reitern (Index 1...,n) fortgesetzt werden.
Achja, das Makro ist der Userform ganz unten :).

Über Hilfestellungen würde ich mich freuen da ich keine Ideen für weitere Ansätze hab.

Zur Abwechslung eilt dieses Thema auch nicht da das nebenher geht

Vielen Dank im vorraus
Gruß

 

Hallo N123456789,

hab' mal reingeschaut und folgend ein paar Anmerkungen, was mir so aufgefallen ist.

Frames sind häufig nicht notwendig. Wenn es nur z.B. um die Optik geht, kannst Du ein Label verwenden
und dieses mit der Eigenschaft SpecialEffect = ...Etched und BackStyle = ...Transparent simulieren.

Warum möchtest Du die MultiPage Seiten dynamisch anlegen? Das ist sehr viel Aufwand und Du müsstest,
wenn Du Ereignisse in den dynamisch erstellten Steuerelementen auswerten möchtest, mit Klassen arbeiten.
Du kannst z.B. einzelne Seiten per Code und Visible = False/True unsichtbar/sichtbar setzen. Und somit eine
oder mehrere statische Pages erstellen.

Referenzierungsketten sollten immer vollständig sein. Die folgende auskommentierte Zeile führt zu einem Fehler,
weil sich das .Rows dann auf Me bezieht, was nicht geht. Vor dem .Row müsste dann z.B. nochmal auf die Tabelle
referenziert werden.

Code:

'  With Me
'  lngRowAuftrag = Sheets("Auftragsdatenbank").Cells(.Rows.Count, 1).End(xlUp).Row

lngRowAuftrag = ThisWorkbook.Worksheets("Auftragsdatenbank").Cells( _
                ThisWorkbook.Worksheets("Auftragsdatenbank").Rows.Count, 1).End(xlUp).Row

Gruß

 

Hi Maninweb,

danke für deinen Hinweis. Jetzt bin ich tatsächlich am überlegen ob das dynamische sinnvoll ist. Ich finde es schöner aber wenn das mit exponentiellem Aufwand verbunden ist dann weiche ich davon ab.

Um mal einen entwurf selber erstellen zu können würd ich gerne mehr über das statische wissen. Wie sollte ich da am besten vorgehen? Sage ich von anfang an dass ich z.b. 6 Reiter habe (1-Neu 2,..,6-Historie)? In dem Fall muss ja meine Schleife die Visibility von jedem Reiter ansprechen oder? Ich sag dann z.b. wenn es 3 mal die selbe Kundennummer gibt dann mach Reiter 1-4 visible? Wie bekomme ich aber dann den bezug her das dass jede Datenbank Zeile die Textfelder eines bestimmten reiters füllt? Die Logik für diese Schleife ist mir noch unklar. Kann man auch z.b. Sagen wenn 7 Eintrage vorhanden sind, möchte ich nur die aktuellsten 5 oder so?

Wenn du mir in Worten weiterhelfen könntest würde ich mal einen versuch starten. Dann kommt vielleicht schritt für schritt wieder was tolles raus :)

Gruß

 

Hallo N123456789,

hatte vorhin eher kurz drüber geschaut. Die Anforderungen an Deine Anwendung bewegen sich, soweit ich das verstande habe, in unterschiedlichen Bereichen: Rechnung und Historie.

Für ein Historie erscheint mir ein Reiter pro Eintrag zu umständlich. Ich würde da eher an einen Reiter denken, z.B. "Historie" und darin wieder eine Liste, wo bei Klick, die jeweiligen Daten erscheinen. In der Liste sind die wichtigsten Eckdaten aufgeführt, der Klick zeigt dann dadrunter die Detaildaten. Damit hättest Du auch das Problem nicht, wieviele Reiter im Voraus erstellt werden müssten und müsstest Dich als User nicht durch die Reiter klicken, sondern nur duch die Liste. Du kannst z.B. in einer ListBox (gehe davon aus, Du hast einen Mac, weshalb Du wohl keine anderen ActiveX Elemente verwenden wirst können, ausser die aus Excel VBA) auch Spalten mit ID's Zeilennummner usw. anlegen, die Du versteckst (ColumnWidth = 0) und diese Info dafür nutzen, um die Einträge in der Excel Tabelle wiederzufinden.

Falls Du jedoch lieber im voraus erstellte Reiter verwenden möchtest, läuft's dann auf das Ein- und Ausblenden der Reiter aus. Wobei dann wieder etwas Verwaltungsaufwand entsteht. Könntest es auch in einem ersten Schritt mit nur ganz wenigen Steuerelementen testen.

Gruß

 

Hi Maninweb,

danke erneut für deinen Hinweis. Die Idee würde ich ja fast als semi dynamisch bezeichnen ;). In der Listbox kann ich dann "dynamisch" alle relevanten Altdaten verwalten und mir in wie du sagst textboxen unten erneut anzeigen lassen.
KLASSE IDEE DANKE
Eine Frage noch bevor ich loslege. Ist es möglich wenn ich im Reiter "Neu" etwas anlege, mir es dann im reiter "Historie" sofort anzeigen zu lassen?
also mehr oder weniger eine aktualisierung der Listbox vornehmen sobald ein neuer eintrag gemacht ist?

Wenn das geht leg ich sofort los. Die idee finde ich klasse. Ich hoffe nur dass ich es syntaxmäßig korrekt ausformulieren kann.

Gruß

Ps: bin nachwie vor erstaunt dass du sofort wusstest dass ich mit einem Mac arbeite :). Stimmt!

 

Hi N123456789,

Gern geschehen :)

Wüsste nicht, was dagegen spricht, Daten "sofort" zu aktualisieren. Muss nur programmiert werden.
Würde zudem empfehlen, erst mal einen Prototyp als UserForm zu erstellen. Daraus kannst Du die
Anforderungen an die Algo's usw. ein gutes Stück ableiten. Gerne hier wieder, wenn Du Fragen hast.

PS: das mit dem Mac war nicht schwer, denn es wurde ein Ordner _MACOSX mit entpackt. Der Ordner
dürfte beim Mac versteckt sein, wird aber mit gepackt. Und, in den Kommentaren von Deinem Code
sind die Umlaute falsch dargestellt, liegt wohl daran, dass der Mac eine andere Codierung verwendet.

Auch interessant: die Schriftgröße von den Texten in den Frames liegt bei 2 Punkt. Das dürfte aber
dann eher auf MS zurückzuführen sein; schätze ich mal.

Gruß

 

Hi Maninweb,

vielen Dank. Das wusste ich alles gar nicht. Indem fall gut was gelernt. Ich werde meinen Prototypen hier vorstellen sobald ich etwas geschafft hab. ich denke ab Wochenende habe ich wieder etwas Zeit dafür. Vielen Dank noch einmal.

Gruß

 

Hallo,

Momentan hänge ich gerade an einer absolut simplen Berechnung aber ich bekomme es einfach nicht hin. Ich will den Nettobetrag, die MwSt. und den Gesamtbetrag berechnen. Das würde ich gerne über den Input aus 7 Textboxen machen. Jedoch funktioniert es mit den Spesen noch nicht recht. Außerdem obwohl ich eine "else" bedingung für den Fall "0" bei den Fahrtkosten eingefügt habe, meckert er trotzdem wenn ich "nichts" eintrage. das verstehe ich nicht ganz da ich es ja eigentlich mit der IF,Else bedingung abgedeckt habe.
Nun Frage ich mich woran es liegt. Mein erster Ansatz war eine Variable für jdes Textfeld zu erstellen als von A-M um dann nur noch mit Buchstaben zu rechnen. Leider ging das auch nicht. Deswegen versuche ich jetzt das Textfeld direkt anzusprechen. Macht man das so? Oder gibt es da vielleicht eine elegantere Lösung?
Code ist wie folgt:

hat jemand eine Idee? besonders beim Feld txtEssen meckert er besonders. Unabhängig wie ich es benenne. Vorher hieß es auch schon txtVerpflegung und er hat an der selben stelle gemeckert. Über eine Hilfestellung würde ich mich sehr freuen.

Gruß

 

Hallo N123456789,

Falls Deine TextBox auf der UserForm txtEssen heißt, kannst Du diese nicht erneut mit Dim deklarieren. Ausserdem müsstest Du die Datentypen einhalten, also wenn Du ein Single deklarierst auch in ein Single umwandeln und nicht in ein Double. In der Deklaration ist zudem nur txtEssen als Double deklariert, die anderen als Variant. Tipp: die Deklaration jeder Variable pro Zeile durchführen, nicht in einer Zeile. Schau' Dir dazu das Beispiel-Sub an.

Code:

Sub Deklarationen()

  Dim a, b As String            ' a ist ein Variant
  Dim c As Long, d As String
  
  Dim e As Single
  Dim f As Integer
  
  
  MsgBox "a : " & VarType(a) & " - " & TypeName(a)
  MsgBox "b : " & VarType(b) & " - " & TypeName(b)
  MsgBox "c : " & VarType(c) & " - " & TypeName(c)
  MsgBox "d : " & VarType(d) & " - " & TypeName(d)
  MsgBox "e : " & VarType(e) & " - " & TypeName(e)
  MsgBox "f : " & VarType(f) & " - " & TypeName(f)
  
End Sub

Ausserdem würde ich empfehlen, der Übersichtlichkeit halber, Variablen am Anfang einer Prozedur zu deklarieren, nicht mitten drin.

Um ein Problem mit doppelt deklarierten Variablen zu vermeiden, kannst Du Präfixe für Deine Variablen verwenden, wobei Du dabei frei bist, auch ein eigenes Bennenungsystem zu verwenden. Für Textboxen hast Du ja schon txt genommen. Für ein Single könntest Du sng, ein Long lng, ein String str oder ein Integer int nehmen. Anbei mal ein Beispiel-Code, wo auch eine - einfache - Überprüfung stattfindet, ob es sich um Zahlenwerte handelt.

Code:

Sub Beispielrechnung()

  Dim sngStunden    As Single
  Dim sngStundenSatz As Single
  
' Zuweisung...
  
  If IsNumeric(txtStd.Text) Then
    
    sngStunden = CSng(txtStd.Text)
    
  End If
  
  If IsNumeric(txtStdSatz.Text) Then
    
    sngStundenSatz = CSng(txtStdSatz.Text)
    
  End If
  
  MsgBox CStr(sngStunden * sngStundenSatz)
  
End Sub

Gruß

 

Hi Maninweb,

Danke für die Antwort insbesondere mit deinen codezeilen aus der sub "Beispielrechnung" war ich sehr schnell in der Lage das Problem zu lösen. Die Deklarierhinweise habe ich berücksichtigt und so sieht der fertige funktionierende code aus
(vielleicht interessiert es dich ja :))
Eine Frage habe ich noch. Das ist aber wirklich nur das Sahnehäupchen. Ist es möglich meine 12 Textboxen so zu formatieren dass am Ende der Zahl immer ein Euro Zeichen steht? oder ist das leichter mit einem Label hinter der textbox getan?

Code:

Private Sub cmdBerechnung_Click()
'Berechnung der Rechnungswerte: MwSt, Netto, Gesamt
'Alle Variablen als Zahlen
  Dim sngStunden    As Single
  Dim sngStundenSatz As Single
  Dim sngKm As Single
  Dim sngKmSatz As Single
  Dim sngSonstiges As Single
  Dim sngUnterkunft As Single
  Dim sngVerpflegung As Single
  Dim sngZwStd As Single
  Dim sngZwKm As Single
  Dim sngZwSpesen As Single
  Dim sngNetto As Single
  Dim sngMwSt As Single
  Dim sngGesamt As Single
  
' Zuweisungen damit die Textbox erkennt dass es Zahlen sind
  If IsNumeric(txtStd.Text) Then                        '1
    sngStunden = CSng(txtStd.Text)
  End If
  If IsNumeric(txtStdSatz.Text) Then                 '2
    sngStundenSatz = CSng(txtStdSatz.Text)
  End If
  If IsNumeric(txtKm.Text) Then                       '3
    sngKm = CSng(txtKm.Text)
  End If
    If IsNumeric(TxtKmSatz.Text) Then       '4
    sngKmSatz = CSng(TxtKmSatz.Text)
  End If
    If IsNumeric(txtSonstiges.Text) Then       '5
    sngSonstiges = CSng(txtSonstiges.Text)
  End If
    If IsNumeric(txtUnterkunft.Text) Then            '6
    sngUnterkunft = CSng(txtUnterkunft.Text)
  End If
  If IsNumeric(txtVerpflegung.Text) Then        '7
    sngVerpflegung = CSng(txtVerpflegung.Text)
  End If
  If IsNumeric(txtZwStd.Text) Then             '8
    sngZwStd = CSng(txtZwStd.Text)
  End If
    If IsNumeric(txtZwKm.Text) Then       '9
    sngZwKm = CSng(txtZwKm.Text)
  End If
    If IsNumeric(txtZwSpesen.Text) Then       '10
    sngZwSpesen = CSng(txtZwSpesen.Text)
  End If
    If IsNumeric(txtNetto.Text) Then       '11
    sngNetto = CSng(txtNetto.Text)
  End If
    If IsNumeric(txtMwSt.Text) Then       '12
    sngMwSt = CSng(txtMwSt.Text)
  End If
    If IsNumeric(txtGesamt.Text) Then       '13
    sngGesamt = CSng(txtGesamt.Text)
  End If
  
'---------------------- Zwischensummen ---------------
'Berechnung Zwischensumme der Grundleistung
        sngZwStd = CStr(sngStunden * sngStundenSatz)
        txtZwStd.Value = sngZwStd
'Berechnung Zwischensumme der Fahrtkosten
        sngZwKm = CStr(sngKm * sngKmSatz)
        txtZwKm.Value = sngZwKm
'Berechnung Zwischensumme Spesen
        sngZwSpesen = CStr(sngVerpflegung + sngUnterkunft + sngSonstiges)
        txtZwSpesen.Value = sngZwSpesen
'----------------------------------------------------

'----------------------- Gesamtsummen ---------------
'Berechnung Netto
sngNetto = CStr(sngZwStd + sngZwKm + sngZwSpesen)
txtNetto.Value = sngNetto
'Berechnung MwSt
 sngMwSt = CStr(sngNetto * (txtMwStSatz.Value / 100))
 txtMwSt.Value = sngMwSt
'Berechnung Gesamt
txtGesamt.Value = CStr(sngNetto + sngMwSt)
'----------------------------------------------------
End Sub

Gruß

 

Hallo N123456789,

einfacher ist das Euro-Zeichen als Label hinter dem Textfeld zu setzen :)

Hätte noch einige Anmerkungen zu Deinem Code. Schau' mal hier den Teil...

Code:

'---------------------- Zwischensummen ---------------
'Berechnung Zwischensumme der Grundleistung
sngZwStd = CStr(sngStunden * sngStundenSatz)
txtZwStd.Value = sngZwStd
'Berechnung Zwischensumme der Fahrtkosten
sngZwKm = CStr(sngKm * sngKmSatz)
txtZwKm.Value = sngZwKm
'Berechnung Zwischensumme Spesen
sngZwSpesen = CStr(sngVerpflegung + sngUnterkunft + sngSonstiges)
txtZwSpesen.Value = sngZwSpesen

'Berechnung Netto
sngNetto = CStr(sngZwStd + sngZwKm + sngZwSpesen)
txtNetto.Value = sngNetto
'Berechnung MwSt
sngMwSt = CStr(sngNetto * (txtMwStSatz.Value / 100))
txtMwSt.Value = sngMwSt
'Berechnung Gesamt
txtGesamt.Value = CStr(sngNetto + sngMwSt)

sngNetto hast Du korrekt als Single deklariert, aber wandelst das Ergebnis der Berechnung in einen String um.
Das brauchst Du nicht, denn die Berechnung liefert ein Single. Dasselbe mit sngZwStd, sngZwKm oder sngMwSt.

Eine Typumwandlung ist nur dann notwendig, wenn Du von einem deklarierten Datentyp in einen anderen umwandeln
möchtest; vorausgesetzt dies ist von der Werten her möglich. Wenn Du z.B. rechnen möchtest und Singles deklariert
hast, brauchst Du nicht umwandeln. Wenn Du aber z.B. das Ergebnis einem Textfeld zuweisen möchtest, kannst Du
umwandeln, denn das Textfeld beinhaltet einen Text. Genauso anders herum, wenn Du aus dem Inhalt des Textfeldes
eine Zahl machen möchtest - was Du bei der Zuweisung der Single-Variablen anhand der Werte aus den Textfeldern
gemacht hast :)

Excel VBA hat einen eingebauten Mechanismus, um Datentypen implizit umzuwandeln. Das heißt, dass Excel VBA
versucht, die Umwandlung intern vorzunehmen. Wenn Du einem Textfeld einen Single zuweist - zum Beispiel
über Textfeld1.Text = sngWert, macht Excel VBA die Umwandlung automatisch von sngWert in einen String.
Deshalb funktioniert z.B. auch MsgBox sngWert.

Code:

'Berechnung Zwischensumme der Grundleistung
        sngZwStd = sngStunden * sngStundenSatz
        txtZwStd.Text = CStr(sngZwStd)
'Berechnung Zwischensumme der Fahrtkosten
        sngZwKm = sngKm * sngKmSatz
        txtZwKm.Text = CStr(sngZwKm)
'Berechnung Zwischensumme Spesen
        sngZwSpesen = sngVerpflegung + sngUnterkunft + sngSonstiges
        txtZwSpesen.Text = CStr(sngZwSpesen)
'Berechnung Netto
        sngNetto = sngZwStd + sngZwKm + sngZwSpesen
        txtNetto.Text = CStr(sngNetto)
'Berechnung MwSt
        sngMwSt = sngNetto * (txtMwStSatz.Value / 100)
        txtMwSt.Text = sngMwSt
'Berechnung Gesamt
        txtGesamt.Text = sngNetto + sngMwSt

Normalerweise funktioniert die interne Umwandlung ganz gut, aber nicht immer. Mein persönliches Credo dabei ist,
sich nicht auf Excel zu verlassen und eventuelle Typumwandlungen selbst vorzunehmen. Kommt daher, weil es
andere Programmiersprachen explizit fordern und so etwas wie bei VBA erst gar nicht zulassen (z.B. C++).

Im Beispiel hier oben sind mal beide Varianten drin (mit und ohne CStr()).

Gruß