Office: (Office 2013) Mehrere Werte aus andere Spalte vergleichen und abgleichen

Ich habe ein Problem mit einer großen Datenmenge, in der unvollständige DS vorliegen.
Es gibt 2 Spalten mit einer Identifikationsnr. In einer Spalte eine eindeutige KundenID, in der zweiten eine für den jeweiligen Auftrag, der aber leider mehrerer Zeilen/Materialien haben kann. (dann alle mit derselben AuftragsID). Nun fehlen leider die KundenID bis auf jeweils einmal bei Anlage des Auftrags. Die übrigen Zellen sind leer und damit nicht zuzuordnen.
Es müsste also in der Spalte A (KdID)nachgesehen werden, ob sie leer ist. Falls ja muss überprüft werden, ob mit der AuftragsID ein Eintrag mit KundenID vorliegt und dieser Wert dann in den entsprechenden Feldern übernommen werden.
Geht das? Vielen Dank

 

Hallo,

in der beiliegenden Excel-Datei habe ich dir deine Vorgaben mit einem VBA-Makro "KdNr_Nachtragen" in einem allgemeinen Codemodul ergänzt.
Aufgerufen wird das Makro mit der Tastenkombination Alt+F8
Es setzt voraus, dass Spalte A die Kundennr. und Spalte B die AuftragNr. enthält, wobei die Leerzellen von Spalte A ergänzt werden, soweit dies möglich ist.

Code:

Option Explicit

Dim colAuftrgID As New Collection

Sub KdNr_Nachtragen()
  Dim rngZeilen As Range
  Dim Durchgang As Byte
 
  On Error GoTo Err_AuftrgID
 
  For Durchgang = 1 To 2
      For Each rngZeilen In Range("A1").CurrentRegion.Rows
        With rngZeilen
          If .Cells(1) = 0 Then
            'KundenID ist leer: Teste, ob eine AuftrgID (bereits) vorhanden
            'Ja, AuftrgID ist vorhanden; Trage ihre KundenID ein:
            .Cells(1) = colAuftrgID(CStr(.Cells(2)))
            'Nein, AuftrgID ist (noch) nicht vorhanden; gehe zur nächsten Zeile
          Else
            If Durchgang = 1 Then
              'KundenID liegt soeben vor: nimm KundenID/AuftrgID in die Collection auf
              colAuftrgID.Add Item:=CStr(.Cells(1)), Key:=CStr(.Cells(2))
            Else
              'KundenID liegt bereits vor: tue nichts, gehe zur nächsten Zeile
            End If
          End If
        End With
Nxt_AuftrgID:
      Next rngZeilen
  Next Durchgang
 
  Set colAuftrgID = Nothing
  Exit Sub
 
Err_AuftrgID:
  Resume Nxt_AuftrgID
End Sub

 

Vielen Dank für die Mühe
ich scheitere an Option Explicit > Syntax Fehler ? liegt das an mir? ich habe es jetzt lediglich in ein Makro kopiert.

 

Hallo,

hast du gesehen, dass ich dir die Excel-Datei "Uwe_Test-KundenNr.xlsm" ins Forum hinaufgeladen habe?

Oder aber es ist obiger VBA-Code ohne das Wort "Code:" zur Gänze in ein allgemeines Codemodul zu kopieren, wobei natürlich darauf zu achten ist, falls dort bereits ein "Option explicit" enthalten ist, dass dieses nur 1x und zwar am Anfang des Moduls als erste Zeile eingefügt wird (bzw. enthalten ist).

Durch das "Option Explicit" kann der Compiler überprüfen, ob alle Variablen, die im Programmtext vorkommen, auch tatsächlich deklariert sind. Bei einem so kurzen Progrämmchen wie das obige mag es keine besondere Hilfe darstellen, aber bei längeren Programmen ist es außerordentlich hilfreich. Es können so automatisch auch alle Tippfehler innerhalb von Variablenbezeichnern entdeckt werden, sodass man sich nicht zu Tode suchen muss, um irgendwelche Bugs im Text (aufgrund von Tippfehlern) aufzuspüren. Nur unerfahrene Programmierer lassen es daher weg.

 

Super - funktioniert prima
Vielen Dank

 

Einen sehr empfehlenswerten Blog über Variablen und mehr findest Du hier:
Online - Excel Programmierung VBA Makro: Option Explicit, Intellisense und Techniken des Schreibens

Mal ein Beispiel:

Code:

Dim MeineExtremLangeUndSchwerZuMerkendeVariable As Long

Im Editor gebe ich Später mei (klein geschrieben, im Editor sollte man außerhalb der Variablendeklaration IMMER klein schreiben), gefolgt durch Strg + Leertaste ein.
Der Editor macht daraus wie durch Magie MeineExtremLangeUndSchwerZuMerkendeVariable

Ist tatsächlich so, dass die Beschriftung auf meiner linken Strg-Taste nicht mehr zu sehen ist. ;)