Office: (Office 365) Neuaufbau Datenbasis für Zählerstandstabelle

Also als erstes: So nach der Struktur hätte ich das niemals aufgebaut, da wäre ich nicht drauf gekommen. Aber das macht verdammt viel Sinn! Vielen Dank für diese neue Erfahrung/Lerneffekt!

Bin dabei, dies für meine restlichen Zähler zu übernehmen.

Folgende Fragen zur Verbrauchstabelle:

Zelle B4:

Code:

=WENN($A4="";"";LET(neu;Zähler!B4;alt;Zähler!B3;WENN(UND(neu<alt;neu<100);neu;neu-alt)))

Dieses <100 soll was genau bedeuten?

Zelle M3:

Code:

=LET(ja;M$2;mo;$L3;dvo;DATUM(ja;mo;1);dbi;DATUM(ja;mo+1;0);vg;VERGLEICH(dbi;$A$4:$A$2000;0);WENNNV(INDEX($C$4:$C$2000;vg);0))

Könntest du mir diese nochmal etwas genauer erläuteren? Die Variable "dvo" wird doch garnicht in der Berechnung genutzt oder?

Nochmals vielen Dank!

 

Dieses <100 war da, um die rückwärtszählende Zählerstände abzufangen. Wenn neuer Stand kleiner als alter Stand UND Zählerstand neu <100 (irgend ein recht kleiner Wert), dann liegt ein neuer Zähler vor.

"Die Variable "dvo" wird doch gar nicht in der Berechnung genutzt oder?"
Stimmt - gut erkannt.
Ursprünglich wollte ich alle Verbräuche vom Monatsersten bis Monatsletzten addieren, aber dann kam mir die Idee, dass ja der Monatsverbrauch bereits vorliegt.
dvo;DATUM(ja;mo;1);
kann eigentlich weg. Aber kannste auch drin lassen, denn mit der Formel kannst du auch später andere Formeln bauen...

 

Hier mit Monatsauswertung und Diagramm:

 

Ok, verstanden. Rückwärtsdrehende Zähler können jetzt nicht mehr vorkommen, aber gut zu wissen, wie man das lösen kann.
Aber das kann ich ja dann für jeden Zählerwechsel benutzen (Gas, Wasser etc.) - ich muss nur an dem Tag, wo ein Zähler ausgebaut wird, den Ausbaustand nehmen - und erst am nächsten Tag den aktuellen vom neuen Zähler, richtig? Ich glaube, da hatte ich bisher auch immer einen Denkfehler.

Danke für das Diagramm - da gucke ich dann weiter, wenn ich die Verbrauchstabelle für alle Zähler komplett fertig habe!

Vielen Dank!

 

Formeln mit LET sind dank der Variablen viel übersichtlicher und besser nachvollziehbar - oder ?

 

Ja definitiv! Für heute reicht's - morgen geht's weiter :) Vielen Dank für die Anregungen und neue Inputs!

 

Hallo Onur,

Ich finde Let alleine macht in E_365 den Kohl nicht fett. Hier mal meine Version Deiner 155 bzw. 55 Auswertungsformeln.

Gruß von Luschi
aus klein-Paris

 

Ich habe jetzt aufgrund Zeitmangel nur nen bissel weitergemacht, wollte erstmal Strom Bezug fertig machen mit meinen "Wunschstatistiken"...

Brauche nur nochmal Hilfe bei dem DELTA Vorjahreszeitraum (orange markiert)... Da komm ich nicht weiter...

 

Danke für deine Version, die schaue ich mir auch in Ruhe an...

 

Und woher soll ich wissen, WAS du da berechnet haben willst ???

 

Die Differenz von Summe der Verbrauchswerte bis heute - die Summe der Verbrauchswerte im gleichen Zeitraum des Vorjahres. Ich dachte das war logisch mit dem Wort Vorjahreszeitraum - aber vllt habe ich das auch blöd erklärt.

 

Guckst du

 

Hallo Miteinander,

hier mal ein Weg dies mit einer Formel in Blatt "Verbräuche" alle Berechnungen in einem Rutsch ausgeben zu lassen. Ich habe auch gleich den Wert in J mit eingebaut. Die Frage die sich mir allerdings stellt: Kann das auch bei Zählern der anderen Medien passieren. Bei Strom ist mir das klar.
Formel in C3:

Code:

=LET(
    xA; Zähler!A:G;
    xB; SEQUENZ(ANZAHL2(Zähler!A:A)-1);
    xZeins; (xB=1);
    xC; INDEX(xA; xB+2; 1);
    xD; INDEX(xA; xB+2; 2);
    xE; INDEX(xA; xB+2; 3);
    xF;  INDEX(xA; xB+2; 4);
    xG; INDEX(xA; xB+2; 5);
    xH; INDEX(xA; xB+2; 6);
    xI; INDEX(xA; xB+2; 7);
    xJ; LAMBDA(i;
    LET(
        iZ; ZEILEN(i);
        iZz; SEQUENZ(iZ);
        xJ; i;
        xK; WENN(iZz=1; 0; INDEX(i; iZz-1));
        xL; INDEX(J:J; iZz+2);
        WENN((xJ<xK)*(xJ<100); xJ + xL; xJ-xK)
    )
);
    xM; xJ(xD);
    xN; xJ(xE);
    xO;  xJ(xF);
    xP; xJ(xG);
    xQ; xJ(xH);
    xR; xJ(xI);
    xS; LAMBDA(i;
        LET(
            iZ; ZEILEN(i);
            idx; SEQUENZ(iZ);
            xMon; MONAT(xC);
            xJahr; JAHR(xC);
            xZei; idx;
            xSp; MTRANS(idx);
            xMsk;
                (xZei>=xSp) *
                (xMon = MTRANS(xMon)) *
                (xJahr = MTRANS(xJahr));
            MMULT(xMsk; i)
        )
    );
    HSTAPELN(xC; WENN(xZeins; ""; xM); WENN(xZeins; ""; xS(xM));WENN(xZeins; ""; xN); WENN(xZeins; ""; xO); WENN(xZeins; ""; xS(xO)); WENN(xZeins; ""; xP);  WENN(xZeins; ""; xQ); WENN(xZeins; ""; xR)))

Die -1,3 im Zusammenhang mit Spalte J habe ich noch nicht eingebaut. Wie kommt diese Zahl zustande. Wenn diese Zahl händisch aufbereitet wird könnte man dies noch in die Zelle in J eintragen (z.B.: 10,8##-1,3) und dies via TEXTTEILEN trennen und diese Matrix passend zuweisen.

Gruß Uwe

 

Das kann ich nicht 100% sagen. Das ist mein erster digitaler Stromzähler, der hatte 1kwh als Bezug und 1,3kwh als Einspeisung schon drauf. Alle anderen Zähler waren bisher beim Einbau immer auf 0 (Gas, Wasser).

 

Hallo Miteinander,

ich hoffe ihr seid nicht sauer. Ich war mal so dreist und habe die Tabelle der Ablesedaten in ein Listobjekt umgebaut. Dann habe ich auch noch die Spalten fürs Eintragen der Ausgleichswerte bei Zählerwechsel angelegt. Die Ausgleichswerte der Zählerstandänderungen sind in Spalte B und D siehe Zeile 944 bereits verarbeitet. Für die anderen Ausgleichswerte fehlen mir Daten zum Testen, deshalb sind diese noch nicht eingebaut. Es kann gut sein, dass diese womöglich sogar ohne Lambda Schleifenbau hinkommen.
Fabian erkläre bitte wie die beiden Ausgleichswerte Strom Zählerstand neu 1 KWh zu 10,8 und Einspeisung 1,3 KWh zu -1,3 sich ergeben. Ich habe es erst mal als gegeben hingenommen.

Gruß Uwe