Office: Mengenberücksichtigung

Hallo Stephan,

ich kann Dir sicherlich helfen, allerdings eben wie bereits geschrieben ausschließlich mit den Funktionen die es bis XL2016 gab. Diese sind allerdings für die Rechnungstabelle auch völlig ausreichend. Ich könnte Dir damit Formeln aufzeigen, die die vorhandenen ersetzen und damit auch Deine Hilfsspalten in Spalte K:S überflüssig machen (nur die in Spalte I halte ich für sinnvoll) und dabei sogar noch etwas kürzer sind als Deine bisherigen Formeln.

Außerdem würde ich da zumindest den Zuschlag für das Falten je "Artikel" gleich mit einbeziehen. Das wäre auch für den "Wildformatzuschlag" möglich. Für diesen bin ich übrigens der Meinung bin, das in diesen auch der Zuschlag für das Falten mit ein berechnet werden sollte (so dass im Beispiel anstelle 1,86 € sich 2,06 € ergeben würden).

Oder was meinst Du?

 

Halle Werner,

für vereinfachte Formeln und Berechnungen bin ich immer dabei, aber das mit dem Falten muss so bleiben, weil es gibt bei meinen Kumpel Kunden da ist in dem Einzelpreis das Falten incl.

Gruss stephan

 

Hallo Stephan,

auch das ließe sich einfacher regeln. Wenn in Spalte G der Datenzeile nichts steht, wird ja auch kein Zuschlag für Falten berechnet. Wenn Du aber eine andere separate Kennzeichnung als "ja" benötigst, dann nutze dafür das "nein", denn momentan wird ja nicht wirklich benötigt. Alternativ könntest für "nein" z.B. "incl." in der Dropdownzelle anbieten.

 

OK dann zeige mir was du meinst, ich stehe gerade auf dem Schlauch, ich hätte auch gerne die Spalte Datum weg ohne das sich die Tabelle verschiebt, d.h. das die Spalte Netto ausserhalb der Tabelle/Druckbereich bleibt.

anbei eine aktuelle Tabelle

Gruß Stephan

 

sorry falsche Exceltabelle, hier die richtige

 

Hallo Stephan,

Die Spalte [Datum] zu entfernen ist doch kein Problem.
Und da Du offensichtlich nicht alles gelesen hast, was ich meinen letzten 2 Beiträgen an Dich geschrieben habe, zeige ich Dir nachfolgend nur für das von Dir zuerst eingestellte Beispiel meine Formeln auf. Diese kommen ohne Deine Hilfsspalten rechts von "Gesamtpreis" aus. Sie werden bei entsprechender Formelanpassung auch nicht für die in B49:I55 gebraucht. Selbst die Hilfsspalte für "qm" hab ich eliminiert.

Siehe nachfolgend. Wobei die benannte Formel: _qm (welche die entsprechende Hilfsspalte ersetzt) ist bei aktivierter Zelle G26 (!) zu definieren.

Arbeitsblatt mit dem Namen 'Rechnung'
	B	C	D	E	F	G	H
26	Anzahl	Bezeichnung	Farbe	Format	Falten	Einzelpreis	Gesamtpreis
27
28	8,00	CAD-Plot	Farbe	DIN A0	Ja	7,15 € / Stk.	57,20 €
29	2,00	CAD-Plot	SW	DIN A0	Ja	3,30 € / Stk.	6,60 €
30	1,00	sonstiges		Datenbearbeitung		45,00 € / Stk.	45,00 €
31	1,00	Digitaldruck	SW	DIN A4		0,20 € / Stk.	0,20 €
32	5,00	Digitaldruck	sw	DIN A4		0,20 € / Stk.	1,00 €
33	30,00	Digitaldruck > 20	Farbe	DIN A3		1,30 € / Stk.	39,00 €
34	3,00	Digitaldruck	SW	DIN A4		0,20 € / Stk.	0,60 €
35	20,00	Papierzuschlag	100 g	DIN A4		0,02 € / Stk.	0,40 €
36	22,00	Digitaldruck > 20	SW	DIN A4		0,08 € / Stk.	1,76 €
37	0,25	sonstiges		Datenbearbeitung		45,00 € / Stk.	11,25 €
38	1,00	CAD-Plot Wildformat	Farbe	0,84 x 1,70 m	Ja	10,21 € / Stk.	10,21 €
39	1,00	Digitaldruck	SW	DIN A4		0,20 € / Stk.	0,20 €
40	2,00	Großkopie	Farbe	DIN A1		7,50 € / Stk.	15,00 €
41	1,00	PVC-Forex-Platte	Farbe	DIN A0		95,00 € / Stk.	95,00 €
48						Gesamt:	283,42 €
50	Wildformatzuschlag von 20 %						2,04 €
51	Gesamt Netto ohne Rabatt						285,46 €
52	Mengenrabatt ab 10 Plänen 10 %						-18,61 €

Zelle	Format	Wert
G27	0,00" € / Stk.";;
H27	#.##0,00 €

Name	Bezug
_qm	=WENNFEHLER(LINKS(Rechnung!$E26;SUCHEN("x";Rechnung!$E26)-1)*WECHSELN(TEIL(Rechnung!$E26;SUCHEN("x";Rechnung!$E26)+2;99);"m";"");"")

Zelle	Formel
G27	=WENNFEHLER(AGGREGAT(15;6;tbl_Preise[Preis]/([@Bezeichnung]&[@Farbe]&WENN(ZÄHLENWENN([@Bezeichnung];"*"&"Wild"&"*");"";[@Format])=tbl_Preise[Artikel]&tbl_Preise[Farbe]&tbl_Preise[Größe]);1)*(1+([@Falten]="Ja")*SVERWEIS("Falten";Zuschlag[[Zuschlagsart]:[Werte]];2;0)/100)*WENN(_qm=""; 1;_qm);"")
H27	=WENNFEHLER([@Einzelpreis]*[@Anzahl];"")
H48	=RUNDEN(TEILERGEBNIS(109;[Gesamtpreis]);2)
H50	=WENN(B50="";0;RUNDEN(SUMMEWENN(Rechnung[Bezeichnung];"*Wild*";Rechnung[Gesamtpreis])/100*SVERWEIS("*Wild*";Zuschlag;2;0);2))
H51	=Rechnung[[#Ergebnisse];[Gesamtpreis]]+H50
H52	=-(SUMMENPRODUKT(SUMMEWENNS(Rechnung[Gesamtpreis];Rechnung[Bezeichnung];{"CAD*"."Groß*"."*Platte"}))+H50)*SVERWEIS(SUMMENPRODUKT(SUMMEWENNS(Rechnung[Anzahl];Rechnung[Bezeichnung];{"CAD*"."Groß*"."*Platte"}));MRabatt[[Anzahl]:[Prozent]];2)/100

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

 

ich werde es morgen während ich die EDV für einen LA Wettkampf mache versuchen einzubauen, da habe ich viel Zeit dazwischen ;)

es fehlt aber die Zeile mit dem Falten und dem Faltpreis in Klammern, ist die Zelle B48

Gruss Stephan

 

Hallo Stephan,

zu Deiner Aussage:

Wozu? Die Preise dafür sind doch bereits in EP und damit auch im GP inbegriffen. Eine derartige Angabe würde z.B. mich als Kunden nur verwirren.
Aber nun gut, die Formel dafür:

=WENN(ZÄHLENWENN(Rechnung[Falten];"Ja")>0;"In den Plänen ist der Preis für das Falten, schneiden und Heftstreifen mit "&SVERWEIS("Falten";Zuschlag;2;0)&" % bereits enthalten. ("&TEXT(SUMMEWENNS(Rechnung[Gesamtpreis];Rechnung[Falten];"Ja")/100*SVERWEIS("Falten";Zuschlag;2;0);"0,00")&" €)";"")

 

Hallo Stephan,

Du wirst sicherlich feststellen, dass ich Deine Wahrheitswerte aus =tbl_Preise[MRab] nicht abfrage, diese also eingespart werden kann. Die Berücksichtigung dessen hab ich anderes realisiert. Analog wäre das auch sicherlich für =tbl_Preise[DRab] möglich.
Und noch ein Hinweis zu Deinen Dropdownzellen für "Platten". Obwohl Du in Deiner Preisliste nur A0-formatige hast, bietest Du auch A4:A1 an. Du solltest Deine Dropdwonzellendefinition möglichst als Deiner Preisliste generieren.