Office: (Office 2007) Mittelwert von jedem x'ten Wert

Hallo zusammen,

ich habe folgendes Problem:

Ich habe eine Tabelle mit ca. 60.000 Zeilen. In den Zellen jeder Spalte ist ein wiederkehrender Rythmus. Es handelt sich um ´Werte eines zyklischen Prozesses.

Nun möchte ich gerne den Mittelwert von jedem xten-Wert generieren, um den "gemittelten Zyklus" grafisch darstellen zu können.

Also beispielsweise den Mittelwert von jedem 15. Wert einer Spalte.

Könnt ihr mir da weiterhelfen? Wäre super.

Lieben Gruß

:)

 

Hallo generalharm,

mal ein Beispiel für den Mittelwert aus jeder 3. Zelle im Bereich A1:A10, also die Zellen A3, A6 und A9:

=SUMMENPRODUKT((ZEILE($A$1:$A$10)/3=GANZZAHL(ZEILE($A$1:$A$10)/3))*($A$1:$A$10))/SUMMENPRODUKT(--(ZEILE($A$1:$A$10)/3=GANZZAHL(ZEILE($A$1:$A$10)/3)))

Gruß Ingolf

 

Hallo,

danke für die Antwort.

Die Formel funktioniert prinzipiell. Wie muss ich Sie denn abändern, wenn ich in der nächsten Zelle den Mittelwert des 1., 4. und 7. Wertes bekommen möchte und in der nächsten Zelle den Mittelwert des 2., 5. und 8. Wertes?

 

Hallo generalharm,

jetzt rate mal, warum in der Formel immer wieder durch 3 (/3)geteilt wird. Bevor Du diese Formel praxiswirksam einsetzt, sollte Dir die Wirkungsweise voll bewußt sein.

Gruß von Luschi
aus klein-Paris

 

Tabelle1

	A	B	C
1	1	5,50	Mittelwert 1;4;7;10
2	2	5	Mittelwert 2;5;8
3	3	6,00	Mittelwert 3;6;9
4	4
5	5
6	6
7	7
8	8
9	9
10	10

verwendete Formeln
Zelle	Formel	Bereich	R1C1 für Add In
B1	=SUMMENPRODUKT(((ZEILE($A:$A) -1) /3=GANZZAHL((ZEILE($A:$A) -1) /3) ) *($A:$A) ) /SUMMENPRODUKT(--((ZEILE($A:$A) -1) /3=GANZZAHL((ZEILE($A:$A) -1) /3) ) )		=SUMPRODUCT(((ROW(R1C1:R10C1) -1) /3=INT((ROW(R1C1:R10C1) -1) /3) ) *(R1C1:R10C1) ) /SUMPRODUCT(--((ROW(R1C1:R10C1) -1) /3=INT((ROW(R1C1:R10C1) -1) /3) ) )
B2	=SUMMENPRODUKT(((ZEILE($A:$A) +1) /3=GANZZAHL((ZEILE($A:$A) +1) /3) ) *($A:$A) ) /SUMMENPRODUKT(--((ZEILE($A:$A) +1) /3=GANZZAHL((ZEILE($A:$A) +1) /3) ) )		=SUMPRODUCT(((ROW(R1C1:R10C1) +1) /3=INT((ROW(R1C1:R10C1) +1) /3) ) *(R1C1:R10C1) ) /SUMPRODUCT(--((ROW(R1C1:R10C1) +1) /3=INT((ROW(R1C1:R10C1) +1) /3) ) )
B3	=SUMMENPRODUKT((ZEILE($A:$A) /3=GANZZAHL(ZEILE($A:$A) /3) ) *($A:$A) ) /SUMMENPRODUKT(--(ZEILE($A:$A) /3=GANZZAHL(ZEILE($A:$A) /3) ) )		=SUMPRODUCT((ROW(R1C1:R10C1) /3=INT(ROW(R1C1:R10C1) /3) ) *(R1C1:R10C1) ) /SUMPRODUCT(--(ROW(R1C1:R10C1) /3=INT(ROW(R1C1:R10C1) /3) ) )

 

Hi,
die Formel in E2 kannst du nach unten kopieren:

	A	B	C	D	E
1	1	Bemerkung	Mittelwert	ab Zeile	Mittelwert
2	2	Mittelwert 1;4;7;10	5,5	1	5,5
3	3	Mittelwert 2;5;8	5	2	5
4	4	Mittelwert 3;6;9	6	3	6
5	5
6	6
7	7
8	8
9	9
10	10

Zelle	Formel
C2	=SUMMENPRODUKT(((ZEILE($A:$A) -1) /3=GANZZAHL((ZEILE($A:$A) -1) /3) ) *($A:$A) ) /SUMMENPRODUKT(--((ZEILE($A:$A) -1) /3=GANZZAHL((ZEILE($A:$A) -1) /3) ) )
E2	=SUMMENPRODUKT(A:A*(REST(ZEILE(A:A);3)=REST(D2;3)))/SUMMENPRODUKT(--(REST(ZEILE(A:A);3)=REST(D2;3)))
C3	=SUMMENPRODUKT(((ZEILE($A:$A) +1) /3=GANZZAHL((ZEILE($A:$A) +1) /3) ) *($A:$A) ) /SUMMENPRODUKT(--((ZEILE($A:$A) +1) /3=GANZZAHL((ZEILE($A:$A) +1) /3) ) )
C4	=SUMMENPRODUKT((ZEILE($A:$A) /3=GANZZAHL(ZEILE($A:$A) /3) ) *($A:$A) ) /SUMMENPRODUKT(--(ZEILE($A:$A) /3=GANZZAHL(ZEILE($A:$A) /3) ) )

Excel Tabellen im Web darstellen >>