Office: Neues verzeichnis öffnen mit Zellbezug zur aktuellen datei

habe schon das ganze Netz durchsucht und keine Lösung meines Problems gefunden. Vielleicht fin ich sie ja hier.

Folgendes Problem:

Ich habe eine Excel-Datei (z. B. datei-pfad.xls) geöffnet und nehmen wir an in Zelle A1 ein Listenfeld in dem ich einen Pfad aus mehreren auswählen kann.

Nun möchte ich gern aus einem Makro heraus das Verzeichnis im Windows-Explorer öffnen, dessen Pfad in Zelle A1 steht.

Aus diesem Verzeichnis heraus möchte ich dann eine andere Excel-Datei öffnen.
Wenn sich diese dann geöffnet hat, sollte sich die Datei datei-pfad.xls schliessen, ohne sich zu speichern.

Hab schon alles probiert, bekomm das einfach nicht hin...

Sollte ungefähr so aussehen, funktioniert aber leider nicht:

Sub altedateiöffnen()
Dim Pfad As String
Pfad = Range("A1")
Start = Shell("Explorer.exe & Pfad", 1)
ActiveWorkbook.Close
Application.DisplayAlerts = False
End Sub

 

Hallo stincer1000,

unter der Annahme, dass in Zelle A1 der komplette Pfad (samt Excel-Datei) enthalten ist, müsste folgendes Makro funktionieren:

Code:

Sub AlteDatei_Öffnen()
  Dim Pfad As String
  Dim AktWb As Excel.Workbook
  Dim NeuWb As Excel.Workbook
  
  Pfad = Range("A1").Value
  Set AktWb = Application.ActiveWorkbook
  Set NeuWb = Workbooks.Add(Pfad)
  
  AktWb.Close SaveChanges:=False
End Sub

 

Re

danke erstmal für die antwort,

datei öffnen über ein vorgegebenes verzeichnis aus zelle ist kein problem - ich möchte aber nur den windows-explorer öffnen mit pfad aus einer zelle und mir dann erst eine datei auswählen...

problem ist, ob es überhaupt funktioniert, dass ein Verzeichnis mit pfad aus einer zelle geöffnet werden kann, ohne vorher eine datei festzulegen...

 

Re: Re

Doch, das geht schon... Aber bevor Du mit VBA anfängst, würde ich erstmal versuchen, ob ein Hyperlink Dir da nicht vielleicht schon reicht.

Setz einfach mal spaßeshalber den Hyperlink der Zelle auf "C:\Programme\" und klick drauf. Eigentlich sollte sich der Explorer mit dem Verzeichnis öffnen.

Allerdings wird Excel dann kaum mitkriegen, wenn Du dort eine neue Datei öffnest. Und Dein ursprüngliches Posting ging aber dahin, daß die ursprüngliche Datei sich dann schließen soll. Das wird dann irgendwie nix...

Das wirst du nur über den Dialog hinbekommen, der Dir signalisiert, ob abgebrochen oder geöffnet wurde.

Gruß, Michael

 

Hallo,

ich habe mein voriges Makro dahingehend erweitert, dass in Zelle A1 nur der Vorgabepfad für den Dateidialog steht.

Code:

Sub AlteDatei_Öffnen()
  Dim Pfad As String
  Dim AktWb As Excel.Workbook
  Dim NeuWb As Excel.Workbook
  
  Pfad = Range("A1").Value
  Set AktWb = Application.ActiveWorkbook
  
  With Application.FileDialog(msoFileDialogOpen)
    .AllowMultiSelect = False
    .InitialFileName = Pfad
    .Filters.Add Description:="Excel-Dateien ", Extensions:="*.xl*", Position:=1
    If .Show Then
      'Excel-Datei wurde ausgewählt und
      'ist statt bisheriger Excel-Datei zu öffnen
      Pfad = .SelectedItems(1)
      Set NeuWb = Workbooks.Add(Pfad)
      AktWb.Close SaveChanges:=False
      
    Else
      'Abbrechen-Button wurde gedrückt;
      'Daher ist nichts zu unternehmen
      
    End If
  End With
  
End Sub

1) Wird das Makro ausgeführt, holt es sich den Pfad aus Zelle A1 ab.
2) Daraufhin wird der Dateidialog ausgeführt und der Inhalt des Verzeichnisses, auf das der Pfad zeigt, angezeigt, allerdings nur die Dateien, deren Dateierweiterung mit ".xl" beginnt.
3a) Es kann aber daraufhin auf einen anderen Dateifilter umgeschaltet werden, falls gewünscht - doch Vorsicht, es muss sich letztendlich um Dateierweiterungen handeln, die mit Excel verknüpft sind und von Excel geöffnet werden können (sonst gibt es unter Punkt 4a) ein Problem)!!!
3b) Es kann auch ein anderes Verzeichnis ausgewählt werden.
4a) Sobald 1 Datei selektiert wurde, wird der Öffnen-Button aktiv, der sodann betätigt werden kann. Es wird die ausgewählte (Excel-)datei geöffnet und die bisherige Excel-Datei aus dem Arbeitsspeicher entfernt, ohne dass sie vorher auf Platte gespeichert wird (gemäß Deinem Wunsch).
(Auch der Doppelklick auf die gewünschte Excel-Datei funktioniert).
4b) Wird jedoch auf den Abbrechen-Button geklickt, wird der Dateidialog ohne jede sonstige Aktion geschlossen.

Ich hoffe, dass dies in etwa Deinen Wünschen entsprechen müsste. Wie Du siehst, muss man dazu nicht unbedingt den Windows-Explorer bemühen, es genügt auch ein ganz normaler Dateidialog, der auch die gleichen Fähigkeiten besitzt wie der Explorer (Es können Dateien gelöscht werden, verschoben werden, vorübergehend angesehen werden, etc...)