Office: Mit VBA erst Wert in Spalte suchen, dann Spalte in dieser Zeile suchen

kpue · 21. März 2018

Hallo Zusammen,

bisher habe ich immer, wenn zwei Suchkriterien vorlagen, eine Kombination von Index/Vergleich genutzt. Damit komme ich bei meinem aktuellen Problem leider nicht weiter.

Es handelt sich um eine Planungsdatei, wo die Auftragsnummer und allgemeinen Infos links in den ersten 3-4 Spalten angeordnet sind. Alles rechts davon ist zeitbezogen, das heisst jeder Spalte wird ein Datum zugeordnet. Und in diesen Spalten sind Meilensteine eingetragen.

Ich möchte quasi in einem anderen Tabellenblatt die Auftragsnummern zeilenweise aufführen und spaltenweise die Meilensteinkürzel. Dann soll für jede Kombination aus Auftragsnummer/Meilenstein das Datum aus der Planungsdatei gezogen werden.

Im Prinzip müsste erst die Auftragsnummer in der Spalte A gesucht werden, dann die Zeilenummer in der diese steht zwischenspeichern und dann in der Zeile die entsprechenden Meilensteine suchen.

Ich habe mal eine Beispieldatei angehängt und würde mich freuen, wenn ihr mir da weiterhelfen könntet. Falls noch Informationen fehlen, trage ich die gerne nach.

Cool wäre es als Public Funktion, falls sowas möglich ist *wink.gif*

Vielen Dank euch!

BG

Kevin

:)

Beverly · 22. März 2018

Hi Kevin,

du kannst es mit dieser Function versuchen:

Code:

Function Angabe(rngA As Range, rngB As Range)
Dim varZeile As Variant
Dim varAngaben As Variant
Dim rngErgebnis As Range
Application.Volatile
varZeile = Application.Match(rngA, Worksheets("Auslastung ").Columns(1), 0)
If Not IsError(varZeile) Then
With Worksheets("Auslastung ")
Set rngErgebnis = .Range(.Cells(varZeile, 4), .Cells(varZeile + 1, 17)).Find(Cells(3, rngB.Column), lookat:=xlWhole)
If Not rngErgebnis Is Nothing Then
Angabe = .Cells(2, rngErgebnis.Column)
Else
Angabe = ""
End If
End With
Else
Angabe = "Nr. nicht gefunden"
End If
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In Zelle B4 eingeben =Angabe($A4;B4) und dann nach unten und nach rechts ziehen. Beachte den absoluten Bezug für Spalte A.

Hinweis 1: du solltest für hochgeladene Mappen einen sprechenden Namen wählen, damit man sie als Helfer besser einem bestimmten Tread zuordnen kann - Namen wie Mappe1, Test, Beispiel usw. sind dafür zu allgemein.

Hinweis 2: deine Tabelle heißt "Auslastung " mit einem Leerzeichen am Ende

rastrans · 22. März 2018

Nun habe ich so lange gebraucht, da war Beverly schneller.
Hier trotzdem noch meine Funktion: Code:

Public Function Auftrag(Auftragsnummer As String, Auftragsart As String)
Dim ws As Worksheet
Dim rngSuche As Range
Dim bolFound As Boolean
Dim strResult As String

Application.Volatile
strResult = vbNullString
For Each ws In ThisWorkbook.Worksheets
bolFound = StrComp(Trim(ws.Name), "Auslastung", vbTextCompare) = 0
If bolFound Then Exit For
Next
If bolFound Then
Set rngSuche = ws.Columns(1).Find(What:=Auftragsnummer, LookAt:=xlWhole)
If Not rngSuche Is Nothing Then
Set rngSuche = rngSuche.Offset(0, 3)
Set rngSuche = Range(rngSuche, rngSuche.Offset(1, ws.UsedRange.SpecialCells(xlCellTypeLastCell).Columns.Count)).Find(What:=Auftragsart, LookAt:=xlWhole)
If Not rngSuche Is Nothing Then strResult = ws.Cells(2, rngSuche.Column).Value
End If
End If
Auftrag = strResult
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Macht das gleiche. Das Leerzeichen in deiner Tabellenbeschriftung wundert mich auch! Deswegen die Prüfung, ob das Tabellenblatt überhaupt vorhanden ist. Wobei ich das Leerzeichen zur Prüfung lösche.

Office: Mit VBA erst Wert in Spalte suchen, dann Spalte in dieser Zeile suchen

Mit VBA erst Wert in Spalte suchen, dann Spalte in dieser Zeile suchen

Mit VBA erst Wert in Spalte suchen, dann Spalte in dieser Zeile suchen

Mit VBA erst Wert in Spalte suchen, dann Spalte in dieser Zeile suchen - Similar Threads - VBA Wert Spalte

Excel VBA - Code Hilfe (Spalten, Werte kopieren etc.)

Werte der letzten Zelle einer Spalte in mehreren Tabellenblättern ermitteln

Doppelte Werte in einer Spalte per VBA ermitteln

Werte einer Spalte in Bezug zu einer anderen Spalte anordnen (VBA)

VBA - Zwei Spalten Vergleichen, Bestimmter Wert - Bestimmte Ausgabe

Zeilen und Spalten mit VBA ausblenden wenn Wert 0 in bestimmten Zellen

VBA - Spalte nach Wert durchsuchen und in andere kopieren