Office: Mehrere Bedingungen in Wenn Dann Funktionen

Hallo Ich habe ein Problem mit einer Wenn Dann Funktion.

Ich habe eine Tabelle in der ich den kompletten Prozess eines Auftrages verfolgen will, d.h. vom Auftrag bis zur Rechnungsstellung. Um mir die verschiedenen Stati anzeigen zu lassen habe ich eine Wenn Dann Funktion verwendet (d.h. z.B. Angebot versandt, Ware bestellt vom Kunden, Ware bestellt beim Lieferant)
Leider zeigt mir die Funktion immer nur an Angebot versandt und nichts anderes, egal was ich eingebe. Hat hier vielleicht jemand eine Idee? Wäre klasse wenn mir jemand helfen könnte.

Anbei noch die Formel mit der ich dachte, dass es funktioniert
=IF(H114<>0;"Angebot versand";IF(AND(H114<>0;N114<>0);"Kunde hat bestellt";IF(AND(N114<>0;P114<>0);"Ware bestellt beim Lieferant";IF(AND(R114<>0;J114="ja");"erledigt und gebucht";IF(J114="nein";"kein Auftrag";"?")))))

viele Grüße

Markus

 

Hallo Markus -

Es ist klar, daß Du in den meisten Fällen die Anzeige "Angebot versandt" bekommst; nämlich immer dann, wenn in H114 irgend etwas steht. Das hast Du im Anfang Deiner Formel festgelegt:

=IF(H114<>0;"Angebot versandt"; ...

D. h. nur wenn H114 leer ist, hast Du eine Chance, etwas Anderes angezeigt zu bekommen.

Da ich mir so nicht vorstellen kann, was in
H114 ... J114 ... N114 ... P114 ... R114
eingetragen ist, wären nähere Infos hilfreich. Vielleicht beschreibst Du noch mal genau, welche Anzeige Du in welchen Fällen bekommen möchtest.

 

Hallo Krino

Hallo Krino,

Vielen Dank erstmal für die schnelle Antwort.
Im Anhang habe ich eine Datei, in der ich mal die Tabelle beispielhaft ausgefüllt habe.
In zeile 13 müßte bei Status stehen "Angebot versandt", in Zeile 14 "Kunde hat bestellt", in Zeile 15 "Ware bestellt beim Lieferanten", in Zeile 16 "gebucht und erledigt" und in Zeile 17 kein Auftrag.

Man soll praktisch immer den Status des Angebotes bekommen wenn ich dann z.b. in Spalte das Datum der Kundenbestellung eintrage dann sollte kommen Kunde hat bestellt, wenn ich in Spalte p das Datum eingebe soll kommen "Ware bestellt beim Lieferant" usw.

 

Hallo Markus -

Kopiere in F13 die Formel

=WENN((H13<>0)*(J13="ja")*(N13<>0)*(P13<>0)*(R13<>0);"gebucht und erledigt";WENN((H13<>0)*(J13="ja")*(N13<>0)*(P13<>0);"Ware bestellt beim Lieferanten";WENN((H13<>0)*(J13="ja")*(N13<>0);"Kunde hat bestellt";WENN((H13<>0)*(J13="nein");"Kein Auftrag";"Angebot versandt"))))

und kopiere sie nach unten.

Ich hänge die Datei mit der Formel noch mal an, falls Du eine englische Version hast.

 

Hallo Krino

Hallo Krino

vielen vielen Dank :lol:

Jetzt hätte ich noch kleinere Fragen.
Der * (Stern) heißt dann das diese Bedingungen alle erfüllt sein müssen, oder bzw. wenn diese Bedingungen aller erfüllt sind dann erscheint der jeweilige Text?
Was heißt denn die 1 bei "IF((H117<>0)*(J117="ja")*(N117<>0)*(P117<>0)=1"

Nochmals vielen vielen Dank

Grüße

markus

 

Hallo Markus -

Da hast Du mich gleich auf einen Flüchtigkeitsfehler aufmerksam gemacht; das "=1" kannst Du ersatzlos löschen. Ich nehme beim Erstellen längerer Formeln manchmal zunächst einfache Beispielgleichungen, um mich nicht völlig in den Klammern zu verheddern. Die Eins war wohl ein Überbleibsel von so einer Hilfskonstruktion; habe sie inzwischen beseitigt.

Man hätte auch jeweils AND nehmen und die Bedingungen mit Semikolon trennen können.
Ich habe mir angewöhnt, UND und ODER zu vermeiden und stattdessen Multiplikation bzw. Addition der Booleschen Ausdrücke zu nehmen; man kann so die Formeln etwas kürzer halten. Ist aber eine Geschmacksfrage. Das Sternchen ist das normale "Mal"-Zeichen; es steckt nichts Großes dahinter.

Beispiel:
=WENN(UND(B3<>0;C3<>0);"aaa";"bbb")
hat die gleiche Bedeutung wie
=WENN((B3<>0)*(C3<>0);"aaa";"bbb")

Die roten Klammern, sog. Boolesche Ausdrücke, haben als Ergebnis entweder WAHR oder FALSCH; anders gesagt, 1 oder 0.
1 x 1 = 1; Ausgabe aaa
0 x 1 = 0; Ausgabe bbb
1 x 0 = 0; Ausgabe bbb
0 x 0 = 0; Ausgabe bbb
Man sieht also, die Multipikation der Klammern gibt die gleichen Ergebnisse wie die UND-Abfrage.

Entsprechend Addition als Ersatz für ODER.