Office: Mehrere Spalten durchsuchen und Wert von anderen Zelle ausgeben

Hallo,
Ich komm hier leider nicht auf eine Lösung und hoffe hier kann mir wer weiterhelfen. :-)
Ich bräuchte die Mengen die in der Übersicht sind, dann jeweils neben Größe und Farbe in dem zweiten Excel.

Hier hab ich die Mengen pro Style# und Farbe


und hier bräuchte ich die Mengen pro Spalte


Vielen Dank im Voraus

Ganz liebe Grüße

 

Hallo,

ich habe dir in der beiliegenden Datei in Zelle D16 folgende Formel eingefügt:
=SUMMEWENNS(INDEX($D$4:$L$13;0;WENNFEHLER(VERGLEICH($C16;$D$2:$L$2;0);VERGLEICH($C16;$D$1:$L$1;0))); $A$4:$A$13;$A16; $B$4:$B$13;$B16)
Diese Formel habe ich dann in die restlichen Zellen (Bereich D17:D31) kopiert.
Datei liegt bei.

 

Hallo,

etwas übersichtlicher sieht vorgenannte Formel wie folgt aus:

 

Hi, Ihr seid spitze. Beide Formeln funktionieren :-)
Vielen lieben Dank

 

Noch eine kurze Frage - Wenn ich jetzt eine weitere Größenangabe habe wie zb 14.15.16.17.18. funktioniert es nicht wenn ich eine dritten VERGLEICH(....) hinzufüge?

Danke

 

Hallo,

das ist klar, das kommt davon, wenn zuerst versucht wird, mittels Salami-Taktik nur einen Teil des Problems darzustellen.

Angenommen: Deine dritte Größenskala befinde sich im Bereich D3:L3. Dann lautet die neue Formel:

Wie du siehst, muss die alte WENNFEHLER-Funktion in eine weitere äußere WENNFEHLER-Funktion verschachtelt werden.
=SUMMEWENNS(INDEX($D$4:$L$13; 0; WENNFEHLER(WENNFEHLER(VERGLEICH($C16; $D$2:$L$2; 0); VERGLEICH($C16; $D$1:$L$1; 0)); VERGLEICH($C16; $D$3:$L$3; 0))); $A$4:$A$13; $A16; $B$4:$B$13; $B16)

 

Hallo,

Für Excel 365: eine Formel für die gesamte Tabelle (Siehe angehängte Datei).

Code:

=LET(y,ZÄHLENWENN($D$4:$L$8,">0"),z,$D$4:$L$8>0,WAHL({1\2\3\4},INDEX($A$4:$A$8,AGGREGAT(15,6,ZEILE($A$1:$A$5)/z,SEQUENZ(y))),INDEX($B$4:$B$8,AGGREGAT(15,6,ZEILE($A$1:$A$5)/z,SEQUENZ(y))),INDEX($D$1:$L$2,VERGLEICH(INDEX(C4:C8,AGGREGAT(15,6,ZEILE($A$1:$A$5)/z,SEQUENZ(y))),C1:C2,0),NACHSPALTE(SPALTE($A$4:$L$8)/z,2)),NACHSPALTE(D4:L8,1)))

 

Hallo,

ich habe bemerkt, dass im Posting #6 in meiner Formel ein Fehler enthalten war. Die Formel muss lauten:
=SUMMEWENNS(INDEX($D$4:$L$13; 0; WENNFEHLER(WENNFEHLER(VERGLEICH($C16; $D$2:$L$2; 0); VERGLEICH($C16; $D$1:$L$1; 0)); VERGLEICH($C16; $D$3:$L$3; 0))); $A$4:$A$13; $A16; $B$4:$B$13; $B16; $C$4:$C$13; INDEX($C$1:$C$3;MIN(WENN($D$1:$L$3=$C16;ZEILE($1:$3)))))
Es kann sein, dass du diese Formel als Array-Formel eingeben musst (Abschluss der Formeleingabe mit der Tastenkombination UMSCHALT+Strg+EINGABE), sodass sie danach in geschweiften Klammern eingeschlossen erscheint.
Das hängt von deiner Excel-Version ab.

 

Hi Zusammen, ich hab probiert und probiert, bekomm es aber leider nicht hin :-(
Meine möglichen Sizeruns sind 35 Zeilen. Vielleicht könnt ihr euch das nochmal anschauen bitte?
Hab jetzt ein komplettes Beispiel hochgeladen.
Ziel wäre es dass ich in Tab2 immer die Daten und Größen einfüge und sie mir dann in Tab1 dann immer pro Zeile hinzugefügt werden.

Danke danke euch im Voraus
Liebe Grüße

 

Hallo,

da du nirgends deine Excel-Version angegeben hast, nehme ich an, dass du Excel365 hast.
Dafür habe ich dir in Zelle F2 (und folgende) des Arbeitsblattes "Tabelle1" folgende Formel eingefügt:
=LET(styleKr; $C2; colorKr; $D2; sizeKr; $A2; dt; Tabelle2!$T$38:$AQ$52; zlKr; Tabelle2!$A$38:$S$52; spKr; Tabelle2!$S$2:$AQ$36; spGrKr; WEGLASSEN(spKr; ; 1); spGrBez; SPALTENWAHL(spKr; 1); spGrI; ZUZEILE(spGrKr); spGrAnz; SPALTEN(spGrKr); zlGrAnz; ZEILEN(spGrKr); spDtI; VERGLEICH(sizeKr; spGrI; 0); spDt; REST(spDtI; spGrAnz); zlDt; (spDtI - spDt) / spGrAnz + 1; SUMMEWENNS(INDEX(dt; 0; spDt); INDEX(zlKr; 0; 8); styleKr; INDEX(zlKr; 0; 7); colorKr; INDEX(zlKr; 0; 19); INDEX(spGrBez; zlDt)))

Falls in Spalte A Größenangaben enthalten sind, die nicht existieren, liefert die Formel pflichtgemäß "#NV!" = nicht verfügbar.
Falls sonstige Kombinationen (von Style = Spalte C bzw. von Color = Spalte D) enthalten sind, zu denen es keine Mengen gibt, ergibt die Formel den Wert 0.
Mit den oben in der Formel fett geschriebenen Zell(bereich)en wird die Formel gefüttert.

Etwas übersichtlicher erscheint die Formel in folgendem Add-In von Microsoft:

Die modifizierte Datei liegt bei.

 

DANKE, es funktioniert jetzt. Mega mega danke. Das is ne riesige Arbeitserleichterung für mich :-)

DANKE