Office: (Office 365) MsgBox mit Berechnung und Eintrag in Tabelle

Moin moin liebe Formengemeinschaft. Nun bin ich schon das WWW am Durchsuchen und habe nichts passendes gefunden.

Ausgangspostion:

Ich habe eine Datenbank und überwache hier Daten mit einem bestimmten Ablaufdatum. Die Daten bekomme ich als Kalenderwoche oder auch bei einer anderen Position als Quartal und Jahr geliefert. (Bsp: 23/2000) Diese Angabe muss ich dann in den ersten Kalendertag / ersten Tag im Quartal dieser Woche / dieses Quartal manuell berechnen und das Datum um 5 Jahre erweitern und das Datum in mein Eingabeformular eintragen.

Bsp: KW 43/2000 = 23.10.2000 + 5 Jahre = Eintrag in der Datenbank 23.10.2005
Q 1/2000 = 01.01.2000 + 5 Jahre = Eintrag in der Datenbank 01.01.2005

Habe mir nun überlegt, ob es geht, dass ich wenn ich da Datum eintragen möchte, eine MsgBox sich öffnet, ich dort KW / Quartal und Jahr eintrage, das Ergebniss plus 5 genommen und wenn ich auf OK klicke, das Ergebniss = gleich das Datum im Eingabeformular eingetragen wird.

Ob soetwas machbar ist? Vielleicht hat ja einer eine Idee und ich muss nicht immer manuell alles Umwandeln.

Liebe Grüße Tobias

 

Hallo,

indem du folgende benutzerdef. VBA-Funktionen in ein allgem. VBA-Codemodul kopierst

Code:

Public Function Input_KwQin5J() As Date
  Dim strKwQuJahr As String, strDef As String
 
  On Error GoTo Err_KwQu
  strDef = "KW 43/" & Year(Date)
 
Nochmal_KwQu:
  strKwQuJahr = InputBox(Prompt:=Replace("Eingabe, zB.:$KW 43/2000 $Q 1/2000", "$", vbNewLine), _
                         Title:="Kalenderwoche/Quartal/Jahr-Eingabe", _
                         Default:=strDef)
  If Len(strKwQuJahr) Then
     strDef = strKwQuJahr
     Input_KwQin5J = KwQJ_in5Jahren(strKwQuJahr)
     Exit Function
  Else
     Error 6
  End If
Err_KwQu:
  MsgBox Prompt:="Eingabe '" & strKwQuJahr & "' war fehlerhaft." & vbNewLine & _
                 "Nochmalige Eingabe!", _
         Buttons:=vbCritical, _
         Title:="Eingabefehler"
  Resume Nochmal_KwQu
 
End Function

'KW 43/2000 -> 23.10.2000 + 5 Jahre -> 23.10.2005
'Q 1/2000   -> 01.01.2000 + 5 Jahre -> 01.01.2005
Public Function KwQJ_in5Jahren(strKwQJ As String) As Date
  Dim EhKwQJ() As String, KwQJ() As String
  Dim dt As Date
  strKwQJ = Trim$(Replace(strKwQJ, "  ", " "))
  EhKwQJ = Split(strKwQJ, " ")
  KwQJ = Split(EhKwQJ(1), "/")
  Select Case UCase(EhKwQJ(0))
    Case "KW": dt = DateSerial(KwQJ(1), 1, 7 * KwQJ(0) - 3 - Weekday(DateSerial(KwQJ(1), 0, 0), 3))
    Case "Q":  dt = DateSerial(KwQJ(1), 3 * KwQJ(0) - 2, 1)
    Case Else: dt = Date
  End Select
  KwQJ_in5Jahren = DateSerial(Year(dt) + 5, Month(dt), Day(dt))
End Function

kannst du die erste der beiden Funktion verwenden, um deine Kalenderwoche/Quartal/Jahr-Eingabe in einer Inputbox zu tätigen: Input_KwQin5J()
Das Resultat, das diese Funktion liefert, ist dann das entsprechende Datum in 5 Jahren.
In die Inputbox, die nach dem Funktionsaufruf erscheint, kannst du 2 Formate eingeben:
KW 43/2000
Q 1/2000
sodass dann dazu die Funktion eine der beiden Datumsangaben als Resultat liefert:
23.10.2005
01.01.2005

 

Vielen Dank, im Moment tüftel ich, wie und wo ich es eintrage, bzw wie ich den Code richtig verarbeite. Es geht um die Ablauf - Felder.In allen trage ich bis jetzt das Datum ein und es wird in der Tabelle gespeichert. Gruß Tobias

 

Hallo,

genau in diesem Feld, wo du das getan hast bzw. tun willst, musst du in der
Feldeigenschaft: Steuerelementinhalt
die Formel =Input_KwQin5J()
eingeben. Vorher musst du aber meine erstellten Funktion in ein allgemeines VBA-Codemodul kopieren, also nicht in eines von einem Formular/Bericht/Tabelle, auch nicht in ein sogenanntes Access-Makro-Modul.