Office: MTRANS mit automatisch veränderter Matrix

Hallo zusammen

Ich folgenden Datensatz,:
In Spalte A befinden sich Datum und Zeitwerte. Pro Tag habe ich 96 Zeilen (Viertelstundenwerte). Dies für 365 Tage.
In Spalte B steht der entsprechende Messwert.

Nun möchte ich das ganze für eine spätere Auswertung horizontal darstellen.
Das Ziel ist es, das ich pro Tag eine Zeile mit den 96 Werten in den Spalten E bis CV (96 Spalten) habe.

Dazu habe ich die Funktion =MTRANS(B1:B96) für die Werte des ersten Tages verwendet.
Nun möchte ich, das in der darunterliegenden Zeile die Werte für die jeweils darauf folgenden 96 Viertelstundenwerte stehen.
Dies würde dann so aussehen.
E1:CV1 =MTRANS(B1:B96) --> Werte 01. Januar in Zeile 1
E2:CV2 =MTRANS(B97:B192) --> Werte 02. Januar in Zeile 2
E3:CV3 =MTRANS(B193:B288) --> Werte 03. Januar in Zeile 3

Damit ich nicht die ganzen 365 Tage, und dies über mehrere Jahre von Hand eingeben muss, möchte ich den Versatz von 96 Werten, durch herunterziehen automatisch übernehmen können.

Ich habe mit =INDEX und =BEREICH.VERSCHIEBEN versucht, bin aber nicht zum Ziel gekommen.

Ich hoffe Ihr könnt mir helfen.

Vielen herzlichen Dank im Voraus!
Gruss,
VIVA!

 

Hallo,
die Formel aus folgendem Link entsprechend anpassen:
Einspaltige Liste in mehreren Spalten nebeneinander * (herber.de)

 

Hallo Anton
Danke für die Antwort.
Ich sehe leider nicht wie ich mit dieser Formel die Problemstellung lösen kann.
Diese kann nach meinem Verständnis die =MTRANS Funktion ersetzen.

Ich habe eine Beispieldatei angelegt, damit die Problemstellung eventuell verständlicher wird.
Die Zellen E1:CV3 sind dabei beispielhaft mit den richtigen Werten ausgefüllt (01. bis 03. Januar).
Jetzt möchte ich dies für die Zeilen 4 und fort folgend für den 04. Januar bis zum 31. Dezember erstellen.
Möglichst mit Funktionen und herunterziehen, damit mühsame Handarbeit erspart bleibt.

Danke und Gruss

 

Hallo,

in Zelle E1 die Formel eingeben (bzw. kopieren):
=INDEX($B:$B;(ZEILE()-1)*96+SPALTE()-4;1)
und diese in die restlichen Zellen des Bereiches E1:CV76 kopieren. Das war's.

 

Hallo,

es sei denn, dass du Excel365 hast, dann genügt folgende Formel in E1:
=MTRANS(SPALTENUMBRUCH($B:$B;96))
die ausschließlich nur in E1 eingegeben werden darf. In den restlichen Zellen des Ergebnisbereiches darf keine Formel und kein Wert enthalten sein, sonst wird ein #ÜBERLAUF!-Fehler in E1 angezeigt.

 

Hi,

=MTRANS(INDEX(B:B;1+(ZEILE(A1)-1)*96):INDEX(B:B;ZEILE(A1)*96))

mit Bereich.Verschieben wäre die Formel etwas einfacher. Aber davon würde ich abraten, da dies volatil ist.
=MTRANS(BEREICH.VERSCHIEBEN($B$1:$B$96;(ZEILE(A1)-1)*96;))

Ganz anderer Ansatz bei aktuellem Excel mit nur einer einzigen Formel:
=LET(anz;ANZAHL(B:B);s;96;z;AUFRUNDEN(anz/s;0);INDEX(B:B;SEQUENZ(z;;0;s)+SEQUENZ(;s)))

EDIT: Gggggrrmmpppfffllll
SPALTENUMBRUCH() sollte ich mir endlich einmal merken!

EDIT 2:
=ZEILENUMBRUCH(B:B;96)
wäre noch eleganter.

 

Hallo,
Vielen Dank für die verschiedenen Lösungsansätze, welche ALLE funktionieren.
Da ich ein Freund von Einfachheit bin, verwende ich die Funktion ZEILENUMBRUCH.
Schockierend, wie einfach es manchmal sein kann :-)
Ist diese Funktion neu? Ich finde dazu keine Beschreibung von Microsoft...

 

Hi,

wenn du die Formel eingibst und dann auf das "Zeilenumbruch" unterhalb der Eingabe klickst, dann kommst du direkt auf die Hilfeseite.

Das funktioniert auch bei der Eingabe der Formel direkt in der Zelle. oder wenn man beim tippen F1 drückt sobald die Funktion eindeutig ist (ansonsten landet man ev. bei der falschen Funktion).

Auf der Hilfeseite findet sich unter Verfügbarkeit folgendes:

Insgesamt ist die Funktion so jung, dass es noch reichlich unübersetzte Wörter in der Hilfe gibt. Sogar die Überschrift lautet "WRAPROWS-Funktion" anstatt ZEILENUMBRUCH-Funktion.