Office: niedrigste Werte in Zeilen Namen zuordnen

Hallo,

ich habe einen Preisspiegel mit in acht nebeneinanderliegenden Spalten namentlich benannten Bietern und mehrere hundert Zeilen mit Leistungspositionen und jeweils den Einheitspreisen der acht Bieter zu diesen Positionen.
Über die Funktion: =WENN($D20=MIN($D20:$K20);$D$9;WENN($E20=MIN($D20:$K20);$E$9;WENN($F20=MIN($D20:$K20);$F$9;WENN($G20=MIN($D20:$K20);$G$9;WENN($H20=MIN($D20:$K20);$H$9;WENN($I20=MIN($D20:$K20);$I$9;WENN($J20=MIN($D20:$K20);$J$9;WENN($K20=MIN($D20:$K20);$K$9))))))))
frage ich in einer weiteren Spalte zu jeder Zeile/Position den Bieter mit dem niedrigsten Einheitspreis ab und übernehme den betreffenden Namen des Bieters aus der Kopfzeile in diese Zelle. Das funktioniert auch wunderbar, solange nur ein Bieter den niedrigsten EP hat. Haben mehrere Bieter den gleichen niedrigsten EP, wird in der Zelle logischerweise der erste Bieter mit dem niedrigsten Wert angegeben.
Mit welcher Formel kann ich es erreichen, dass in einer bzw. mehreren weiteren Spalten auch die anderen Bieter mit dem gleichen niedrigen EP angegeben werden?

Gruß
Cara

 

hi Cara, wenn ich dich richtig verstanden hab' kannst du deine formel um einiges kürzen, oder sehe ich das falsch..?

=INDEX(D9:K9;;VERGLEICH(MIN(D20:K20);D20:K20;0))

kannst du nich mal näher beschrieben oder deine tabelle hier darstellen oder (d)eine (beispiel)datei hochladen - mit deinem gewünschten ergebnis..

 

Hallo!

Für mehrere Ergebnisse so:

	A	B	C	D	E	F	G	H	I	J	K
1	aaa
2	ccc
3	ggg
4
5
6
7
8
9				aaa	bbb	ccc	ddd	eee	fff	ggg	hhh
10
11
12
13
14
15
16
17
18
19
20				100	111	100	222	333	444	100	555

Zelle	Formel
A1	{=WENN(ZEILE(A1)>ZÄHLENWENN(D$20:K$20;MIN(D$20:K$20));"";INDEX($9:$9;KKLEINSTE(WENN(D$20:K$20=MIN(D$20:K$20);SPALTE(D:K));ZEILE(A1))))}
A2	{=WENN(ZEILE(A2)>ZÄHLENWENN(D$20:K$20;MIN(D$20:K$20));"";INDEX($9:$9;KKLEINSTE(WENN(D$20:K$20=MIN(D$20:K$20);SPALTE(D:K));ZEILE(A2))))}
A3	{=WENN(ZEILE(A3)>ZÄHLENWENN(D$20:K$20;MIN(D$20:K$20));"";INDEX($9:$9;KKLEINSTE(WENN(D$20:K$20=MIN(D$20:K$20);SPALTE(D:K));ZEILE(A3))))}
A4	{=WENN(ZEILE(A4)>ZÄHLENWENN(D$20:K$20;MIN(D$20:K$20));"";INDEX($9:$9;KKLEINSTE(WENN(D$20:K$20=MIN(D$20:K$20);SPALTE(D:K));ZEILE(A4))))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

ich hatte so ähnlich nur noch keine fehlerabfrage...

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K
4	Anbieter 2	Anbieter 5
5
6	Anbieter 2
7	Anbieter 5
8
9				Anbieter 1	Anbieter 2	Anbieter 3	Anbieter 4	Anbieter 5	Anbieter 6	Anbieter 7	Anbieter 8
10
11
12
13
14
15
16
17
18
19
20					20			20

Zelle	Formel
A4	{=INDEX($D$9:$K$9;;KKLEINSTE(WENN($D$20:$K$20>0;SPALTE($A$1:$H$1));SPALTE(A1)))}
B4	{=INDEX($D$9:$K$9;;KKLEINSTE(WENN($D$20:$K$20>0;SPALTE($A$1:$H$1));SPALTE(B1)))}
A6	{=INDEX($D$9:$K$9;;KKLEINSTE(WENN($D$20:$K$20>0;SPALTE($A$1:$H$1));ZEILE(A1)))}
A7	{=INDEX($D$9:$K$9;;KKLEINSTE(WENN($D$20:$K$20>0;SPALTE($A$1:$H$1));ZEILE(A2)))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

Hallo Schatzi, hallo hiob,

vielen Dank für die schnelle Hilfe. Ich habe die Formel von Schatzi angewendet und es funktioniert.

Gruß
Cara