Office: makro zum löschen von zeilen

Hallo liebes office-hilfe team!

Ich habe eine wichtige frage zu einem bestimmten makro, das ich suche. Ich verwende das office 2003 paket.

Ich hoffe, dass ich meine frage genau schildern kann & es auch noch verständlich bleibt :-)

folgendes:

Ich soll für meine arbeit etwa 120 000 zeilen bearbeiten bzw. bestimmte dinge aus den zeilen löschen und alles mit der hand zu löschen wäre fasst unmöglich in kurzer zeit, also suche ich ein makro, dass mir die arbeit abnimmt - kann aber selber absolut keins selbstschreiben.

Ich lad euch einen screenshot hoch, damit es leichter zu beschreiben ist, wenns euch recht ist.


http://img377.imageshack.us/img377/8223/excelproblemlz8.jpg

Beschreibung zum bild:

Ich benötige nur den inhalt der spaltennr. A - H in den zeilen 7, 10, 20, 29, 33.
und das geht weiter bis zur ungefähr zeilennr. 120000 :shock:

vl. kann man ja ein markro kreiieren, damit nur der inhalt der paar zeilennr. erhalten bleibt, oder das halt nur jene zeile löscht wo das wort "name, usw." der genannten nr. vorkommt

Ich hoffe ihr wisst, was mein problem ist. nun hoffe ich, das mir jemand helfen kann, da es wirklich wichtig für mich ist. ihr seit meine letzte rettung :)

ich danke schon mal im voraus.

mfg

 

Hallo!

Das "usw." wäre interessant, denn momentan kann ich nicht erkennen, nach welchen Kriterien eine Zeile gelöscht werden soll...

PS: Excel 2003 besitzt "nur" 65536 Zeilen. Wie kommst du auf 120000???

 

danke für die schnelle antwort :-)

insg. sind 120.000 zeilen, natürlich auf 8 files aufgeteilt :-)

die suchkriterien wären die, welche wörter in den zeilen nr. 7,10,20,29,33 vorkommen. also zeile 7 "suchbeg" zeile 10 "Name" zeile 20 "Bemerkgen" zeile 29 "Busperre" und zeile 33 "Zahlwege", aber ACHTUNG es gibt 2 "Busperre" ich brauche nur das aus zeile 29.

lg

 

Hallo!

Nur damit ich es richtig verstehe:
Jeder Datensatz beinhaltet in Spalte D genau EINmal die Begriffe "Suchbegr.", "Name", "Bemerkungen" und "Zahlwege", sowie genau ZWEImal den Begriff "BuSperre", wobei bei "BuSperre" immer nur das ZWEITE Auftreten erhalten bleiben soll.
Alles andere, außer den genannten Begriffen soll weg.
Ist das richtig so?

 

genau!

nur ich brauche die ganze zeile wo diese Begriffe vorkommen also von A - H .. der rest kann gelöscht werden!

 

Hallo!

Dann teste mal diesen Code, aber achte auf die GENAUE Schreibweise, z.B. beim ominösen Begriff "Bemerkgen"...

Code:

Sub Test()
  Dim Letzte As Long, i As Long, x As Long
  '***Letzte Zeile ermitteln:
  Letzte = IIf(Cells(Rows.Count, 4) = "", Cells(Rows.Count, 4).End(xlUp).Row, Rows.Count)
  '***Such von unten bis Zeile 5:
  For i = Letzte To 5 Step -1
    Select Case Cells(i, 4).Value
      '***Zeilen mit diesen Begriffen bleiben stehen:
      Case "Suchbegr.", "Name", "Bemerkgen", "Zahlwege"
      '***Jede zweite Zeile mit "BuSperre" wird gelöscht:
      Case "BuSperre"
        x = x + 1
        If x Mod 2 = 0 Then Rows(i).Delete
      '***Alle anderen Zeilen werden gelöscht:
      Case Else
        Rows(i).Delete
    End Select
  Next i
End Sub

 

Ich danke dir!!

Ich habe es versucht anzuwenden, jedoch beginnen die zeilen und alles zu "flimmern" .. als würde man scrollen und es hört aber nicht auf. das excel + vba prog. sind abgestürzt

 

Hallo!

Das Flimmern kannst du abschalten, aber abstürzen sollte der Code trotzdem nicht...

Code:

Sub Test()
  Dim Letzte As Long, i As Long, x As Long
  Application.ScreenUpdating = False
  Application.Calculation = xlCalculationManual
  Letzte = IIf(Cells(Rows.Count, 4) = "", Cells(Rows.Count, 4).End(xlUp).Row, Rows.Count)
  For i = Letzte To 5 Step -1
    Select Case Cells(i, 4).Value
      Case "Suchbegr.", "Name", "Bemerkgen", "Zahlwege"
      Case "BuSperre"
        x = x + 1
        If x Mod 2 = 0 Then Rows(i).Delete
      Case Else
        Rows(i).Delete
    End Select
  Next i
  Application.Calculation = xlCalculationAutomatic
  Application.ScreenUpdating = True
End Sub

 

sorry für doppelpost!

ich kanns kaum glauben "ES FUNKTIONIERT EINWANDFREI" !!

habe es nochmal versucht und nach kurzer zeit hat alles funktioniert.

ich danke dir für deine bemühung und schnelle antwort *im kreis vor freude hüpf*