Office: Makro TextBox Pivot

Hallo!

Ich hoffe mir kann hier jemand helfen. Leider bin ich nicht so fit im Umgang mit Makros.

Mein Problem: Ich habe zwei TextBoxen (TextBox1 und TextBox2) in denen die Namen von zwei verschiedenen Städten eingegeben werden sollen. Danach soll mit einem Klick auf einen Button (den habe ich auch schon) über ein Makro dann genau die zuvor eingegeben Städte in einer Pivot Tabelle (diese liegt auf einem anderen Tabellenblatt in der gleichen Datei) ausgewählt werden.

Ich habe keine Ahnung wie der Makro-Code dafür aussehen sollte... Kann mir jemand helfen?

Ich arbeite dabei mit Excel 2010.

Grüße!

 

Hallo,

ich kann dir nicht helfen da zum einen meine VBA-Kenntnisse dafür nicht ausreichen und zum anderen deine Beschreibung zu dürftig ist - da solltest du auf jeden Fall noch nachbessern.

Ich stelle mir im Moment eine andere Frage: Was ist der Zweck dieser Übung?

So wie ich das im Moment verstehe willst du zwei Städte auswählen und diese Städte sollen dann in der PT gefiltert werden. Reicht es nicht aus diese Städte direkt in der PT zu filtern? Oder verstehe ich die Absicht falsch.

 

Hallo Peter,

ich will die Auswahl nicht direkt in der Pivot vornehmen, da diese für den Anwender (der die Städte eintippt) nicht sichtbar sein soll (Pivot liegt auf anderem Tabellenblatt). Zudem sind es mehrere Pivots sodass man mehrmals auswählen müsste.
Es ist bei der Auswahl dann jeweils nur ein Wert aus jeder Pivot von Interesse, welche ich über eine Verlinkung auf dem ersten Tabellenblatt sichtbar machen will.

Grüße!

 

Hallo,

Du hast
1) in VBA eine UserForm erstellt, die 2 TextBox-Felder "TextBox1" und "TextBox2" enthält. In diese gibst Du den Namen je 1 Stadt ein.
Ferner enthält dieses Formular die Befehlsschaltfläche "cmdPivot", deren Click-Ereignisbehandlungsroutine auf den Namen "cmdPivot_Click" des folgenden Makros eingestellt ist.

2) Das folgende VBA-Makro befinde sich im Codemodul der Userform aus Punkt 1). Es setzt Folgendes voraus:
2a) Ein Arbeitsblatt namens "Auswertung".
2b) Dieses enthalte eine PivotTable namens "StädteWerte".
2c) Diese PivotTable enthalte ein PivotTable-Feld namens "Stadt". Dabei darf es sich um ein Seitenfeld, Zeilenfeld oder Spaltenfeld handeln.

3) Programmablauf im Makro:
3a) Nach dem Klick auf die Befehlsschaltfläche "cmdPivot" wird der Inhalt der beiden TextBoxen "TextBox1" und "TextBox2" in die beiden String-Variablen Stadt1$ und Stadt2$ übernommen.
3b) Danach wird zum PivotTable-Feld "Stadt", das sich in der PivotTable "StädteWerte" des Arbeitsblattes "Auswertung" befindet, gegangen.
3c) Dort werden zuerst alle Werte (PivotItem) aus der Werteliste (PivotItems) des Feldes entfernt (quasi das Häkchen entfernt)
3d) Zum Schluss werden die beiden "Stadt"-Werte wieder mit Häkchen versehen, damit nur diese beiden Werte in der PivotTable-Abfrage aufscheinen.
3e) Eventuell kann man noch die PivotTable mit den neu eingestellten Werten explizit aktualisieren lassen (ist jedoch normalerweise nicht notwendig, da durch die Neueinstellung der Items eine Aktualisierung erfolgt.

Code:

Option Explicit

Private Sub cmdPivot_Click()

'------ 3a) Formular: Städtenamen-Ermittlung
  Dim Stadt1$, Stadt2$
  With Me
    Stadt1$ = .TextBox1.Value
    Stadt2$ = .TextBox2.Value
  End With
  
'------ 3b) PivotTable: Einstellen Stadt1$, Stadt2$ im Feld "Stadt"
' Im Arbeitsblatt "Auswertung" befinde sich die PivotTable "StädteWerte".
' Diese habe ein Pivotfeld (Seitenfeld, Zeilenfeld, Spaltenfeld) namens "Stadt"

  Dim Ws As Worksheet
  Dim Pt As PivotTable
  Dim PtFld As PivotField
  Dim PtIt As PivotItem
  
  Set Ws = Worksheets("Auswertung")
  Set Pt = Ws.PivotTables("StädteWerte")
  Set PtFld = Pt.PivotFields("Stadt")
  
  '3c) Bei allen Einträgen im Pivottabellenfeld "Stadt" das Häkchen entfernen
  For Each PtIt In PtFld.PivotItems
    PtIt.Visible = False
  Next PtIt
  
  '3d) Im Pivotfeld "Stadt" werden die beiden Werte Stadt1$ und Stadt2$ "angehakt"
  With PtFld
    .PivotItems(Stadt1$).Visible = True
    .PivotItems(Stadt2$).Visible = True
  End With
  
  '3e) Eventuell PivotTable aktualisieren:
  Pt.RefreshTable
  
End Sub

Anmerkung: Insbesondere bei der PivotTable-Programmierung ist es eine enorme Starthilfe, wenn man den Makrorekorder verwendet. Man erhält so die getätigten Einstellungen als VBA-Code geliefert, den man dann anschließend natürlich verfeinern und optimieren sollte. Auch ich bin beim obigen Makro so vorgegangen.

 

Hallo Anton! Vielen Dank für deine Hilfe! Ich werde es gleich mal ausprobieren! :)