Office: (Office 365) Median mit mehreren Bedingungen.

Helfe beim Thema Median mit mehreren Bedingungen. in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, ich hoffe mir kann jemand weiterhelfen. In einer Excel-Datei habe ich für ein gesamtes Jahr die Arbeitszeiten pro Tag aufgeführt.... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von skh2510, 8. Dezember 2022.

  1. skh2510 Neuer User

    Median mit mehreren Bedingungen.


    Hallo zusammen,

    ich hoffe mir kann jemand weiterhelfen.
    In einer Excel-Datei habe ich für ein gesamtes Jahr die Arbeitszeiten pro Tag aufgeführt. Jetzt möchte ich den Median der Monate April bis Oktober jeweils für Montag, Dienstag, Mittwoch, etc. errechnen.
    In Spalte B stehen die Zahlen der Monate; 1=Januar, etc
    In Spalte C stehen die Wochentage; Mo, Di, Mi, etc.
    In Spalte E stehen die Arbeitszeiten pro Tag

    R3 = Mo für Montag

    Dazu habe ich folgende Formel erstellt:
    =MEDIAN(WENN(UND(C4:C368=R3;B4:B368>=4;B4:B368<=10);E4:E368))

    Es funktioniert aber leider nicht. Ich habe auch schon ">="&4 (ebenso bei der 10) ausprobiert und ich habe auch schon STRG+Alt+Enter ausprobiert.
    Habt ihr eine Idee, was ich falsch mache und wie es richtig geht?

    Vielen lieben Dank und viele Grüße!
     
    skh2510, 8. Dezember 2022
    #1
  2. steve1da Office Guru
    Hola,
    das schreibt man nicht mit UND:
    =MEDIAN(WENN((C4:C368=R3)*(B4:B368>=4)*(B4:B368<=10);E4:E368))
    Gruß,
    steve1da
     
    steve1da, 8. Dezember 2022
    #2
  3. skh2510 Neuer User
    Super, vielen lieben Dank, es funktioniert :-)
     
    skh2510, 8. Dezember 2022
    #3
  4. skh2510 Neuer User

    Median mit mehreren Bedingungen.

    Jetzt habe ich das nächste Problem:
    Wenn ich nun das gleiche für Januar bis März und Oktober bis Dezember machen möchte, habe ich folgende Formel eingegeben:
    =MEDIAN(WENN((C4:C368=R3)*(B4:B368<=3)*(B4:B368>=10);E4:E368))
    das funktioniert nicht. Dann habe ich das hier eingegeben:
    =MEDIAN(WENN((C4:C368=R3)*(B4:B368>=1)*(B4:B368<=3)*(B4:B368>=10)*(B4:B368<=12);E4:E368))
    weil ich dachte, dass das Problem vielleicht mit der 0 zusammenhängt, aber auch das funktioniert nicht.

    Habt ihr noch Ideen?

    Vielen lieben Dank und viele Grüße.
     
    skh2510, 8. Dezember 2022
    #4
  5. steve1da Office Guru
    Das kann auch nicht klappen. Das sind alles UND Abfragen und aktuell suchst du eine Monatszahl die gleichzeitig kleiner als 3, größer als 10 und in der zweiten Formel größer als 1, kleiner als 3, größer als 10 und kleiner als 12 ist.
    Welche Zahl soll denn das sein?
     
    steve1da, 8. Dezember 2022
    #5
  6. skh2510 Neuer User
    Dass * wie UND funktioniert war mir nicht bewusst. Mit einer ODER-Funktion hat es jetzt geklappt.
    Vielen Dank!
     
    skh2510, 8. Dezember 2022
    #6
  7. skh2510 Neuer User
    Hat jemand auch noch eine Idee, wie ich von den gleichen Zahlen von März bis September einen Mittelwert bilden kann. Hier scheint das hier nicht zu funktionieren:
    =MITTELWERTWENNS(E4:E368;C4:C368;R3;B4:B368;ODER((>=1)*(<=3);(>=10)*(<=12)))

    Vielen Dank im Voraus.
     
    skh2510, 8. Dezember 2022
    #7
  8. HKindler
    HKindler hat Ahnung

    Median mit mehreren Bedingungen.

    Hi,

    weder ODER() noch UND() funktionieren in solchen Formeln. Da muss man dann schon den Trick mit * bzw. + anwenden.
    Und rechnen kann man in den ganzen xxxWENN(s)-Formeln auch nicht.
    Da muss man dann schon =MITTELWERT(WENN(xxx)) (bei altem Excel als Matrix-Formel mit Strg-Shift-Enter abschließen) oder SUMMENPRODUKT(xxx) verwenden:

    {=MITTELWERT(WENN((C4:C368=R3)*((B4:B368>=1)*(B4:B368<=3)+(B4:B368>=10)*(B4:B368<=12));E4:E368))}

    =SUMMENPRODUKT((C4:C368=R3)*((B4:B368>=1)*(B4:B368<=3)+(B4:B368>=10)*(B4:B368<=12))*E4:E368)/SUMMENPRODUKT((C4:C368=R3)*((B4:B368>=1)*(B4:B368<=3)+(B4:B368>=10)*(B4:B368<=12)))

    =LET(b;B4:B368;MITTELWERT(WENN((C4:C368*((b>=1)*(b<=3)+(b>=10)*(b<=12));E4:E368)))

    =LET(b;B4:B368;x;(C4:C368=R3)*((b>=1)*(b<=3)+(b>=10)*(b<=12));SUMMENPRODUKT(x*E4:E368)/SUMMENPRODUKT(x))

    Alles ungetestet....

    Übrigens: theoretisch müsste (b<=3)*(b>=10) auch schon ausreichen. Oder hast du einen Monat 0 oder 13 in deiner Tabelle stehen?
     
    HKindler, 8. Dezember 2022
    #8
  9. neopa C hat Ahnung
    Hallo,

    zumindest für letzteres (Mittelwertermittlung) würde ich eine Pivotauswertung bevorzugen. Evtl. hat man in XL365 damit auch die Möglichkeit den Median zu ermitteln. In meiner älteren XL-Version (XL 2016) ist das leider noch nicht der Fall. Aber mit Power Query ist da auch eine Median-Auswertung möglich.
     
    neopa C, 8. Dezember 2022
    #9
  10. lupo1
    lupo1 Tutorial Guru
    (b-3<8) oder (b-3>7) (für das Komplement) reduziert die Sache um einen Term
    _______________________________________

    Mit der in [LAMBDA] schnelles Summen-Pivot genannten Alleskönner-Highspeed-Superformel kannst Du in Deinem 365 eine einzige Formel anwenden:

    =PVT(HSTAPELN(TEXT(B4:B368;"00")&"|"&C4:C368;E4:E368);{1.4.10})

    Die 1 zeigt Dir den Bezeichner an: 01|Mo z.B.
    Die 4 zeigt Dir dabei die Anzahl 4 oder 5 Wochentage pro Monat an - als Kontrolle für den Median, der bei 4 gemittelt und bei 5 treffgenau ist.
    Die 10 gibt den Median des Bezeichners zurück.

    Mit FILTER drumrum blendest Du dann noch ungewünschte Monate aus.
     
    Zuletzt bearbeitet: 8. Dezember 2022
  11. skh2510 Neuer User
    Vielen lieben Dank für die vielen guten Antworten!
    Es hat tatsächlich geklappt mit:
    =MITTELWERT(WENN((C4:C368=R3)*((B4:B368>=1)*(B4:B368<=3)+(B4:B368>=10)*(B4:B368<=12));E4:E368))

    Die anderen werde ich auch noch ausprobieren. Gerade die "Alleskönner-Highspeed-Superformel" klingt interessant :-)
     
  12. lupo1
    lupo1 Tutorial Guru
    ungetestet kürzbar auf
    =MITTELWERT(WENN((C4:C368=R3)*(REST(B4:B368+2;12)<6);E4:E368))
     
  13. skh2510 Neuer User

    Median mit mehreren Bedingungen.

    =MITTELWERT(WENN((C4:C368=R3)*(REST(B4:B368+2;12)<6);E4:E368))
    getestet und funktioniert gut! :-) Vielen Dank! :-)
     
Thema:

Median mit mehreren Bedingungen.

Die Seite wird geladen...
  1. Median mit mehreren Bedingungen. - Similar Threads - Median mehreren Bedingungen

  2. Median mit Teilergebnis

    in Microsoft Excel Hilfe
    Median mit Teilergebnis: Hallo zusammen, ich bräuchte Hilfe bei der Formel im Blatt "OKI" Spalte H. In der Spalte H, sollte unter Berücksichtigung der Teilergebnisse, der Median ausgegeben werden. Nach meiner Berechung...
  3. Berechnen des Medians einer Gruppe von Zahlen

    in Microsoft Excel Tutorials
    Berechnen des Medians einer Gruppe von Zahlen: Berechnen des Medians einer Gruppe von Zahlen Excel für Microsoft 365 Excel für Microsoft 365 für Mac Excel für das Web Excel 2019 Excel 2016 Excel...
  4. MEDIAN-Funktion

    in Microsoft Excel Tutorials
    MEDIAN-Funktion: MEDIAN-Funktion Excel für Microsoft 365 Excel für Microsoft 365 für Mac Excel für das Web Excel 2019 Excel 2016 Excel 2019 für Mac Excel 2013...
  5. Median aus Abfrage

    in Microsoft Access Hilfe
    Median aus Abfrage: Hi, ich möchte den Median aus Werten einer Abfrage berechnen. Meine Idee war ich Zähle wieviele Datensätze vorhanden sind, Teile diesen Wert durch 2 und nehme das Ergebnis um mir den Wert...
  6. MEDIANWENNS-Funktion

    in Microsoft Excel Hilfe
    MEDIANWENNS-Funktion: Hallo, ich verzweifele gerade an einer für meine Begriffe sehr simplen Aufgabe. Ich suche nach einem Äquivalent zur MITTELWERTWENNS-Funktion, die ich bereits in meine Tabelle eingebaut habe:...
  7. Median, Fehlerindikatoren, Minimum un Maximum gleichzeitig in Diagramm Excel 2010

    in Microsoft Excel Hilfe
    Median, Fehlerindikatoren, Minimum un Maximum gleichzeitig in Diagramm Excel 2010: Hallo zusammen Ich möchte in einem Diagramm Median mit den Fehlerindikatoren und zusätzlich noch das Minimum und Maximum zum Beispiel mit einem Punkt darstellen. Ich bin soweit, dass ich ein...
  8. Median berechnen nach Prinzip der SummeWenn Funktion???

    in Microsoft Excel Hilfe
    Median berechnen nach Prinzip der SummeWenn Funktion???: Hallo zusammen, ich bin ein bisschen verzeifelt. Alleine komme ich mit meinem Problem nicht weiter, deshalb hoffe ich, dass mir hier jemand weiter helfen kann... Es geht um die Berechung...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden