Office: MAxwert Ergebnis als Spaltenname

Hallo zusammen...

Ich bin gerade dabei eine Tabelle anzulegen...klar excel.....

Hab da auch gleich mal ne Frage zur Auswertung...

Also ich hab in der Spalte "A" die Namen der Athleten eingetragen

In Zeile "2" sind ab Spalte "B" die verschiedenen Disziplinen eingetragen

In Zeile "65" ab Spalte "B" habe ich nun die Formel =KGRÖSSTE($B$6:$B$49;ZEILE(A1))
eingetragen um somit den besten Wert pro Disziplin angezeigt zu bekommen.

Um mir das Suchen jedoch zu vereinfachen, hätte ich lieber den jeweiligen Namen des besten Wertes in Zeile "65" als den besten Wert!!!!!

Hat jemand ne idee, wie ich das anstellen kann....

VD für eure Mühe
Gruß Flix

 

Hallo!

ungetestet:
=INDEX(A6:A49;VERGLEICH(KGRÖSSTE(B6:B49;ZEILE(A1));B6:B49;))

 

Super

Hallo,

danke für den ersten hat das super geklappt....

nur für den 2 besten in Zeile 66 klappt das, wenn ich statt
=INDEX(A6:A49;VERGLEICH(KGRÖSSTE(B6:B49;ZEILE(A1));B6:B49;))
=INDEX(A6:A49;VERGLEICH(KGRÖSSTE(B6:B49;ZEILE(A2));B6:B49;))

eingebe....
Aber beim drittbesten (selbe Punkte wie 2beste) kommt bei
=INDEX(A6:A49;VERGLEICH(KGRÖSSTE(B6:B49;ZEILE(A3));B6:B49;))
das selbe raus wie bei Zeile 66????


geht das och anders??? oder kan nic hda irgendwie in ranking einflicken???

VD
Gruß

 

Hallo!

Ja, bei Punktgleichheit zickt die Formel rum, da sie "nur" den ersten Treffer findet.

Probier diese:
=INDEX(A$6:A$49;VERGLEICH(KGRÖSSTE(B$6:B$49+ZEILE($6:$49)%%%;ZEILE(A1));B$6:B$49+ZEILE($6:$49)%%%;))

Achtung Matrixformel: Die Eingabe der Formel mit der Tastenkombination Strg+Shift+Enter abschließen!

 

hi Flix, kannst du mal (d)eine (beispiel)datei hochladen..?

 

Hallo,

sorry, dass ich hier poste, ist aber in nem anderen Forum auch schon mal angefragt!

	A	B	C
1			Hilfsspalte
2	ich	5	4,999998
3	du	5	4,999997
4	er	5	4,999996
5	sie	6	5,999995
6	es	3	2,999994
7	wir	2	1,999993
8	ihr	1	0,999992
9	sie	2	1,999991
10
11		sie
12		ich
13		du
14		er
15		es

Zelle	Formel
C2	=B2-ZEILE()%%%
C3	=B3-ZEILE()%%%
C4	=B4-ZEILE()%%%
C5	=B5-ZEILE()%%%
C6	=B6-ZEILE()%%%
C7	=B7-ZEILE()%%%
C8	=B8-ZEILE()%%%
C9	=B9-ZEILE()%%%
B11	=INDEX($A$2:$A$10;VERGLEICH(KGRÖSSTE($C$2:$C$10;ZEILE(A1));$C$2:$C$10;0))
B12	=INDEX($A$2:$A$10;VERGLEICH(KGRÖSSTE($C$2:$C$10;ZEILE(A2));$C$2:$C$10;0))
B13	=INDEX($A$2:$A$10;VERGLEICH(KGRÖSSTE($C$2:$C$10;ZEILE(A3));$C$2:$C$10;0))
B14	=INDEX($A$2:$A$10;VERGLEICH(KGRÖSSTE($C$2:$C$10;ZEILE(A4));$C$2:$C$10;0))
B15	=INDEX($A$2:$A$10;VERGLEICH(KGRÖSSTE($C$2:$C$10;ZEILE(A5));$C$2:$C$10;0))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

ohne hilsspalte ginge doch aber auch..:

=INDEX(A:A;VERGLEICH(KGRÖSSTE(B$1:B$10-ZEILE($1:$10)/9^9;ZEILE(A1));B$1:B$10-ZEILE($1:$10)/9^9;0))

als array-formel abzuschliessen (Strg+Umsch+Enter)

 

Hallo hab mal ein beispiel angefügt...

Danke für den Versuch....

Jetzt funktioniert 1. und 2. Stärke...3.,4.und5. aber nicht mehr.....

Und wie kann ich einstellen, dass bei meinem beispiel z.b. Sprint wichitger ist als schwimmen...

VD Gruß

 

Stärke 1-5 funktioniert doch...hab Strg+Shift+Enter vergessen....möööp

aber eien Frage bleibt... wie kann ich einstellen, dass schwimmen wichtiger als Sprint ist oder umgekehrt???
(siehe bsp oben)

VD Gruß

 

hi, ich habe das nun so verstanden..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1		Frank	Guido	Rudi	Sandro	Ralf	usw
2	Laufen	30	20	20	22	13	14
3	Schwimmen	29	10	15	17	18	9
4	Radfahren	6	8	18	19	22	10
5	Sprint	29	28	27	15	19	9
6	Weitsprung	28	27	19	10	9	22
7	Gewichtheben	22	29	17	28	19	30
8	usw
9
10
11	1. Stärke	Laufen	Gewichtheben	Sprint	Gewichtheben	Radfahren	Gewichtheben
12	2. Stärke	Schwimmen	Sprint	Laufen	Laufen	Sprint	Weitsprung
13	3. Stärke	Sprint	Weitsprung	Weitsprung	Radfahren	Gewichtheben	Laufen
14	4. Stärke	Weitsprung	Laufen	Radfahren	Schwimmen	Schwimmen	Radfahren
15	5. Stärke	Gewichtheben	Schwimmen	Gewichtheben	Sprint	Laufen	Schwimmen

Zelle	Formel
B11	{=INDEX($A:$A;VERGLEICH(KGRÖSSTE(B$2:B$10-ZEILE($2:$10)/9^9;ZEILE(A1));B$1:B$10-ZEILE($1:$10)/9^9;0))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

soweit so gut...so ist das schonmal richtig..zumindest wie ich das meine....

was muss ich an ihrer Formel ändern, wenn jetzt schwimmen und sprint den gleichen wert (hier 29) haben aber nicht mehr schwimmen wichtiger sein soll sondern sprint.... oder eine dritte sportart mit dem wert29 wichtiger als die anderen beiden sein sollen???

Was muss ich noch ändern, wenn meine Sportarten bei Zelle A6 starten und Zelle A49 enden???


=INDEX($A:$A;VERGLEICH(KGRÖSSTE(B$2:B$10-ZEILE($2:$10)/9^9;ZEILE(A1));B$1:B$10-ZEILE($1:$10)/9^9;0))
sorry

VD
Gruß

 

dann musst du das halt gewichten! wo ist das problem? aber wenn ich silex1 richtig vertsanden habe, handelt es sich hier um crossposting, ich "arbeite" nicht gern für den papierkorb, deswegen bin ich hier jetzt raus...!

 

ich weiß nicht was darin schlimm ist, in 2 verschiedenen foren nach einer antwort zu fragen...

für den papierkorb haben sie sicerlich nicht gearbeitet, im anderen orum kam nämlich niemand auf eine ähnlich gute lösung!!!!!

ich wäre ihnen trotzdem verbunden, wenn sie mir das mit der Gewichtung von den einzelnen Sportarten erklären könnten...

VD
und Gruß

P.S.: das mit denZellen 6bis49 hab ich trotz meiner wenigen Excell-Kenntnissen selbst hinbekommen...

 

Hallo Jörg,

Du arbeitest nicht für den Papierkorb! Alles Bestens.
Hab es nur erwähnt!
Aber in dem anderen Forum ist die Tabellendarstellung nicht möglich und Dateianhänge nur über externe Anbieter möglich!

Daher meine Bitte, hol den Entwurf aus dem Papierkorb! ;-)

 

hi Silex1, ich kann doch dem frager die gewichtung nicht abnehmen...