Office: (Office 2019) nächste freie Zelle in aktueller Spalte ab aktueller Cursorposition

Hallo zusammen,

ich habe mal eine Frage und hoffe, dass ihr mir helfen könnt.

Ich möchte, dass in VBA die nächste freie Zelle in einer vorher definierten Spalte ab der aktiven Cursor Position ausgegeben wird.

(Office 2016) - Nächste Leere Zeile statt Letzte Zeile finden

Dieser Beitrag klang schon vielversprechend, jedoch erfüllt der Code nicht die Anforderung, dass die aktive Cursor Position mit einbezogen wird. Ich habe versucht dies anzupassen, aber leider funktioniert das nicht.

Code:

Dim lngZeile As Long
    lngZeile = ActiveCell.Column
   
    With Sheets("Angebotsübersicht")
        Do
            If .Cells(lngZeile, 6) = "" Then
                MsgBox "Erste leere Zelle ist " & lngZeile
                Exit Sub
            End If
            lngZeile = lngZeile + 1
        Loop While lngZeile < .Cells(Rows.Count, "B").End(xlUp).Row
    End With

Meine Erwartung wäre, dass Zelle F7 ausgegeben wird und nicht F1 oder F13.

Ich hoffe man versteht was ich meine.

Vielen Dank im Voraus!

Viele Grüße
Chaoswolf

 

Hi,

mit der Codezeile

Code:

lngZeile = ActiveCell.Column

weist du der Variablen die SPALTE der aktiven Zelle und NICHT die ZEILE zu.

Column = Spalte
Row = Zeile

---

 

Da hatte ich wohl definitiv zu wenig Kaffee heute!

Hier nochmal der funktionierende Code. Der Code findet ab der Cursor Position die nächste freie Zeile in der Spalte F. Anbei auch eine Testdatei zum nachvollziehen.

Code:

Private Sub CommandButton1_Click()
        Dim lngZeile As Long
        lngZeile = ActiveCell.Row
      
        With Sheets("Tabelle1")
            Do
                If .Cells(lngZeile, "F") = "" Then
                    MsgBox "Erste leere Zelle ist " & lngZeile
                    Exit Sub
                End If
                lngZeile = lngZeile + 1
            Loop While lngZeile < .Cells(Rows.Count, "F").End(xlUp).Row
        End With
End Sub

Vielen Dank @Beverly !

 

Ein Problem hat sich jedoch jetzt noch ergeben...

Wenn ich jetzt in der Testdatei F12 anklicke, also den letzten Block nach dem es eine freie Zeile gibt, dann funktioniert das nicht. Hast du evtl. eine Idee warum?

 

WAS funktioniert nicht? Da musst du schon genauer werden, denn die allgemeine Aussage, dass etwas nicht funktioniert, ist keinesfalls hilfreich und meine Glaskugle ist gerade zur Reparatur .

---

 

Der Ausführungsteil innerhalb der IF Anweisung, innerhalb der Schleife wird nicht ausgeführt. Es kommt zu keiner Fehlermeldung, eine Messagebox erscheint jedoch ebenfalls nicht.

Wenn ich auf F12 stehe bin ich nicht in einer leeren Zelle, also müsste die Schleife ja so lange zu inkrementieren bis ich in einer leeren Zelle bin und dann müsste ja die Messagebox hoch kommen, das geschieht jedoch nicht.

 

Du hast doch die Abbruchbedingung

Code:

Loop While lngZeile < .Cells(Rows.Count, "F").End(xlUp).Row

angegeben - also "wiederhole so lange wie die Variable Zeile kleiner als die letzte Zeile der Spalte F ist". F12 entspricht jedoch deiner letzten belegten Zeile, die Variable lngZeile ist jedoch bereits mit dem Wert 13 belegt - folglich ist die Bedingung zum Wiederholen der Schleife nicht mehr gegeben.

Laufe doch einfach mal im Einzelschrittmodus durch den Code - dann siehst du, wass dort eigentlich abläuft.

---

 

Danke für den Hinweis. Wie du ja schon geschrieben hast, steigt die Schleife in Zeile 13 aus, sodass der Schleifenkörper (nennt man das so?...) gar nicht mehr ausgeführt wird. Ich habe nun noch das < durch <= ersetzt und ein + 1 hinten dran gehangen, sodass auch die letzte freie Zeile angezeigt wird.

Der Code sieht dann so aus.

Code:

Private Sub CommandButton1_Click()
        Dim lngZeile As Long
        lngZeile = ActiveCell.Row
     
        With Sheets("Tabelle1")
            Do
                If .Cells(lngZeile, "F") = "" Then
                    MsgBox "Erste leere Zelle ist " & lngZeile
                    Exit Sub
                End If
                lngZeile = lngZeile + 1
            Loop While lngZeile <= .Cells(Rows.Count, "F").End(xlUp).Row + 1
        End With
End Sub

 

Oder so - indem der Schleifenzähler gleich zu Beginn der Schleife erhöht wird:

Code:

Private Sub CommandButton1_Click()
        Dim lngZeile As Long
        lngZeile = ActiveCell.Row - 1
        With Sheets("Tabelle1")
            Do
                lngZeile = lngZeile + 1
                If .Cells(lngZeile, "F") = "" Then
                    MsgBox "Erste leere Zelle ist " & lngZeile
                    Exit Sub
                End If
            Loop While lngZeile <= .Cells(Rows.Count, "F").End(xlUp).Row
        End With
End Sub

---