Office: (Office 2013) Menge aus 2 Tabellenblättern erstellen / Autovervollständigung

Moin Moin,

ich habe aktuell das "Projekt" per Excel eine Tabelle für unseren Warenbestand zu erstellen.

Folgende Ist-Situation:

In Tabellenblatt 1 (Ein_Ausgang) erfasse ich die EAN sowie IMEI der Handys. Per Macro werden der Wareneingang in Tabellenblatt 2 (Eingang) übertragen, sowie der Warenausgang in Tabellenblatt 3 (Ausgang).
In Tabellenblatt 4 (IMEI) sollen meine gesamten vorrätigen Handys (nach Ein- und Ausgang) aufgelistet sein.

Nun meine 2 Probleme:

1.
Da ich den Wareneingang möglichst schnell erledigen möchte, erfasse ich nur EAN und IMEI (werden gescannt). In Tabellenblatt 2 (Eingang) sollen allerdings noch Hersteller sowie Modell erscheinen. In Tabellenblatt 7 (Datenbank) habe ich EAN, Hersteller sowie Modell aufgelistet. Ich bekomme es nicht hin, dass Tabellenblatt 2 anhand der EAN den Hersteller sowie das Modell automatisch einfügt.

2.
In Tabellenblatt 4 (IMEI) sollen alle Handys, nach Eingang und Ausgang aufgelistet werden. Sozusagen steht in Tabellenblatt 2 (Eingang):
Hersteller 1, Modell 1 mit EAN 1231 sowie IMEI 1
Hersteller 1, Modell 1 mit EAN 1231 sowie IMEI 2
In Tabellenblatt 3 (Ausgang) steht:
Hersteller 1, Modell 1 mit EAN 1231 und IMEI 1
In Tabellenblatt 4 (IMEI) sollte nun nur noch erscheinen:
Hersteller 1, Modell 1 mit EAN 1231 und die IMEI 2 (da ich dieses Handy noch nicht verkauft habe)

Ist dies mit Excel überhaupt machbar? Wenn ja, mit welcher Formel oder Makro?

Ich hoffe ihr könnt mir in irgendeiner Art helfen und ich habe es nicht zu umständlich beschrieben :-)

Schon mal viele lieben Dank im Vorraus,
René

 

Hola,

zu 1:

D6:

Code:

=INDEX(Datenbank!B$6:B$11;VERGLEICH($H6;Datenbank!$D$6:$D$11;0))

F6:

Code:

=INDEX(Datenbank!C$6:C$11;VERGLEICH($H6;Datenbank!$D$6:$D$11;0))

Die Bereiche in den Formeln musst du noch anpassen.

Zu 2.
Das schaue ich mir morgen mal an.

Gruß,
steve1da

 

Moin Moin,

Danke für die schnelle Hilfe. TOP!

Hast du wegen meinem 2. Problem schon eine Lösung finden können?

Beste Grüße,
René

 

Hola,

leider weicht deine Beschreibung von der Tabelle ab.

Ist die IMEI eindeutig? Kann ich also über die IMEI eindeutig ein Handy identfizieren?

Gruß,
steve1da

 

Moin,

ja, die IMEI ist von jedem Handy einzigartig.
Die IMEI ist für das Handy wie die Personalausweisnummer für den Bundesbürger ;-)

Beste Grüße,
René

 

Hola,

also, in die Tabelle "Eingang" in M1 folgende Formel zum runterziehen:

Code:

=ZÄHLENWENN(Ausgang!$J$6:$J$566;J6)

In die Tabelle "IMEI" in B6:

Code:

{=WENNFEHLER(INDEX(Eingang!D$6:D$1000;KKLEINSTE(WENN(Eingang!$M$6:$M$1000>0;ZEILE($1:$995));ZEILE(A1)));"")}

In C6:

Code:

{=WENNFEHLER(INDEX(Eingang!F$6:F$1000;KKLEINSTE(WENN(Eingang!$M$6:$M$1000>0;ZEILE($1:$995));ZEILE(B1)));"")}

In D6:

Code:

{=WENNFEHLER(INDEX(Eingang!H$6:H$1000;KKLEINSTE(WENN(Eingang!$M$6:$M$1000>0;ZEILE($1:$995));ZEILE(C1)));"")}

In E6:

Code:

{=WENNFEHLER(INDEX(Eingang!J$6:J$1000;KKLEINSTE(WENN(Eingang!$M$6:$M$1000>0;ZEILE($1:$995));ZEILE(D1)));"")}

Bei den 4 Formeln gilt: die {} nicht mit eingeben, sondern die Formel mit Strg-Shift-Enter abspeichern!

Die 4 Formeln dann nach unten ziehen.

Gruß,
steve1da

 

Moin Moin,

das mit den Formeln hat so weit geklappt! Super dafür schon mal!

Nun hab ich aber das Problem, dass bei IMEI die aufgelistet werden, die ich schon verkauft habe. Ich wollte in dem Tabellenblatt IMEI allerdings die aufgelistet haben, die ich noch nicht verkauft habe.

 

Hola,

sorry, mein Fehler.

Ändere die erste Formel wie folgt:

Code:

=(WENN(ZÄHLENWENN(Ausgang!$J$6:$J$566;J6);0;1))*(J6<>"")

Und die kommt in M6, nicht in M1.

Gruß,
steve1da

 

Dickes fettes Danke, steve1da!

Du bist mein Held!

 

Hola,

danke für das Feedback!

Sollte das irgendwann zu langsam werden, einfach melden.

Gruß,
steve1da