Office: (Office 2010) MsgBox mit Auswahl OK, UserForm Schließen, UserForm Neu

Hallo zusammen,

ich habe die UserForm1 geöffnet.

Nach einem Prozess kommt diese MsgBox:
Code:

Dort klicke ich dann auf "OK" und die MsgBox schließt sich.

Ich würde jetzt aber gerne zusätzlich zu "OK" noch folgende Möglichkeiten:

- "Neuer Auftrag" - UserForm1 muss daher geschlossen werden und neu geöffnet werden.

- "Schließen" - 1. MsgBox schließen - 2. UserForm1 schließen.

Vielen Dank

:)

 

Eine Schlatfläche mit "Neuer Auftrag" wirst du nicht in eine MsgBox bekommen.
Da musst dir eine UF basteln.
Sowas ähnliches wurde hier schonmal gefragt =). (wenn ich mich richtig erinnere)

 

Hallo,

um eine "eigene MsgBox" zu erstellen, musst du eine zusätzliche UserForm anlegen, die deine gewünschten Buttons und Funktionen hat.
Die MsgBox von Excel kannst du zwar ein wenig verändert, aber die Beschriftung der Buttons zum Beispiel nicht.

VG
Santa

 

Danke für eure Hilfe.

Die MsgBox habe ich ja eingebunden.

Wie binde ich aber die UserForm statt der MsgBox ein?

Sagen wir die UserForm ist "UserForm5". Kann man die auch benennen?

Danke

 

Hallo Santa,

das ist nicht ganz richtig. Mit ein bisschen API-Zauber kann ich auch die Beschriftung der Buttons ändern.

 

Hallo Nepumuk,

cool, das wusste ich noch nicht *Smilie
Hast du ein Beispiel oder kannst einen Link zum Nachlesen empfehlen?

VG
Santa

 

huhu Nepumuk,

Das würde mich jetzt aber auch stark Interessieren.

mfg
kvn

 

Hallo Santa,

bitteschön:

Option Explicit

Private Declare Function FindWindowA Lib "user32.dll" ( _
ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long
Private Declare Function SetTimer Lib "user32.dll" ( _
ByVal Hwnd As Long, _
ByVal nIDEvent As Long, _
ByVal uElapse As Long, _
ByVal lpTimer As Long) As Long
Private Declare Function KillTimer Lib "user32.dll" ( _
ByVal Hwnd As Long, _
ByVal nIDEvent As Long) As Long
Private Declare Function MessageBoxA Lib "user32.dll" ( _
ByVal Hwnd As Long, _
ByVal lpText As String, _
ByVal lpCaption As String, _
ByVal wType As Long) As Long
Private Declare Function SendDlgItemMessageA Lib "user32.dll" ( _
ByVal hDlg As Long, _
ByVal nIDDlgItem As Long, _
ByVal wMsg As Long, _
ByVal wParam As Long, _
ByVal lParam As String) As Long

Private Const TIMER_ID = 0
Private Const TIMER_ELAPSE = 25
Private Const WM_SETTEXT = &HC
Private Const GC_CLASSNAMEMSEXCEL = "XLMAIN"
Private Const GC_CLASSNAMEMSDIALOGS = "#32770"

Private lstrButtonCaption1 As String
Private lstrButtonCaption2 As String
Private lstrButtonCaption3 As String
Private lstrBoxTitel As String
Private llngHwnd As Long

Private Function MsgBoxPlus( _
ByVal strText As String, _
ByVal strTitle As String, _
ByVal strButtonText1 As String, _
Optional ByVal strButtonText2 As String, _
Optional ByVal strButtonText3 As String, _
Optional ByVal enmStyle As VbMsgBoxStyle) As Long

Dim lngResult As Long

lstrButtonCaption1 = strButtonText1
lstrButtonCaption2 = strButtonText2
lstrButtonCaption3 = strButtonText3
lstrBoxTitel = strTitle

If Val(Application.Version) > 9 Then
llngHwnd = Application.Hwnd
Else
llngHwnd = FindWindowA(GC_CLASSNAMEMSEXCEL, Application.Caption)
End If

Call SetTimer(llngHwnd, TIMER_ID, TIMER_ELAPSE, AddressOf SetButtonText)

If lstrButtonCaption2 = "" And lstrButtonCaption3 = "" Then
lngResult = MessageBoxA(llngHwnd, strText, strTitle, vbOKOnly Or enmStyle)
ElseIf lstrButtonCaption2 <> "" And lstrButtonCaption3 = "" Then
lngResult = MessageBoxA(llngHwnd, strText, strTitle, vbYesNo Or enmStyle)
Else
lngResult = MessageBoxA(llngHwnd, strText, strTitle, vbAbortRetryIgnore Or enmStyle)
End If

If lngResult = 1 Or lngResult = 3 Or lngResult = 6 Then
MsgBoxPlus = 1
ElseIf lngResult = 4 Or lngResult = 7 Then
MsgBoxPlus = 2
Else
MsgBoxPlus = 3
End If

End Function

Private Sub SetButtonText()

Dim lngBox_hWnd As Long

Call KillTimer(llngHwnd, TIMER_ID)

lngBox_hWnd = FindWindowA(GC_CLASSNAMEMSDIALOGS, lstrBoxTitel)

If lstrButtonCaption2 = "" And lstrButtonCaption3 = "" Then
Call SendDlgItemMessageA(lngBox_hWnd, vbCancel, WM_SETTEXT, 0&, lstrButtonCaption1)
ElseIf lstrButtonCaption2 <> "" And lstrButtonCaption3 = "" Then
Call SendDlgItemMessageA(lngBox_hWnd, vbYes, WM_SETTEXT, 0&, lstrButtonCaption1)
Call SendDlgItemMessageA(lngBox_hWnd, vbNo, WM_SETTEXT, 0&, lstrButtonCaption2)
Else
Call SendDlgItemMessageA(lngBox_hWnd, vbAbort, WM_SETTEXT, 0&, lstrButtonCaption1)
Call SendDlgItemMessageA(lngBox_hWnd, vbRetry, WM_SETTEXT, 0&, lstrButtonCaption2)
Call SendDlgItemMessageA(lngBox_hWnd, vbIgnore, WM_SETTEXT, 0&, lstrButtonCaption3)
End If

End Sub

Public Sub Aufruf()
Select Case MsgBoxPlus(strText:="Ich bin der Text", strTitle:="Titel", _
strButtonText1:="Button 1", strButtonText2:="Button 2", _
strButtonText3:="Button 3", enmStyle:=vbInformation)
Case 1
MsgBox "Button 1"
Case 2
MsgBox "Button 2"
Case 3
MsgBox "Button 3"
End Select
End Sub

 

Huhu =),

möchte dir da jetzt nicht zu nahe tretten, aber der aufwand ist ja enorm, wenn man auch einfach ein UF bauen kann, oder?

 

Ok.

Was davon muss ich denn jetzt wohin kopieren?

Was muss ich z.B. an die Stelle kopieren wo mal mein Text stand?

Code:

Danke

 

\@Nepumuk:
Interessant!
Die Größe der Button ist vermutlich fix, da ja nur bestehende Texte geändert werden?

@christian:
Ich würde es mit einer neuen Userform machen, das ist vermutlich übersichtlicher:
Dort wo du jetzt die MsgBox aufrufst, sprichst du jetzt die Userform an (UserForm5.Show).
Den Namen kannst du auch ändern, das empfehle ich sogar *Smilie klicke die Userform an und suche im Fenster Eigenschaften (F4, falls nicht sichtbar) nach (Name). Dort kannst du den Codenamen der Userform ändern.

VG
Santa

 

Hallo,

ich benutze das auch nicht, das sollte nur eine Demo sein wie es geht.

 

Danke für die Tipps.

Mit Unload schließe ich ja eine UserForm.

Wie schließe ich dann aber zwei auf einmal?

Danke

 

Wie bekomme ich denn " & Ordnerpfad_pdf & " in meine neue UserForm?

 

Hallo zusammen,

ich habe es jetzt so gelöst:

Code:

Ist das so eine gute Lösung?

Leider klappt das mit dem Anzeigen des "Ordnerpfad" nicht.

Kann mir da noch jm helfen?

Danke