Office: Mehrkampf mit Streichresultaten

Hallo an die Forumsgemeinde,

hierbei handelt es sich um einen Mehrkampf, bei dem es 6 verschiedene
Wettkampfarten gibt.

Wenn ein Wettkampf öfter als einmal durchgeführt wird, dann gibt es ein
Streichresultat für die niedrigste Punktezahl. Also beispielsweise
Wettkämpfer "A" hat in den drei Wettkämpfen "BLAU" einmal
30 Punkte, einmal 60 Punkte und einmal 80 Punkte. Streichresultat
wären in diesem Fall die 30 Punkte.

Trifft zu bei vier Wettkampfarten:
grün
orange
blau
gelb

In der Spalte "TOTAL" wird die Gesamtpunktezahl ohne Abzug angezeigt.
In der Spalte "STREICH" sollte die Punktanzahl nach Abzug der
vier Streichresultate angezeigt werden. Also Gesamtpunktezahl minus
Summe der vier Streichresultate.

Die Streichresultate sollten automatisch durch einen Stern " 40* "
oder eine Klammer " (40) " gekennzeichnet werden.

Überdies sollten die einzelnen Zeilen anschließend nach Ergebnis
gereiht werden. Also ganz oben in Zeile "RANG" "1" der Athlet mit
der besten Punktezahl nach Abzug der Streichresultate usw.

Läßt sich sowas relativ einfach lösen oder ist das für mich als
mathematischen Laien nicht machbar?

Vielen Dank für Eure Bemühungen.

Gruß
Kramer

 

Hallo!

Gegenfrage:
Was soll z.B. bei den orangenen Ergebnissen von Spieler C gestrichen werden? Die 0 oder die 18?
(Oder allgemeiner: Sollen Nullen mitbetrachtet oder ignoriert werden?)

Und warum verwendest du pro Spieler ZWEI Zeilen? Das wird spätestens beim Sortieren zum Problem!!!

 

Hallo,

die "0" stellt einen Ausfall dar und soll als 0 Punkte behandelt werden,
also als Streichresultat.

Die jeweils zweite Zeile kommt weg und es sollte dann so aussehen wie unten.

Vielen Dank.

Gruß
Kramer

 

Hallo!

Anhand von 3 Datensätzen habe ich mal was zusammengehämmert.
Müsste so passen, oder?

	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1
2
3
4	Rang	Name	Streich	Total	Grün	Ora	Blau	Ora	Blau	Gelb	Weiss	Gelb	Blau	Ora	Ora	Grau	Grün
5	2	A	475	691	40	80	45	80	100	100	10	100	36	100
6	1	B	500	655	100	50	60	60	80	45	50	50	80	80
7	3	C	458	568	80	0	100	18	50	60	60	80	60	60
8

Zelle	Formel
A5	=RANG(C5;C$5:C$19)
C5	=D5-(ANZAHL(E5;Q5)>1)*MIN(E5;Q5)-(ANZAHL(F5;H5;N5;O5)>1)*MIN(F5;H5;N5;O5)-(ANZAHL(G5;I5;M5)>1)*MIN(G5;I5;M5)-(ANZAHL(J5;L5)>1)*MIN(J5;L5)
D5	=SUMME(E5:Q5)
A6	=RANG(C6;C$5:C$19)
C6	=D6-(ANZAHL(E6;Q6)>1)*MIN(E6;Q6)-(ANZAHL(F6;H6;N6;O6)>1)*MIN(F6;H6;N6;O6)-(ANZAHL(G6;I6;M6)>1)*MIN(G6;I6;M6)-(ANZAHL(J6;L6)>1)*MIN(J6;L6)
D6	=SUMME(E6:Q6)
A7	=RANG(C7;C$5:C$19)
C7	=D7-(ANZAHL(E7;Q7)>1)*MIN(E7;Q7)-(ANZAHL(F7;H7;N7;O7)>1)*MIN(F7;H7;N7;O7)-(ANZAHL(G7;I7;M7)>1)*MIN(G7;I7;M7)-(ANZAHL(J7;L7)>1)*MIN(J7;L7)
D7	=SUMME(E7:Q7)

 

Hallo Schatzi,

du machst Deinem Namen alle Ehre. Vielen herzlichen Dank für Deine
Hilfe - funktioniert grandios.

Gibt es eine Möglichkeit, das jeweilige Streichresultat zu markieren? Mit
Stern oder Klammer?

Wenn nicht oder nur sehr kompliziert möglich, dann ist das kein Problem.
Bin mit dem bisherigen Ergebnis mehr als zufrieden.

Gruß
Kramer

 

Hallo!

Eine Möglichkeit wäre, über die Bedingte Formatierung das Zahlenformat benutzerdefiniert zu ändern:

Code:

Standard"*"

Der Nachteil ist, dass (wie in Zeile 5) ein mehrfach auftretendes Minimum auch mehrfach markiert wird...

Hier für das Beispiel "orange":

	E	F	G	H	I	J	K	L	M	N	O	P	Q
1
2
3
4	Grün	Ora	Blau	Ora	Blau	Gelb	Weiss	Gelb	Blau	Ora	Ora	Grau	Grün
5	40	80 *	45	80 *	100	100	10	100	36	100
6	100	50 *	60	60	80	45	50	50	80	80
7	80	0 *	100	18	50	60	60	80	60	60

Zelle	bedingte Formatierung...	Format
F5	1: =(ANZAHL($F5;$H5;$N5;$O5)>1)*(F5=MIN($F5;$H5;$N5;$O5))	abc
H5	1: =(ANZAHL($F5;$H5;$N5;$O5)>1)*(H5=MIN($F5;$H5;$N5;$O5))	abc
N5	1: =(ANZAHL($F5;$H5;$N5;$O5)>1)*(N5=MIN($F5;$H5;$N5;$O5))	abc
O5	1: =(ANZAHL($F5;$H5;$N5;$O5)>1)*(O5=MIN($F5;$H5;$N5;$O5))	abc
F6	1: =(ANZAHL($F6;$H6;$N6;$O6)>1)*(F6=MIN($F6;$H6;$N6;$O6))	abc
H6	1: =(ANZAHL($F6;$H6;$N6;$O6)>1)*(H6=MIN($F6;$H6;$N6;$O6))	abc
N6	1: =(ANZAHL($F6;$H6;$N6;$O6)>1)*(N6=MIN($F6;$H6;$N6;$O6))	abc
O6	1: =(ANZAHL($F6;$H6;$N6;$O6)>1)*(O6=MIN($F6;$H6;$N6;$O6))	abc
F7	1: =(ANZAHL($F7;$H7;$N7;$O7)>1)*(F7=MIN($F7;$H7;$N7;$O7))	abc
H7	1: =(ANZAHL($F7;$H7;$N7;$O7)>1)*(H7=MIN($F7;$H7;$N7;$O7))	abc
N7	1: =(ANZAHL($F7;$H7;$N7;$O7)>1)*(N7=MIN($F7;$H7;$N7;$O7))	abc
O7	1: =(ANZAHL($F7;$H7;$N7;$O7)>1)*(O7=MIN($F7;$H7;$N7;$O7))	abc

 

Das genügt mir vollkommen - nochmals vielen Dank und die besten Grüße.

Kramer