Office: Me.Steuerelement Variable zum Formular öffnen

Hallo,

hänge mal wieder an einer kniffeligen Sache. Und zwar habe ich eine Abfrage mit Spalte A, B, 0000, 0015, 0030, 0045, 0100, 0115 etc - für jede 15 Minuten am Tag eine Spalte (96 Spalten).
Ein Formular welches nun 96 + 2 Felder hat.

EINES der 96 Felder (Person) + die zwei Felder A (Datum) und B(Ort) definieren nun einen genauen Datensatz in der Ursprungs Tabelle.

In der Zeile im Formular wird mir alles angezeigt. Nun möchte ich aber die Person als Hyperlink definieren - beim Draufklicken soll sich ein Formular öffnen.

Frage - wie öffne ich das Formular mit der Variablen "Person". Muss ich nun 96 mal eine VBA Abfrage schreiben und für jedes Feld einzeln die Sache definieren? Oder gibts sowas wie Me.Control bzw. Me.Value etc. um immer den Inhalt auszulesen, von dem Namen den ich angeklickt habe?

Vielleicht denke ich zu kompliziert. Mit den drei Variablen möchte ich die TagesplanID in der Tabelle finden - die mit genau dann einen Datensatz öffnet.

Hier mein Code für eine Zelle... aber das geht auch noch nicht...

Code:

Private Sub I2345_DblClick(Cancel As Integer)
Dim searchID As String
searchID = DLookup("ScheduleID", [INFO_24_Feed_AC_SP_IP], "[IPSP] =" & Me.I2345 And "[ScheduleAC] = " & Me.AC_Registration And "[ScheduleDate] = &  # Me.ScheduleDate # ")
MsgBox searchID, vbInformation
End Sub

Aber es bringt nur Fehler. Ich klicke quasi auf das eigene Feld als Hyperlink - bekomme aber den Wert nicht raus.

 

So auf den ersten Blick könnte ich mir vorstellen, daß Du vielleicht mit einer RadioGroup was werden könntest. Mit dem OnClick-Event könntest Du dann den aktuellen Wert der RadioGroup auslesen und abhängig davon einen Datensatz in einem anderen Formular anzeigen.

Das hat aber, zumindest meiner Meinung nach, einen kleinen Haken:

Du hast jetzt schon 98+ Steuerelemente auf Deinem Formular. Das ist schon jenseits der Grenze, die ich normalerweise versuche, nicht zu überschreiten: ca. 50 Steuerelemente (ohne Label mitzuzählen). Mit der RadioGroup würden nochmal 97 (die Gruppe und die 96 RadioButtons) dazukommen.

Ok, die Rechner werden immer leistungsfähiger, es steht mehr Speicher zur Verfügung und in meinem grenzenlosen Optimismus glaube ich immer noch, daß die Anwendungen in neuerer Version auch auf Leistung optimiert sind. Aber ich erinnere mich noch zu häufig an Formulare, in denen eine Matrix (wie z.B. 52 Wochen in x- und 20+ Mitarbeiter in y-Richtung) dargestellt wurde und das Ding bei jeder Aktivität nur noch elendig auf dem Bildschirm "waberte".

Als "langsam" empfinden die meisten Anwender es eigentlich nicht, wenn eine Aktion mal mehrere Minuten dauert. Das wird schnell akzeptiert. Aber nach einem Mausklick 1/2 Sekunde verzögert eine Reaktion sehen, das ist meistens ein Grund für Meckereien.

Eventuell wäre aber auch das ein Ansatz:

Code:

Option Compare Database
Option Explicit

Dim ControlName_Name As String

' ----------------------------------------------------------------------

Private Sub ControlName_merken(s$)
    ControlName_Name = s
End Sub

Private Sub ControlName_anzeigen()
    MsgBox ControlName_Name
End Sub

' ----------------------------------------------------------------------

Private Sub Textfeld_1_GotFocus()
    ControlName_merken Me!Textfeld_1.Name
End Sub

Private Sub Textfeld_1_DblClick(Cancel As Integer)
    ControlName_anzeigen
End Sub

[...]

Das wäre dann zwar eine Fleißarbeit (2 Ereignisse für jedes Textfeld erfassen), würde aber ohne zusätzliche Steuerelemente auskommen.

Gruß, Michael

 

Da hab ich doch glatt den Anhang vergessen...

Gruß, Michael

 

Und außerdem zu kompliziert gedacht... Gerade eben fiel mir noch ein, daß man mit "ActiveControl" ja das aktivierte Objekt erhält, somit auch das Objekt mit Fokus. Das ganze Merken des Namens kann man sich also sparen und direkt:

Code:

Private Sub ControlName_anzeigen()
    'MsgBox ControlName_Name
    MsgBox ActiveControl.Name
End Sub

benutzen.

Gruß, Michael

 

Genial! Danke - so einfach kann es sein.

Nur noch eine Kleinigkeit - wie bekomme ich nun den Wert den ich in das Textfeld reingeschrieben habe bzw. aus der Datenbank kommt - auch mit raus?

MsgBox ActiveControl.Name 'Gibt mir ja den FeldNamen.
Und wie den Wert??
MsgBox ActiveControl.ItemData geht leider nicht.

Gruß Björn

 

Hallo nochmal... bin nun etwas weiter vorangekommen.
Aber - ich hänge noch an der übergabe von der "ActiveControl.Name" as String.

Code:

Private Sub I2345_Click()

Dim activBox As Variant
activeBox = "Me." & ActiveControl.Name
Dim activContent As String
activeContent = activeBox
Dim meContent As String
meContent = Me.I2345
Dim meAc As String
meAc = Me.AC_Registration
Dim meSchedule As String
meSchedule = Me.[INFO 24 Cross.ScheduleDate]

Dim searchID As String
searchID = DLookup("ScheduleID", "[INFO 24 Feed AC SP IP]", "[IPSP] = '" & meContent & "' And [ScheduleAC] = '" & meAc & "' And [ScheduleDate] = " & meSchedule)
MsgBox searchID
End Sub

Statt meContent = Me.I2345 hätte ich gerne meContent = activeBox
und das dann im DLookup drinnen... er nimmt mir bei activeBox das als TEXT wert - und nicht als Variable die auf ein Feldwert geht.

Desweiteren hänge ich am nachschauen vom "Datum" (meSchedule). Hab nun fast alle Varianten durch # meSchedule # oder ' & meSchedule & "'"

Denk ich wieder zu kompliziert??

 

Das mit dem Datum hab ich nun auf Industrie Datum umgestellt - sprich 40217 ist der 08.02.2010 - und somit läuft der Hase.

Code:

Dim meContent As String
meContent = Me.I2345
Dim meAc As String
meAc = Me.AC_Registration
Dim meSchedule As String
meSchedule = Me.XY

Dim searchID As String
searchID = DLookup("ScheduleID", "[INFO 24 Feed AC SP IP]", "[IPSP] = '" & meContent & "' And [ScheduleAC] = '" & meAc & "' And [ScheduleDateNumber] = " & meSchedule)
MsgBox searchID

Dim sWHERE As String
sWHERE = "[ScheduleID] = " & searchID

DoCmd.OpenForm "INFO24Schedule", acNormal, , sWHERE

Jetzt fehlt mir nur noch wie ich die meContent Variable als Feldabfrage übergeben kann.

 

activecontrol.value?

Gruß, Michael

 

Es könnte in der Richtung klappen:

Code:

Dim meContent As String
meContent = Me!I2345.value
Dim meAc As String
meAc = Me!AC_Registration.value
Dim meSchedule As String
meSchedule = Me!XY.value
[...]

Benutzt Du eigentlich "option explicit" in Deinem Source? In einem anderen Posting paßten die DIM nicht zu den Variablen. Da hattest Du immer ein "e" bei "active" vergessen...

Und das mit dem Datum... Ich hab dafür eine kleine Umwandlungs-Routine namens "SQL_Date" gebastelt. Diese wandelt mir ein Datum (also eine Variant-Variable) in einen String um. Und der hat dann das amerikanische Format "#jjjj/mm/dd#" (Oder war mm und dd auch noch anderes herum? Bin mir jetzt nicht ganz sicher...). Damit kann man dann DlookUp, SQL-Queries und Konsorten füttern.

Aber meistens benutze ich auch eher das Industriedatum, weil es "gefühlt" leichter zu handhaben ist, insbesondere wenn es um Zeitrechnung (Stunden) geht.

Gruß, Michael

 

Hallo Michael,

na die Abfrage funktioniert soweit.

Nur möchte ich statt:

Code:

meContent = Me!I2345.value 

lieber:

Code:

meControl = activecontrol.name

benutzen.

Ich bekomme zwar den "Text" aus dieser Variable ...
Aber benütze ich nun meControl als ein Teil der Bedingung
z. B.

Code:

ControlValue = Me!&meControl

Dann bekomme ich den Wert Me!I2345 als "Text" und nicht dann den Feld.Value z.B. "München"

Wenn das nicht geht - muss ich halt für jedes einzelne Feld den Me!I2345 ; Me!I2330; Me!I2315 etc anpassen....

Also den Steuerelement Namen als Teil eines Strings hernehmen....

 

Ich muß gestehen... Ich bin verwirrt...

Mit activecontrol.name hast Du den Namen des Controls, auf dem der Doppelklick stattfand. Mit activecontrol.value hast Du den Wert, der in diesem Control steht. Und wenn der Name des Controls dem Feld in der Tabelle entspricht, kannst Du den auch direkt für die Abfrage benutzen.

Also z.B. Du hast ein Control "Nachname" auf Deinem Formular. In der Tabelle "tbl_Adressen" gibt es ebenfalls ein Feld "Nachname". Die ControlSource von "Nachname" ist das Feld "[Nachname]" aus der entsprechenden Tabelle. Und in dem Feld steht im aktuellen Datensatz z.B. ein "Schmidt" als Value.

Ein Doppelklick mit dem passenden Ereignis

Code:

MsgBox "Control: " & ActiveControl.Name & Chr$(10) & "Value: " & ActiveControl.Value

würde Dir jetzt

Code:

Control: Nachname
Value: Schmidt

zurückgeben.
Und für eine Abfrage läßt sich das direkt weiter verarbeiten:

Code:

s = "SELECT * FROM tbl_adressen WHERE [" & ActiveControl.Name & "] = '" & ActiveControl.Value & "';"
MsgBox s

Problematischer wird es erst, wenn Deine Control-Namen nicht den Feld-Namen in der Tabelle entsprechen. Dann kannst Du aber immer noch über activecontrol.controlsource den Feldnamen herausfinden.

Code:

Private Sub ControlName_anzeigen()

    Dim control_name As String
    Dim control_value As String
    Dim control_source As String

    Dim sql_select As String
    Dim sql_from As String
    Dim sql_where As String
    Dim sql_query As String

    control_name = ActiveControl.Name
    control_value = ActiveControl.Value
    control_source = ActiveControl.ControlSource

    MsgBox "Control: " & control_name & Chr$(10) & "Value: " & control_value & Chr$(10) & "Source: " & control_source

    sql_select = "*"
    sql_from = "tbl_staedte"
    sql_where = "[" & control_source & "] = '" & control_value & "'"
    sql_query = "SELECT " & sql_select & " FROM " & sql_from & " WHERE " & sql_where & ";"
    MsgBox sql_query

    DoCmd.OpenForm "frm_ControlName_Name_Details", , , sql_where

End Sub

So kannst Du ein neues Formular öffnen und dort alle Datensätze anzeigen, die zu dem Doppelklick-Control passen. Ich hab das ursprüngliche Beispiel mal etwas aufgebohrt und eine "tbl_staedte" darunter gelegt, die aus den Feldern "Land", "Bundesland" und "Stadt" besteht. Das Formular hab ich zu "endlos" gewandelt und eine Kopie davon erstellt.

Wenn du jetzt z.B. auf die mittlere Spalte "Bundesland" einen Doppelklick auf einem Feld mit z.B. dem Wert "Schleswig-Holstein" machst, öffnet sich das 2. Formular mit eben nur diesen passenden Datensätzen. Die eine oder andere Messagebox dazwischen macht es vielleicht noch etwas deutlicher.

Ich hoffe, ich habe Dich jetzt richtig verstanden. Ansonsten müßtest Du es vielleicht doch noch etwas klarer herausstellen...

Gruß, Michael

 

Hallo Michael,

sorry für die Verwirrung...

Also ganz einfach meContent durch ActiveControl.Value - und es läuft :-)

Den Zwischenschritt das ActiveControl.Value an eine Variable übergeben war überflüssig - hat mich aber durchaus einige Stunden verwirrt.

Danke nochmals!