Office: Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen

mo_ozi · 6. März 2011

Moin @ll

ich habe eine Spalte (A1:A50000) mit Zahlwerten und brauche dieses Makro dafür:

wenn Wert1 mehrfach
Wert1 in Gruppe1 (Array?) speichern
wenn Wert2 mehrfach
Wert2 in Gruppe2 speichern
...
zähle Gruppen
Ausgabe Gruppenanzahl
...
zähle Werte in Gruppe1
Ausgabe Anzahl der Werte in Gruppe1
zähle Werte in Gruppe2
Ausgabe Anzahl der Werte in Gruppe2
...

Ich hoff einer von euch kann damit etwas anfangen, leider übersteigt diese Aufgabe meine bisherigen VB Kenntnisse und die Suche hat mir auch nur bedingt weiter geholfen :/

Danke im Voraus und einen schönen Tag
Chris

:)

EarlFred · 8. März 2011

Hallo Chris,

wirklich VBA, oder nicht doch lieber das Hausmittel Pivottabelle verwenden?

Grüße
EarlFred

mo_ozi · 8. März 2011

Hi EarlFred

hm das geht nicht, weil ich mit diesen Zwischenergebnissen (Anzahl der Gruppen und Anzahl der Werte in den Gruppen) noch weiter rechnen muss. Mit einer Pivottabelle kann ich mir die Zahl ja nur "anzeigen" lassen oder?

Cya
Chris

EarlFred · 8. März 2011

Hallo Chris,

man kann auch auf die Ergebnisse der Pivottabelle zugreifen.

Aber habe nebenbei ein Makro geschrieben - schau's Dir mal an, ob ich Deine Frage richtig verstanden habe:

Code:

Sub mo_ozi()
Dim fWerte As Variant, i As Long
Dim dic As Object
Set dic = CreateObject("Scripting.Dictionary")
'Werte aus Tabelle auslesen
fWerte = Range([A1], Cells(Rows.Count, 1).End(xlUp))
'"Gruppen" bilden und Anzahl zählen
For i = LBound(fWerte, 1) To UBound(fWerte, 1)
dic(fWerte(i, 1)) = dic(fWerte(i, 1)) + 1
Next i
'Ausgabe
[C1].Resize(dic.Count) = WorksheetFunction.Transpose(dic.keys)
[D1].Resize(dic.Count) = WorksheetFunction.Transpose(dic.items)
[E1] = "Gruppenanzahl: " & dic.Count
[E2] = "Gesamtzahl: " & UBound(fWerte, 1)
Set dic = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

mo_ozi · 8. März 2011

Hi EarlFred

Danke, super. Ich brauche nun nur noch die Anzahl der Gruppen, die mehrfache Werte haben.
Zum Beispiel:
Werte: 1,1,2,3,4,4,5,6
Anzahl Gruppen mehrfacher Werte: 2
Aber das schaff ich hoffentlich allein, danke!

Hast du einen Tipp für ein erschwingliches VB Buch, in alle wichtigen Befehle drin stehen?

Schönen Feierabend
Chris

EarlFred · 8. März 2011

Hallo Chris,

hier noch die Anzahl der Gruppen mit mehr als einem Eintrag:
Code:

[E3] = "Gruppen mit mehr als einem Eintrag: " & Evaluate("=SUM(IF({" & Join(dic.items, ",") & "}>1,1))")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bei sehr vielen Gruppen:
Code:

[E3] = "Gruppen mit mehr als einem Eintrag: " & WorksheetFunction.CountIf([D:D], ">1")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Einen Buchtipp kann ich Dir nicht geben, tut mir leid.

Grüße
EarlFred

mo_ozi · 8. März 2011

Vielen Dank Earl!!

mo_ozi · 10. März 2011

Heyho ich bins nochmal
habe beim letzten Eintrag keinen Editierbutton gefunden :|

Wenn ich mit der Items-Methode die Anzahl der unterschiedlichen Werte des dictionary ausgeben lassen kann
Code:

[D1].Resize(dic.Count) = WorksheetFunction.Transpose(dic.Items)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

dann kann ich aus dieser Spalte doch auch irgendwie nur die Werte eben dieser Liste anzeigen lassen, die z.b. größer 1 sind !?
Greift man dann wieder auf das dictionary zurück oder liest man die mit der obigen Code-Zeile erstellte Liste aus?
Also z.B. folgende Liste, die mit der obigen Zeile erstellt wurde:
1, 1, 3, 3, 1
Daraus will ich nun eine Liste, in der nur
3, 3
stehen, die anderen fallen weg.

Habe schon die ganze Zeit rumgesucht und rumprobiert aber ich komm nicht drauf :/

Hast du oder habt ihr eine Idee?
Danke und Gruß aus Essen
Chris

EarlFred · 10. März 2011

Hallo Chris,

ich schwing mal den Holzhammer und lass 2 Dics parallel laufen - wir hamms ja *wink.gif*
Code:

Sub mo_ozi()
Dim fWerte As Variant, i As Long
Dim dic As Object, dicCheck As Object
Set dic = CreateObject("Scripting.Dictionary")
Set dicCheck = CreateObject("Scripting.Dictionary")
fWerte = Range([A1], Cells(Rows.Count, 1).End(xlUp))
For i = LBound(fWerte, 1) To UBound(fWerte, 1)
dicCheck(fWerte(i, 1)) = dicCheck(fWerte(i, 1)) + 1
If dicCheck(fWerte(i, 1)) > 1 Then
dic(fWerte(i, 1)) = dicCheck(fWerte(i, 1))
End If
Next i
'Ausgabe
[C1].Resize(dic.Count) = WorksheetFunction.Transpose(dic.keys)
[D1].Resize(dic.Count) = WorksheetFunction.Transpose(dic.items)
[E1] = "Gruppenanzahl: " & dic.Count
[E2] = "Gesamtzahl: " & UBound(fWerte, 1)
Set dic = Nothing
Set dicCheck = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

Office: Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen

Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen

Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen

Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen

Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen

Makro: mehrfache Werte speichern, in gruppen zusammenfassen und zählen - Similar Threads - Makro mehrfache Werte

Name der Datei durch Excel geändert

Ein Makro für mehrere Register

Makro öffnet unerwartete Datei

Leerzeilen entfernen

Makro Schaltflaechen vervielfaeltigen sich....

Macro für Tabellenblatt mehrfach Kopie sowie Datumänderung

Ausführen Code im Makro - mehrfach geht nicht... in Runtime