Office: Makro nur in einer Datei ausführen.

Hallo,

habe eine Excel Datei die in bestimmten Intervallen die Verlinkungen aktualisiert.
Das funktioniert auch wunderbar.
Allerdings wenn ich noch eine andere Excel Datei zusätzlich öffne bekomme ich eine Fehlermeldung.
Wie kann ich sicherstellen das dieses Makro nur auf einer Datei durchgeführt wird?

DieseArbeitmappe: (damit nach dem öffnen in einem bestimmten Intervall aktualisiert wird)
Private Sub Workbook_open()
Application.OnTime Now + TimeValue("00:02:00"), "Refresh"
End Sub

Modul1:
Sub Refresh()
ActiveWorkbook.UpdateLink Name:="F:\AE\Eng\Xdaten.xlsx", _
Type:=xlExcelLinks
ActiveWorkbook.UpdateLink Name:= _
"K:\PartMx\System\WO Index.xlsx" _
, Type:=xlExcelLinks
Application.OnTime Now + TimeValue("00:02:00"), "Refresh"
End Sub

In den Tabellen unter DieseArbeitsmappe ist nichts drin.

Fehlermeldung:
Laufzeitfehler '1004':
Die Methode 'UpdateLink' für das Objekt' _Workbook' ist fehlgeschlagen
Debuggen: gelb markiert ist:
ActiveWorkbook.UpdateLink Name:="F:\AE\Eng\Xdaten.xlsx", _
Type:=xlExcelLinks

 

Moin,
sobald Du eine neue Excel-Datei aufmachst, wird sie zum „ActiveWorkbook”
Das solltest Du in Deinen Makros mit berücksichtigen.
Gruß
Doming

 

Ersetze mal ActiveWorkbook durch ThisWorkbook oder Workbooks("DeinDateiname.xlsm")

 

Super Vielen Dank.
Funktioniert jetzt ohne Fehlermeldung.

Wenn die Referenzdatei auch geöffnet ist kommt nur noch die Fehlermeldung.

 

Du kannst doch prüfen, ob eine der beiden Referenzdateien geöffnet ist und falls ja, dann führst du die Aktualisierung nicht aus - nach diesem Prinzip:

Code:

Sub Refresh()
    Dim wkbMappe As Workbook
    Dim blnPruefen As Boolean
    For Each wkbMappe In Workbooks
        If wkbMappe.Name = "Xdaten.xlsx" Or wkbMappe.Name = "WO Index.xlsx" Then
            blnPruefen = True
            Exit For
        End If
    Next wkbMappe
    ' nur aktualisieren wenn keine der beiden Mappen geöffnet ist
    If blnPruefen = False Then
        ThisWorkbook.UpdateLink Name:="F:\AE\Eng\Xdaten.xlsx", _
            Type:=xlExcelLinks
        ThisWorkbook.UpdateLink Name:="K:\PartMx\System\WO Index.xlsx", _
            Type:=xlExcelLinks
    End If
    Application.OnTime Now + TimeValue("00:02:00"), "Refresh"
End Sub

---

 

Super Vielen vielen Dank. Jetzt läuft es Idiotensicher.