Office: (Office 365) Nach mehreren Zahlenwerten in einer Zelle suchen

Helfe beim Thema Nach mehreren Zahlenwerten in einer Zelle suchen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, ich hoffe jemande hat eine Gute idee wie ich mein Problem lösen kann. Ich versuche mich da jetzt schon seit mehreren Tagen dran und... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Iconoclast55, 3. Februar 2023.

  1. Nach mehreren Zahlenwerten in einer Zelle suchen


    Hallo zusammen,
    ich hoffe jemande hat eine Gute idee wie ich mein Problem lösen kann. Ich versuche mich da jetzt schon seit mehreren Tagen dran und komme einfach nicht weiter. Die entsprechende Datei habe ich mal beigefügt.
    Ich möchte im Prinzip das folgendes passiert:
    - In Spalte B soll gesucht werden nach dem Ausdruck "D" oder "U"
    - Wird der Ausdruck nicht gefunden soll nichts passieren
    - Wenn der Ausdruck gefunden wird soll in der Benachbarten Zelle in Spalte A von beiden Zahlenwerten innerhalb dieser Zelle ein fixer Wert (50) abgezogen werden.
    Vielleicht hat ja jemand fix ne schnelle Lösung dafür.

    Bevor die Frage aufkommt, leider bekomm ich Tabelle so von meinem Programm ausgespuckt.

    vielen Dank schonmal
    und liebe Grüße
     
    Iconoclast55, 3. Februar 2023
    #1
  2. Kalk hat Ahnung
    Hallo

    ,
    Code:
    =WENN(ODER(B2="U";B2="D");"A="&TEIL(A2;3;FINDEN("mm";A2;1)-3)-50&"mm, "&"B="&TEIL(A2;FINDEN("B";A2;1)+2;FINDEN("mm";A2;1)-3)-50&"mm";"")
     
  3. lupo1
    lupo1 Tutorial Guru
    C1#:
    =WENN((B1:B27="D")+(B1:B27="U");
    LET(x;GLÄTTEN(TEIL(WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1:A27;"B";"B=");"=";" = ");"mm";" mm ");" ";WIEDERHOLEN(" ";99));SPALTE(A:L)*99-98;99));
    WECHSELN(NACHZEILE(WENNFEHLER(x-50;x);LAMBDA(a;TEXTVERKETTEN(;;a)));"==";"="));A1:A27)
     
  4. Exl121150 Erfahrener User

    Nach mehreren Zahlenwerten in einer Zelle suchen

    Hallo,

    und hier meine Variante: in Zelle C2 und folgende:
    =WENN(ODER(B2="U";B2="D"); LET(ab;TEXTTEILEN(A2;{"A="."B="."m"};", ";1;0;); TEXTVERKETTEN(", ";1; WAHL({1;2};"A=";"B=")&(ab-50)&"mm"));A2)
     
    Exl121150, 3. Februar 2023
    #4
  5. Exl121150 Erfahrener User
    Hallo,

    und meine NACHZEILE-Formelversion in C1#:
    =NACHZEILE($A$1:$B$27; LAMBDA(zl; LET(a;INDEX(zl;1);b;INDEX(zl;2);WENN(ODER(b="U";b="D");
    LET(ab;TEXTTEILEN(a;{"A="."B="."m"};", ";1;0;);
    TEXTVERKETTEN(", ";1;WAHL({1;2};"A=";"B=")&(ab-50)&"mm"));a))))
     
    Exl121150, 3. Februar 2023
    #5
  6. lupo1
    lupo1 Tutorial Guru
    Hallo Exl,
    weißt Du, was man zusätzlich für =NACHZEILE({102;304};LAMBDA(a;TEXTTEILEN(a;0))) benötigt, damit
    1 2
    3 4
    (in 4 Zellen) dabei rauskommt? Ich habe es schon Elex gefragt. --Ich habe ein Brett vorm Kopf--.
     
    Zuletzt bearbeitet: 3. Februar 2023
  7. Exl121150 Erfahrener User
    Hallo @lupo1,

    das funktioniert so nicht, denn die NACHZEILE-Funktion ist offenbar so ausgelegt, dass sie insgesamt ein 1-spaltiges Array erzeugen darf. Sobald die LAMBDA-Funktion versucht, ihrerseits ein 1-zeiliges Array zu produzieren, erhält man den #KALK!-Fehler (wegen geschachtelter Matrizen).

    Meine obige Formel (Posting#5) umgeht das Problem, indem in der LAMBDA-Fkt. die Array-Elemente am Ende mittels TEXTVERKETTEN zu einem Einzelwert verkettet werden.

    Dieses leidige Problem kann zB. mit folgender Formel umschifft werden:
    =WEGLASSEN(REDUCE(0;{102;304}; LAMBDA(a;v;VSTAPELN(a;TEXTTEILEN(v;"0"))));1)
    Beschränkte Spillfähigkeit neuer Funktionen

    ... aber bei dieser Thematik kennst du dich ja selber bestens aus - weit besser als ich.
     
    Exl121150, 6. Februar 2023
    #7
  8. lupo1
    lupo1 Tutorial Guru

    Nach mehreren Zahlenwerten in einer Zelle suchen

    REDUCE (rekursierend) ist langsam und beschränkt (in dem von Dir angeführten Link), TEXTVERKETTEN kann nur 32k Länge. Letzteres hat auch Elex verwendet. Somit bleibt meine FINDEN-Variante wohl doch die einzige vollfunktionale und unbeschränkte.
     
Thema:

Nach mehreren Zahlenwerten in einer Zelle suchen

Die Seite wird geladen...
  1. Nach mehreren Zahlenwerten in einer Zelle suchen - Similar Threads - mehreren Zahlenwerten Zelle

  2. Kopieren funktioniert nicht mehr

    in Microsoft Word Hilfe
    Kopieren funktioniert nicht mehr: Microsoft Office 2019 Home & Student: Hallo allerseits, habe eben bemerkt, dass seit kurzem in Word die Funktion "Kopieren" nicht funktioniert, Dies entweder mit der Auswahl im Menüband oder...
  3. Bedingte Formatierung mit mehreren Bedingungen

    in Microsoft Excel Hilfe
    Bedingte Formatierung mit mehreren Bedingungen: Guten Tag zusammen Ich möchte die Zelle K7 wie folgt bedingt formatieren: Wenn die Zellen C7 und D7 befüllt sind, soll der Inhalt in Zelle K7 formatiert werden, sondern er kleiner als «-15» ist....
  4. Daten aus mehreren Blättern nach Datums einträgen suchen

    in Microsoft Excel Hilfe
    Daten aus mehreren Blättern nach Datums einträgen suchen: Hallo zusammen, ich habe in einer Excel merere Blätter (maschinen) mit Einträgen( Datum, Arbeitszeit, Produktionsausfall, Störung und Maßnahme) nun möchte ich ein Dahsboard bauen in dem man das...
  5. VBA: Kein "Undo" mehr möglich?

    in Microsoft Excel Hilfe
    VBA: Kein "Undo" mehr möglich?: Hallo, ich habe meine Bestell-Tabelle so abgeändert, dass einiges per Makro, bzw. mittels Buttons übertragen wird. Also zum Beispiel wird mit einem Klick auf den Button die Lieferadresse gleich...
  6. Mail an mehrere Empfänger mit Zuteilung

    in Microsoft Outlook Hilfe
    Mail an mehrere Empfänger mit Zuteilung: Hallo in die Runde. Ich suche nach einer Lösung für folgenden Sachverhalt. Die Firma A schreibt fast täglich mehrere E-Mails an drei Mitarbeiter der Firma B (persönliche zugeteilte Mailadresse)....
  7. Word- und Excel-Dateien lassen sich nicht (mehr) an die Sprunglisten anheften

    in Sonstiges
    Word- und Excel-Dateien lassen sich nicht (mehr) an die Sprunglisten anheften: Hallo liebe Forengemeinde, ich hatte ein kleines Outlook-Problem, welches ich durch eine Office-Schnellreparatur versucht habe zu beheben. Leider hat das nicht geklappt. Dann folgte ich der...
  8. VBA - Schaltfläche für Mehrere Werte Suchen und Zahlenwert ändern

    in Microsoft Excel Hilfe
    VBA - Schaltfläche für Mehrere Werte Suchen und Zahlenwert ändern: Hallo zusammen, und zwar habe ich folgendes Problem und würde das Gerne via VBA über eine Schaltfläche realisieren. Da ich absoluter Neuling bin in dem Thema steh ich da leider total auf dem...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden