Office: Mit VBA Bildschimrpräsentation (pps) öffnen

Hallo Schatzis,

wie kann ich in ACCESS mit VBA eine Bildschirmpräsentqation (PPS-Format) öffnen? Mit der Shell-Funktion gelingt es nicht.

Gruße Egon Szepoks

 

Mit folgender Routine "LaunchDocument" bin ich bislang recht zufrieden. Ich weiß jetzt nicht mehr genau, wo ich die her hab, aber ich würde mal in Richtung "knowledge base" tippen.

Code:

Option Compare Database

Private Const SE_ERR_NOASSOC As Long = 31&

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
    ByVal hWnd As Long, _
    ByVal Operation As String, _
    ByVal Filename As String, _
    Optional ByVal Parameters As String, _
    Optional ByVal Directory As String, _
    Optional ByVal WindowsStyle As Long = vbMaximizedFocus _
    ) As Long
    
Public Function LaunchDocument( _
    ByRef Filename As String, _
    Optional ByVal ParentForm As Form, _
    Optional ByVal ShowOpenWithDialog As Boolean = False, _
    Optional ByVal WindowStyle As VBA.VbAppWinStyle = vbMaximizedFocus _
    ) As Boolean

    Dim lSuccess As Long
    Dim hWndParent As Long

    If Not ParentForm Is Nothing Then
        hWndParent = ParentForm.hWnd
    End If

    lSuccess = ShellExecute(hWndParent, "Open", Filename, vbNullString, vbNullString, WindowStyle)

    Select Case lSuccess
        Case Is > 32
            LaunchDocument = True
        Case SE_ERR_NOASSOC
            If ShowOpenWithDialog Then
                Shell "rundll32 shell32.dll,openas_rundll " & Filename
                LaunchDocument = True
            End If
        Case Else
            LaunchDocument = False
    End Select

End Function

 

Bildschirmpräsentation mit VBA aus ACCES öffnen

Hallo,
ich habe die Funktion gerade gelesen und ausprobiert. Es funktioniert.

Ganz herzlichen Dank.