Office: Mehrfaches Summieren in einer Spalte

Hallo ,

ich habe eine Spalte mit Einzelwerten, die immer wieder durch eine Leerzeile unterteilt werden.
Um diese Einzelwerte jeweils in der Summenzeile zusammen zu rechnen kann ich die Summenfunktion nicht verwenden.

z.B Spalte B
5
8
Summe

13
11
9
16
Summe

etc.

In der Spalte B stehen also jeweils einige Zahlen und sollen dann einzeln in der darunterfolgenden Summenzeilen zusammengerechnet werden. Es kann eine einzelne Zahl oder aber mehrer Zahlen sein.

 

Hallo,

in der selben Spalte geht es nicht, aber in der Nachbarspalte kann man folgendes machen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1
2	5
3	8
4	Summe	13
5
6	13
7	11
8	9
9	16
10	Summe	49

Zelle	Formel
B2	=WENN(A2="Summe";SUMME($A$2:A2)-SUMME($B$1:B1);"")

Die WENN() Bedingung kannst Du individuell anpassen.

 

Hallo vielen Dank aber das ist für mich nicht gut praktizierbar.
Ich habe jeweils unter den einzelnen Zahlen die Summenzeile. Die Zahlen
die in der Spalte stehen und mal 2 mal 8 mal 45 sind sollten jeweils in der gleichen Spalte zusammen gezählt werden.
Händisch ist dies mit der Tastenkombination ALT+SHIFT+0 möglich.

Aber ein Makro das dies genau so erledigt, da weiss ich nicht wie dies funktioniert.

Danke

Eisbubi

 

Hallo,

da ich von VBA null Ahnung habe, würde ich wie folgt vorgehen:

Bereich markieren+eine Leerzeile
F5 drücken
Button : "Inhalte..." drücken
"Leerzellen" markieren und OK drücken

in die Bearbeitungsleiste klicken, Alt+Shifttaste gedrückt halten und 2x ne Null tippen.
Somit sind sind alle Summen ausgerechnet.

Wenn es Dir auch wieder nicht gefällt, muss mal ein VBA-ler drüber schauen.

 

Hallo,

in der beiliegenden Excel-Datei ist folgendes VBA-Makro im allgemeinen Codemodul enthalten:

Code:

Sub Spalten_Addieren()
  Dim rgArea As Range, rgCol As Range, rgSumme As Range
  '
  With ActiveSheet.Cells.SpecialCells(xlCellTypeConstants)
    For Each rgArea In .Areas
        For Each rgCol In rgArea.Columns
          With rgCol
            Set rgSumme = .Offset(.Rows.Count).Resize(1, 1)
            rgSumme.Formula = "=SUM(" & .Address & ")"
          End With
        Next rgCol
    Next rgArea
  '
  End With
  '
End Sub

Drückt man die Tastenkombination Alt+F8 erscheint die Makroauflistung. Wählt man den Button "Ausführen", wird unter alle Zahlenspalten die entsprechende Summenformel platziert.
Voraussetzung ist, dass es sich bei den Zahlen um Zahlenkonstanten handelt. Etwaige Zellen mit Formeln werden nicht berücksichtigt.
Auch unter Zellen, die Text enthalten, wird eine Summenformel platziert (Resultat ist dann 0).

 

Vielen Dank für die prompte Antwort. Ich möchte dies aber nur auf meine Spalte F beziehen, da er sonst alle Spalten berechnet, was aber für mich nicht notwéndig ist.

Ansonsten funktioniert das Makro bestens.

Danke

Eisbubi

 

Hallo,

damit das Makro sich nur auf Spalte F und nicht auf alle Zellen des aktiven Arbeitsblattes bezieht, braucht man nur die "ActiveSheet.Cells"-Eigenschaft durch die "ActiveSheet.Columns("F")-Eigenschaft zu ersetzen:

Code:

Sub SpalteF_Addieren()
  Dim rgArea As Range, rgCol As Range, rgSumme As Range
  '
  With ActiveSheet.Columns("F").SpecialCells(xlCellTypeConstants)
    For Each rgArea In .Areas
        For Each rgCol In rgArea.Columns
          With rgCol
            Set rgSumme = .Offset(.Rows.Count).Resize(1, 1)
            rgSumme.Formula = "=SUM(" & .Address & ")"
          End With
        Next rgCol
    Next rgArea
  '
  End With
  '
End Sub

Die modifizierte Excel-Datei liegt nochmals bei:

 

Danke,
ich verstehe das Makro so einigermasen.

Habe aber noch folgendes Problem:

Meine Tabelle sieht so aus:

B xxxxxxxxxxxxx 23
C xxxxxxxxxxxxx 12
S xxxxxxxxxxxxx 0

P xxxxxxxxxxxxxx 8
B xxxxxxxxxxxxxx 19
B xxxxxxxxxxxxxx 11
S xxxxxxxxxxxxxx 0
In der ersten Spalte steht praktisch ein Kennbuchstabe dann folgt Text und in der Spalte F dann die Beträge. Dazwischen ist immer eine Leerzeile.
Genau in der Spalte Summe sollte er dann die darüberliegenden Beträge zusammenzählen.
Das heist die 0 wird durch den Summenbetrag ersetzt.

Danke für die Hilfe

 

Hallo,

das folgende Makro stellt immer dann eine Summenformel in Spalte F, wenn in Spalte A ein "S" enthalten ist. Dabei summiert die Formel über alle Zeilen in Spalte F, die in Spalte A einen Buchstaben (außer "S") enthalten.

Code:

Sub SpalteF_KritS_Addieren()
  Dim rgZelleA As Range
  Dim Zeile1 As Long, SpalteA As String
  '
  With ActiveSheet
    Zeile1 = 0
    For Each rgZelleA In .Columns("A").Cells
       SpalteA$ = rgZelleA.Value
       If SpalteA$ = "S" Then
         'dann Summenformel in Spalte F stellen
         rgZelleA.Offset(0, 5).Formula = "=SUM(R" & Zeile1 & "C:R[-1]C)"
         'Setze Summierungsstartzeile zurück:
         Zeile1 = 0
       ElseIf Len(SpalteA$) = 0 Then
         'Leerzeile - Tue nichts
       Else
         'Zeile mit Buchstaben außer S in Spalte A
         'Merke dir die Startzeile für die Summierung:
         If Zeile1 = 0 Then Zeile1 = rgZelleA.Row
       End If
    Next rgZelleA
    '
  End With
End Sub

Die Excel-Datei liegt wieder bei.

 

Hallo Anton,

das Makro arbeitet ganz super. Die 12.000 Zeilen sind schnell und flott zusammengerechnet.

Hätte ich nicht gedacht, daß man mit diesen paar Zeilen diese Aufgabe so elegant abwickeln kann.

Danke

Eisbubi